Note: The other languages of the website are Google-translated. Back to English

Excel SUMIF fungsi

Di Excel, fungsi SUMIF dapat membantu menjumlahkan sel berdasarkan satu kriteria, artikel ini akan menjelaskan sintaks fungsi ini dan memperkenalkan beberapa contoh untuk menggunakan fungsi SUMIF.


 sintaks:

Sintaks untuk fungsi SUMIF di Excel adalah:

=SUMIF (range, criteria, [sum_range])

 Argumen:

  • range: Yg dibutuhkan. Rentang sel yang ingin Anda terapkan kriteria.
  • criteria: Yg dibutuhkan. Kriteria yang digunakan untuk menentukan sel mana yang perlu ditambahkan. Kriteria bisa berupa teks, angka, tanggal, ekspresi logika, referensi sel atau fungsi lain.
  • Note: Setiap kriteria teks atau kriteria yang berisi simbol matematika harus diapit dengan tanda kutip ganda. Jika kriterianya adalah numerik, tanda kutip ganda tidak diperlukan.
  • sum_range:Pilihan. Ini adalah rentang sel untuk dijumlahkan. Jika parameter ini dihilangkan, ini menggunakan range sebagai jumlah_rentang.

 Kembali:

Kembalikan penjumlahan untuk daftar angka berdasarkan kriteria tertentu.


 contoh:

Contoh 1: Menjumlahkan jika nilai lebih besar dari, kurang dari, sama dengan atau operator pembanding lainnya

Di Excel, Anda bisa menggunakan fungsi SUMIF untuk menjumlahkan nilai lebih besar dari, kurang dari, sama dengan atau tidak sama dengan kriteria tertentu.

Misalkan, Anda memiliki tabel yang berisi kolom Nama, Jumlah dan Harga seperti gambar di bawah ini yang ditampilkan, bagaimana Anda bisa mendapatkan harga total yang Qty lebih dari 250?

Harap terapkan rumus di bawah ini ke dalam sel kosong:

=SUMIF(B2:B8,">250",C2:C8)
  • Tips: Dalam rumus di atas:
  • B2: B8: adalah rentang sel tempat kriteria akan dicari.
  • "> 250": adalah kondisi tempat Anda ingin menjumlahkan nilai sel berdasarkan.
  • C2: C8: mengacu pada rentang yang akan dijumlahkan.

Lalu tekan Enter kunci untuk mendapatkan harga total yang Qty lebih besar dari 250 seperti gambar berikut yang ditampilkan:

Note: Anda dapat menggunakan operator perbandingan lain, seperti lebih besar dari atau sama dengan (> =), kurang dari (<), kurang dari atau sama dengan (<=), sama dengan (=), tidak sama dengan (<>) untuk kebutuhanmu.


Contoh 2: Rumus SUMIF dengan kriteria teks

Jika Anda ingin menjumlahkan nilai sel berdasarkan apakah nilai teks tertentu ada di kolom lain, fungsi SUMIF juga bisa membantu Anda.


Kasus 1: Jumlahkan nilai sel jika berisi teks tertentu di kolom lain

Ambil data di bawah ini sebagai contoh, untuk mendapatkan semua Qty total jika namanya David di kolom A.

Silakan masukkan atau salin rumus di bawah ini ke dalam sel kosong:

=SUMIF(A2:A8, "David", B2:B8)
  • Tips: Dalam rumus di atas:
  • A2: A8: adalah rentang sel tempat kriteria akan dicari.
  • "David": adalah kondisi tempat Anda ingin menjumlahkan nilai sel berdasarkan.
  • B2: B8: adalah rentang sel yang akan dijumlahkan.

Note: Anda juga dapat menggunakan referensi sel untuk mengganti kondisi dalam rumus di atas seperti ini: =SUMIF(A2:A8, D2, B2:B8).


Kasus 2: Jumlahkan nilai sel yang tidak sama dengan nilai tertentu

Jika Anda ingin menjumlahkan sel saat sel tidak sama dengan nilai tertentu, misalnya, untuk menjumlahkan semua Qty orang kecuali David, bagaimana Anda bisa melakukannya?

Harap terapkan rumus di bawah ini ke dalam sel kosong:

=SUMIF(A2:A8, "<>David", B2:B8)
  • Tips: Dalam rumus di atas:
  • A2: A8: adalah rentang sel tempat kriteria akan dicari.
  • "<> David": adalah kondisi tempat Anda ingin menjumlahkan nilai sel berdasarkan.
  • B2: B8: adalah rentang sel yang akan dijumlahkan.

Note: Anda juga dapat menggunakan referensi sel untuk mengganti kondisi dalam rumus di atas seperti ini: =SUMIF(A2:A8,"<>"&D2, B2:B8), Anda harus menggunakan tanda kutip ganda ("") untuk menyertakan operator perbandingan dan menggunakan tanda & (&) untuk menggabungkan referensi sel. Lihat tangkapan layar:


Contoh 3: Rumus SUMIF dengan karakter wildcard

Terkadang, Anda mungkin perlu menjumlahkan nilai sel berdasarkan sebagian teks yang cocok, bukan yang sama persis. Dalam kasus ini, Anda dapat menggabungkan karakter wildcard asterisk (*) atau tanda tanya (?) Dengan fungsi SUMIF.

Tanda bintang (*): Mewakili sejumlah karakter

Tanda tanya (?): Mewakili karakter tunggal siapa pun dalam posisi tertentu


Kasus 1: Jumlahkan nilai berdasarkan kecocokan parsial dengan karakter asterisk (*)

Misalnya, saya memiliki tabel seperti gambar berikut yang ditampilkan, sekarang, saya ingin menjumlahkan total pesanan produk yang teksnya mengandung Kutools.

Di sini, harap terapkan rumus berikut ke dalam sel kosong:

=SUMIF(A2:A8, "*Kutools*", B2:B8)

Kemudian, tekan Enter kunci untuk mendapatkan hasil di bawah ini:

Catatan:

1.Jika Anda ingin menjumlahkan nilai sel yang diawali dengan Kutools, gunakan rumus ini: = SUMIF (A2: A8, "Kutools *", B2: B8).

2. Untuk menjumlahkan nilai sel jika sel yang sesuai di Kolom A diakhiri dengan teks Kutools, gunakan rumus ini: = SUMIF (A2: A8, "* Kutools", B2: B8).

3. Anda juga dapat menggunakan referensi sel untuk mengganti kondisi dalam rumus di atas seperti ini: =SUMIF(A2:A8, "*"&D2&"*", B2:B8). Anda harus menggunakan tanda kutip ganda ("") untuk mengapit tanda bintang dan menggunakan simbol dan (&) untuk menggabungkan referensi sel. Lihat tangkapan layar:


Kasus 2: Jumlahkan nilai dengan jumlah karakter tertentu dengan tanda tanya (?)

Jika Anda ingin menjumlahkan nilai sel dalam daftar yang sel yang sesuai memiliki tepat 5 karakter seperti gambar berikut yang ditampilkan. Bagaimana Anda bisa menyelesaikan tugas ini di Excel?

Untuk menangani pekerjaan ini, Anda harus menerapkan rumus di bawah ini:

=SUMIF(A2:A8, "?????", B2:B8)

jenis: Dalam rumus ini: satu tanda tanya mewakili satu karakter, lima tanda tanya menunjukkan 5 karakter.

Lalu, tekan Enter kunci, Anda akan mendapatkan hasil yang Anda butuhkan:


Contoh 4: Jumlahkan nilai sel yang terkait dengan sel kosong atau tidak kosong

Di Excel, fungsi SUMIF juga dapat membantu menjumlahkan nilai dalam daftar yang sel yang berdekatan adalah sel kosong atau sel tidak kosong.


Kasus 1: Jumlahkan nilai sel jika sel yang berdekatan kosong

Silakan masukkan atau salin salah satu rumus di bawah ini ke dalam sel di mana Anda ingin mendapatkan hasilnya:

=SUMIF(A2:A8,"=",B2:B8)
=SUMIF(A2:A8,"",B2:B8)

Kemudian, tekan Enter kunci untuk mendapatkan hasil dari harga total jika ada sel kosong di Kolom A, lihat tangkapan layar:


Kasus 2: Jumlahkan nilai sel jika sel yang berdekatan adalah sel yang tidak kosong

Jika Anda perlu menjumlahkan nilai di mana sel yang berdekatan berisi teks tidak termasuk sel kosong, harap terapkan rumus di bawah ini:

=SUMIF(A2:A8,"<>",B2:B8)

Lalu, tekan Enter kunci, semua nilai di mana sel yang berdekatan berisi nilai telah dijumlahkan bersama, lihat tangkapan layar:


Contoh 5: SUMIF dengan tanggal di Excel

Biasanya, Anda juga dapat menggunakan fungsi SUMIF untuk menjumlahkan nilai berdasarkan tanggal tertentu di Excel.


Kasus 1: Jumlahkan nilai jika tanggal adalah tanggal sekarang atau kurang dari, lebih besar dari hari ini

Untuk menjumlahkan nilai sel yang tanggalnya adalah tanggal sekarang, Anda dapat menggunakan rumus di bawah ini:

=SUMIF(B2:B8, TODAY(), C2:C8)

Kemudian, tekan Enter kunci, semua sel yang tanggal terkait hari ini dijumlahkan. Lihat tangkapan layar:

Catatan:

1. Untuk menjumlahkan nilai jika tanggal yang bersangkutan kurang dari atau sebelum hari ini, gunakan rumus ini: = SUMIF (B2: B8, "<" & TODAY (), C2: C8).

2. Untuk menjumlahkan nilai jika tanggal terkait lebih besar dari atau setelah hari ini, gunakan rumus ini: = SUMIF (B2: B8, ">" & TODAY (), C2: C8).


Kasus 2: Jumlahkan nilai antara dua tanggal tertentu

Jika Anda ingin menjumlahkan nilai jika tanggal di antara dua tanggal tertentu, Anda dapat menggabungkan dua fungsi SUMIF bersama-sama untuk menyelesaikan pekerjaan ini.

Silakan terapkan rumus di bawah ini:

=SUMIF(B2:B8, ">=6/15/2019", C2:C8) - SUMIF(B2:B8, ">=7/31/2019", C2:C8)

Dan kemudian, tekan Memasukkan kunci, nilai total antara dua tanggal yang diberikan telah dihitung, lihat tangkapan layar:

Note: Anda juga dapat menggunakan referensi sel untuk mengganti kondisi dalam rumus di atas seperti ini: = SUMIF (B2: B8, "> =" & E2, C2: C8) - SUMIF (B2: B8, "> =" & F2, C2: C8), lihat tangkapan layar:


Contoh 6: Menjumlahkan nilai dalam beberapa kolom di Excel

Fungsi SUMIF ini juga dapat membantu Anda menjumlahkan nilai dalam beberapa kolom berdasarkan satu kondisi. Misalnya, jika Anda memiliki berbagai data seperti gambar di bawah ini, sekarang, untuk mendapatkan nilai total produk KTE dalam empat bulan - Jan, Feb, Mar dan Apr. Bagaimana Anda bisa melakukannya?

Biasanya, fungsi SUMIF digunakan untuk menjumlahkan kolom nilai berdasarkan satu kriteria, untuk menjumlahkan nilai dalam beberapa kolom, Anda dapat menggabungkan beberapa fungsi SUMIF untuk menyelesaikan tugas ini.

Harap terapkan rumus di bawah ini ke dalam sel kosong:

=SUM(SUMIF(A2:A8,G2,B2:B8), SUMIF(A2:A8,G2,C2:C8), SUMIF(A2:A8,G2,D2:D8),SUMIF(A2:A8,G2,E2:E8))

Kemudian tekan Memasukkan kunci untuk mendapatkan hasil yang benar yang Anda butuhkan, lihat tangkapan layar:

Note: Fungsi SUMIF di atas agak sulit untuk Anda gunakan jika ada banyak kolom yang perlu dijumlahkan, jadi di sini, fungsi SUMPRODUCT sederhana dapat membantu Anda menangani pekerjaan ini juga. Silakan gunakan rumus ini: =SUMPRODUCT((A2:A8=G2)*(B2:E8)), lalu tekan Enter kunci untuk mendapatkan hasil:

  • Tips: Dalam rumus di atas:
  • A2: A8: adalah rentang sel tempat kriteria akan dicari.
  • G2: adalah kondisi tempat Anda ingin menjumlahkan nilai sel berdasarkan.
  • B2: E8: adalah rentang sel yang akan dijumlahkan.


 Artikel fungsi SUMIF lainnya:

  • Jumlahkan Nilai yang Sesuai Dengan Tanggal yang Sama di Excel
  • Pernahkah Anda mencoba menjumlahkan nilai yang sesuai berdasarkan tanggal yang sama dari kolom lain di Excel? Misalkan, saya memiliki rentang data berikut (A1: B13), kolom A adalah rentang tanggal berisi beberapa tanggal duplikat, dan kolom B memiliki jumlah pesanan, sekarang, saya perlu menambahkan angka-angka berdasarkan tanggal yang sama di kolom A. Bagaimana cara menyelesaikannya dengan cepat dan mudah di Excel?
  • Tanggal Sumif Lebih Kecil / Lebih Besar Dari Hari Ini Di Excel
  • Misalkan kita memiliki tabel volume penjualan dengan perencanaan dan volume aktual setiap hari. Sekarang kita diminta untuk menghitung tanggal yang terjadi sebelum hari ini dan menghitung total volume perencanaan sebelum hari ini untuk membandingkan volume perencanaan dan volume aktual secara dinamis. Di sini saya akan menerapkan fungsi SUMIF untuk menyelesaikannya di Excel dengan cepat.
  • Sumif Dengan Satu Kriteria Atau Lebih Di Excel
  • Di Excel, menjumlahkan nilai berdasarkan satu atau beberapa kriteria adalah tugas umum bagi kebanyakan dari kita, fungsi SUMIF dapat membantu kita menjumlahkan nilai dengan cepat berdasarkan satu kondisi dan fungsi SUMIFS membantu kita menjumlahkan nilai dengan beberapa kriteria. Artikel ini, saya akan menjelaskan bagaimana menjumlahkan dengan satu atau lebih kriteria di Excel?
  • Sumif Berdasarkan Kecocokan Parsial Di Excel
  • Ambil data di bawah ini sebagai contoh, saya ingin menjumlahkan nilai sel di kolom B ketika ada teks "KTE" parsial di kolom A. Bagaimana mencapainya? Artikel ini, saya akan berbicara tentang cara menjumlahkan nilai sel berdasarkan kecocokan parsial di lembar kerja Excel.

Alat Produktivitas Kantor Terbaik

Kutools for Excel - Membantu Anda Menonjol Dari Kerumunan

Apakah Anda ingin menyelesaikan pekerjaan harian Anda dengan cepat dan sempurna? Kutools for Excel menghadirkan 300 fitur canggih yang canggih (Gabungkan buku kerja, jumlahkan berdasarkan warna, pisahkan konten sel, tanggal konversi, dan seterusnya...) dan hemat 80% waktu untuk Anda.

  • Dirancang untuk 1500 skenario kerja, membantu Anda memecahkan 80% masalah Excel.
  • Kurangi ribuan klik keyboard dan mouse setiap hari, hilangkan mata dan tangan Anda yang lelah.
  • Menjadi ahli Excel dalam 3 menit. Tidak perlu lagi mengingat rumus dan kode VBA yang menyakitkan.
  • Uji coba gratis tanpa batas selama 30 hari. Jaminan uang kembali 60 hari. Upgrade dan dukungan gratis selama 2 tahun.
Ribbon of Excel (dengan Kutools for Excel diinstal)

Tab Office - Aktifkan Pembacaan dan Pengeditan dengan Tab di Microsoft Office (termasuk Excel)

  • Satu detik untuk beralih di antara lusinan dokumen terbuka!
  • Kurangi ratusan klik mouse untuk Anda setiap hari, ucapkan selamat tinggal pada tangan mouse.
  • Meningkatkan produktivitas Anda sebesar 50% saat melihat dan mengedit banyak dokumen.
  • Membawa Tab Efisien ke Office (termasuk Excel), Sama Seperti Chrome, Firefox, dan Internet Explorer Baru.
Cuplikan Layar Excel (dengan Office Tab diinstal)
Urutkan komentar berdasarkan
komentar (0)
Belum ada peringkat. Jadilah yang pertama memberi peringkat!
Belum ada komentar yang diposting di sini
Tinggalkan komentar anda
Posting sebagai Tamu
×
Beri peringkat pos ini:
0   Karakter
Lokasi yang Disarankan

Ikuti kami

Hak Cipta © 2009 - www.extendoffice.com. | Seluruh hak cipta. Dipersembahkan oleh ExtendOffice. | Peta Situs
Microsoft dan logo Office adalah merek dagang atau merek dagang terdaftar dari Microsoft Corporation di Amerika Serikat dan / atau negara lain.
Dilindungi oleh Sectigo SSL