Loncat ke daftar isi utama

Excel SUMPRODUCT fungsi

Di Excel, fungsi SUMPRODUCT bisa digunakan untuk mengalikan dua atau lebih kolom atau larik bersama-sama, lalu mendapatkan jumlah produk. Faktanya, SUMPRODUCT adalah fungsi yang berguna yang dapat membantu menghitung atau menjumlahkan nilai sel dengan beberapa kriteria seperti fungsi COUNTIFS atau SUMIFS. Artikel ini akan memperkenalkan sintaks fungsi dan beberapa contoh untuk fungsi SUMPRODUCT ini.


 sintaks:

Sintaks untuk fungsi SUMPRODUCT di Excel adalah:

=SUMPRODUCT (array1, [array2], ...)

 Argumen:

  • array1: Yg dibutuhkan. Larik atau rentang sel pertama yang ingin Anda kalikan, lalu tambahkan.
  • array2: Pilihan. Larik atau rentang sel kedua yang ingin Anda kalikan, lalu tambahkan.

Catatan:

  • 1. Jika ada nilai non-numerik dalam rentang Anda, SUMPRODUCT memperlakukannya sebagai nol.
  • 2. Jika array atau rentang memiliki jumlah baris dan kolom yang berbeda, fungsi SUMPRODUCT akan mengembalikan #VALUE! kesalahan.
  • 3. Jika ada tes logika dalam array, mereka akan membuat nilai TRUE dan FALSE. Dalam banyak kasus, Anda perlu mengubahnya menjadi 1 dan 0 dengan menggunakan operator unary ganda (-).
  • 4. Fungsi SUMPRODUCT dapat menangani hingga 255 argumen di Excel 2007 dan versi yang lebih baru, dan hanya 30 argumen di versi Excel sebelumnya.
  • 5. SUMPRODUCT tidak mendukung karakter wildcard.

 Kembali:

Kembalikan hasil larik yang dikalikan dan dijumlahkan.


 contoh:

Contoh 1: Penggunaan dasar fungsi SUMPRODUCT

Kegunaan dasar SUMPRODUCT adalah untuk mengalikan dua kolom dan kemudian menjumlahkannya, misalnya, Anda memiliki data tangkapan layar berikut, sekarang Anda ingin mengalikan pesanan dan harga satuan, lalu menjumlahkan semua hasil perkalian bersama-sama untuk mendapatkan total harga.

Untuk menangani tugas ini, harap terapkan rumus di bawah ini:

=SUMPRODUCT(B2:B7,C2:C7)

Penjelasan: Formula ini SUMPRODUCT(B2:B7,C2:C7) = B2*C2+B3*C3+B4*C4+B5*C5+B6*C6+B7*C7.

Lalu, tekan Enter kunci, sel di kolom B dikalikan dengan sel yang sesuai di baris yang sama dari kolom C, dan hasilnya ditambahkan. Lihat tangkapan layar:


Contoh 2: Jumlahkan sel dengan beberapa kriteria dengan fungsi SUMPRODUCT

Kecuali untuk fungsi SUMIFS untuk menjumlahkan nilai sel berdasarkan beberapa kondisi, fungsi SUMPRODUCT juga dapat menyelesaikan pekerjaan ini dengan cepat dan mudah.


Kasus 1: Jumlahkan nilai sel jika berisi teks tertentu di kolom lain

Misalkan, Anda memiliki tabel data seperti gambar di bawah ini, sekarang, Anda ingin menghitung harga total yang produknya KTE dan namanya David, bagaimana Anda bisa melakukannya dengan menggunakan rumus SUMPRODUCT di Excel?

1. Harap masukkan atau salin salah satu rumus di bawah ini ke dalam sel kosong:

=SUMPRODUCT(--(A2:A12="KTE"), --(B2:B12="David"), D2:D12)
=SUMPRODUCT((A2:A12="KTE")*(B2:B12="David")*D2:D12)
  • Tips: Dalam rumus di atas:
  • A2: A12 = "KTE": adalah criteria_range dan kriteria pertama yang ingin Anda jumlahkan berdasarkan.
  • B2: B12 = "David": adalah criteria_range dan kriteria kedua yang ingin Anda jumlahkan berdasarkan.
  • D2: D12: adalah rentang jumlah yang ingin Anda jumlahkan nilai selnya.

2. Kemudian, tekan Enter kunci untuk mendapatkan hasil yang Anda butuhkan:


Kasus2: Jumlahkan sel dengan beberapa kriteria dengan logika OR

Untuk menjumlahkan sel berdasarkan beberapa kriteria dengan logika OR, Anda harus menggunakan simbol plus (+) untuk menggabungkan beberapa kondisi bersama-sama dalam fungsi SUMPRODUCT.

Misalnya, saya ingin menjumlahkan total harga produk KTE dan KTO di kolom A seperti gambar di bawah ini yang ditampilkan:

Harap terapkan rumus berikut ke dalam sel kosong:

=SUMPRODUCT((A2:A12="KTE")+(A2:A12="KTO"), C2:C12)

Lalu, tekan Enter key, total harga produk KTE dan KTO sudah dihitung, lihat screenshot:


Kasus3: Jumlahkan sel dengan beberapa kriteria dengan logika OR dan AND

Dalam beberapa situasi, Anda mungkin perlu menjumlahkan sel dengan logika OR dan AND secara bersamaan. Fungsi SUMPRODUCE juga dapat menyelesaikan pekerjaan ini dengan mudah.

Tanda bintang (*) digunakan sebagai operator DAN.

Simbol plus (+) digunakan sebagai operator OR.

Mari kita lihat contoh, untuk menjumlahkan total harga produk mana yang KTE dan KTO saat penjualan lebih besar dari 200.

Anda harus menyalin atau memasukkan rumus di bawah ini:

=SUMPRODUCT((B2:B12>200)*((A2:A12="KTE")+(A2:A12="KTO"))*C2:C12)

Lalu tekan Enter kunci untuk mendapatkan hasil yang Anda butuhkan:


Contoh 3: Hitung sel dengan beberapa kriteria dengan fungsi SUMPRODUCT

Secara umum, fungsi SUMPRODUCT ini juga dapat membantu kita menghitung sel dengan beberapa kriteria di Excel. Sama seperti nilai penjumlahan, Anda hanya perlu menghapus argumen sum_range dari rumus.


Kasus1: Hitung sel dengan beberapa kriteria dengan logika DAN

Di sini, saya ingin menghitung sel yang produknya KTE dan penjualannya lebih besar dari 200. Jadi, gunakan salah satu rumus di bawah ini:

=SUMPRODUCT(--(A2:A12="KTE"), --(B2:B12>200))
=SUMPRODUCT((A2:A12="KTE")*(B2:B12>200))
  • Tips: Dalam rumus di atas:
  • A2: A12 = "KTE": adalah criteria_range dan kriteria pertama yang ingin Anda hitung berdasarkan.
  • B2: B12> 200: adalah criteria_range dan kriteria kedua yang ingin Anda hitung berdasarkan.

Lalu, tekan Enter kunci untuk mendapatkan jumlah hasil:


Kasus2: Hitung sel dengan beberapa kriteria dengan logika OR

Untuk menghitung jumlah produk KTE dan KTO di kolom A, gunakan rumus ini:

=SUMPRODUCT((A2:A12="KTE")+(A2:A12="KTO"))

Lalu, tekan Enter kunci untuk mendapatkan nomor produk KTE dan KTO. Lihat tangkapan layar:


Kasus3: Hitung sel dengan beberapa kriteria dengan logika OR dan AND

Untuk menghitung jumlah produk KTE dan KTO yang penjualannya lebih dari 200, sebaiknya gunakan rumus sebagai berikut:

=SUMPRODUCT((B2:B12>200)*((A2:A12="KTE")+(A2:A12="KTO")))

Kemudian, tekan Enter kunci untuk mendapatkan jumlah hasil yang Anda butuhkan:


Contoh 4: Hitung rata-rata tertimbang dengan fungsi SUMPRODUCT

Biasanya, kami dapat menghitung rata-rata rentang sel dengan cepat dan mudah. Tetapi, jika Anda ingin menghitung rata-rata dari daftar nilai dengan tingkat relevansi yang berbeda, itu berarti menghitung rata-rata tertimbang. Tidak ada fungsi langsung untuk mendapatkannya di Excel. Namun, fungsi SUMPRODUCT dapat membantu Anda mengatasinya.

Misalnya, saya memiliki tabel statistik nilai untuk siswa, setiap tugas memiliki bobot yang berbeda seperti gambar di bawah ini.

Untuk menghitung rata-rata tertimbang, gunakan rumus berikut:

=SUMPRODUCT(B2:B6, C2:C6) / SUM(C2:C6)

Penjelasan: Rumus ini: SUMPRODUCT(B2:B6, C2:C6) / SUM(C2:C6) = (B2*C2+B3*C3+B4*C4+B5*C5+B6*C6)/(C2+C3+C4+C5+C6)

Lalu, tekan Enter kunci, rata-rata tertimbang telah dihitung sekaligus, lihat tangkapan layar:


 Lebih banyak artikel dengan fungsi SUMPRODUCT:

  • Hitung Nilai Spesifik Di Beberapa Lembar Kerja
  • Misalkan, saya memiliki beberapa lembar kerja yang berisi data berikut, dan sekarang, saya ingin mendapatkan jumlah kemunculan nilai tertentu "Excel" dari lembar kerja ini. Bagaimana saya bisa menghitung nilai tertentu di beberapa lembar kerja?
  • Hitung Rata-Rata Tertimbang Di Excel
  • Misalnya, Anda memiliki daftar belanja dengan harga, bobot, dan jumlah. Anda dapat dengan mudah menghitung harga rata-rata dengan fungsi AVERAGE di Excel. Tapi bagaimana jika harga rata-rata tertimbang? Pada artikel ini, saya akan memperkenalkan metode untuk menghitung rata-rata tertimbang, serta metode untuk menghitung rata-rata tertimbang jika memenuhi kriteria tertentu di Excel.

Alat Produktivitas Kantor Terbaik

Kutools for Excel - Membantu Anda Menonjol Dari Kerumunan

Fitur Populer: Temukan, Sorot, atau Identifikasi Duplikat  |  Hapus Baris Kosong  |  Gabungkan Kolom atau Sel tanpa Kehilangan Data  |  Putaran tanpa Formula ...
Pencarian Super V: Berbagai Kriteria  |  Nilai Berganda  |  Di Multi-Lembar  |  Pencarian Fuzzy...
Adv. Daftar Tarik-turun: Daftar Drop Down Mudah  |  Daftar Drop Down yang Bergantung  |  Multi-pilih Drop Down List...
Manajer Kolom: Tambahkan Jumlah Kolom Tertentu  |  Pindahkan Kolom  |  Alihkan Status Visibilitas Kolom Tersembunyi  Bandingkan Kolom dengan Pilih Sel yang Sama & Berbeda ...
Fitur Unggulan: Fokus Kisi  |  Tampilan Desain  |  Bar Formula Besar  |  Manajer Buku Kerja & Lembar | Perpustakaan Sumberdaya (Teks otomatis)  |  Pemetik tanggal  |  Gabungkan Lembar Kerja  |  Enkripsi/Dekripsi Sel  |  Kirim Email berdasarkan Daftar  |  Filter Super  |  Filter Khusus (filter tebal/miring/coret...) ...
15 Perangkat Teratas12 Teks Tools (Tambahkan Teks, Hapus Karakter ...)  |  50 + Grafik jenis (Gantt Chart ...)  |  40+ Praktis Rumus (Hitung usia berdasarkan ulang tahun ...)  |  19 Insersi Tools (Masukkan Kode QR, Sisipkan Gambar dari Jalur ...)  |  12 Konversi Tools (Angka ke Kata, Konversi Mata Uang ...)  |  7 Gabungkan & Pisahkan Tools (Lanjutan Gabungkan Baris, Pisahkan Sel Excel ...)  |  ... dan banyak lagi

Kutools for Excel Membanggakan Lebih dari 300 Fitur, Memastikan Apa yang Anda Butuhkan Hanya Dengan Sekali Klik...


Tab Office - Aktifkan Pembacaan dan Pengeditan dengan Tab di Microsoft Office (termasuk Excel)

  • Satu detik untuk beralih di antara lusinan dokumen terbuka!
  • Kurangi ratusan klik mouse untuk Anda setiap hari, ucapkan selamat tinggal pada tangan mouse.
  • Meningkatkan produktivitas Anda sebesar 50% saat melihat dan mengedit banyak dokumen.
  • Menghadirkan Tab Efisien ke Office (termasuk Excel), Sama Seperti Chrome, Edge, dan Firefox.
Comments (0)
No ratings yet. Be the first to rate!
There are no comments posted here yet
Please leave your comments in English
Posting as Guest
×
Rate this post:
0   Characters
Suggested Locations