Note: The other languages of the website are Google-translated. Back to English
Masuk  \/ 
x
or
x
Daftar  \/ 
x

or

Word IF fungsi

Fungsi IF adalah salah satu fungsi paling sederhana dan paling berguna di buku kerja Excel. Ini melakukan tes logika sederhana yang bergantung pada hasil perbandingan, dan mengembalikan satu nilai jika hasilnya BENAR, atau nilai lain jika hasilnya SALAH.


 sintaks:

Sintaks untuk fungsi IF di Excel adalah:

=IF (logical_test, [value_if_true], [value_if_false])

doc jika fungsi 2


 Argumen:

  • logical_test: Yg dibutuhkan. Ini adalah kondisi yang ingin Anda uji.
  • value_if_true: Pilihan. Nilai tertentu yang ingin Anda kembalikan jika hasil logical_test adalah TRUE.
  • value_if_false: Pilihan. Nilai yang ingin Anda kembalikan jika hasil logical_test adalah FALSE.

Catatan:

1. Jika nilai_jika_ benar dihilangkan:

  • Jika nilai_jika_ benar argumen dihilangkan dalam fungsi IF, seperti hanya koma setelah logical_test, itu akan mengembalikan nol ketika kondisi terpenuhi. Sebagai contoh: =IF(C2>100,, "Low ").
  • Jika Anda ingin menggunakan sel kosong dan bukan nol jika syaratnya terpenuhi, Anda harus memasukkan tanda kutip ganda "" ke parameter kedua, seperti ini: =IF(C2>100, "", "Low").
doc jika fungsi 3 doc jika fungsi 4

2. Jika nilai_jika_false dihilangkan:

  • Jika nilai_jika_false parameter dihilangkan dalam fungsi IF, itu akan mengembalikan FALSE ketika kondisi yang ditentukan tidak terpenuhi. Seperti: =IF(C2>100, "High").
  • Jika Anda meletakkan koma setelah argumen value_if_true, itu akan mengembalikan nol ketika kondisi yang ditentukan tidak terpenuhi. Seperti: =IF(C2>100, "High" ,).
  • Jika Anda memasukkan tanda kutip ganda "" ke parameter ketiga, sel kosong akan muncul jika kondisi tidak terpenuhi. Seperti: =IF(C2>100, "High" , "").
doc jika fungsi 5 doc jika fungsi 6 doc jika fungsi 7

 Kembali:

Menguji kondisi tertentu, mengembalikan nilai terkait yang Anda berikan untuk TRUE atau FALSE.


 contoh:

Contoh 1: Menggunakan fungsi IF sederhana untuk angka

Misalnya, Anda ingin menguji daftar nilai, jika nilainya lebih besar dari nilai tertentu 100, teks "Baik" ditampilkan, jika tidak, teks "Buruk" dikembalikan.

Masukkan rumus di bawah ini, dan Anda akan mendapatkan hasil di bawah ini sesuai kebutuhan.

=IF(B2>100,"Good","Bad")

doc jika fungsi 8


Contoh 2: Menggunakan fungsi IF untuk nilai teks

Kasus 1: Fungsi IF untuk nilai teks dengan case insensitive:

Di sini, saya memiliki tabel dengan daftar Tugas dan Status Penyelesaian, sekarang, saya ingin tahu tugas mana yang perlu dijalankan, dan mana yang tidak perlu. Ketika teks di Kolom C selesai, "Tidak" akan ditampilkan, jika tidak, "Ya" akan dikembalikan.

Silakan terapkan rumus berikut, sekarang, sel akan mengembalikan "Tidak" ketika teks di kolom C ditampilkan sebagai "selesai", tidak peduli itu huruf besar atau kecil; jika teks lain di kolom C, "Ya" akan dikembalikan. Lihat tangkapan layar:

=IF(C2="completed", "No", "Yes")

doc jika fungsi 9

Kasus 2: Fungsi IF untuk nilai teks dengan case sensitive:

Untuk menguji nilai teks dengan case sensitive, Anda harus menggabungkan fungsi IF dengan fungsi EXACT, silakan terapkan rumus di bawah ini, maka hanya teks dengan pencocokan tepat yang akan dikenali, dan Anda akan mendapatkan hasil seperti yang Anda inginkan:

=IF(EXACT(C2,"COMPLETED"), "No", "Yes")

doc jika fungsi 10

Kasus 3: Fungsi IF untuk nilai teks dengan kecocokan parsial:

Terkadang, Anda perlu memeriksa nilai sel berdasarkan teks parsial, dalam hal ini, Anda harus menggunakan fungsi IF, ISNUMBER, dan SEARCH secara bersamaan.

Misalnya, jika Anda ingin memeriksa sel yang berisi teks "comp", dan kemudian mengembalikan nilai yang sesuai, harap terapkan rumus di bawah ini. Dan Anda akan mendapatkan hasil seperti gambar di bawah ini:

=IF(ISNUMBER(SEARCH("comp",C2)), "No", "Yes")

doc jika fungsi 11

Catatan:

  • 1. Fungsi SEARCH diterapkan untuk teks dengan case insensitive, jika Anda ingin memeriksa teks dengan case sensitive, Anda harus mengganti fungsi SEARCH dengan fungsi FIND. Seperti ini:=IF(ISNUMBER(FIND("comp",C2)), "No", "Yes")
  • 2. Nilai teks sebagai parameter dalam rumus IF, Anda harus mengapitnya dalam "tanda kutip ganda".

Contoh 3: Menggunakan fungsi IF untuk nilai tanggal

Kasus 1: Fungsi IF untuk tanggal untuk membandingkan tanggal dengan tanggal tertentu:

Jika Anda ingin membandingkan tanggal untuk memeriksa apakah lebih besar atau lebih kecil dari tanggal tertentu, fungsi IF juga dapat membantu Anda. Karena fungsi IF tidak dapat mengenali format tanggal, Anda harus menggabungkan fungsi DATEVALUE dengannya.

Silakan terapkan rumus ini, ketika tanggal lebih besar dari 4/15/2019, "Ya" akan dikembalikan, jika tidak, rumus akan mengembalikan teks "Tidak", lihat tangkapan layar:

=IF(D4>DATEVALUE("4/15/2019"), "Yes", "No")

doc jika fungsi 12

Catatan: Dalam rumus di atas, Anda dapat menggunakan referensi sel secara langsung tanpa menggunakan fungsi DATEVALUE juga. Seperti ini: =IF(D4>$D$1, "Yes", "No").

doc jika fungsi 13

Kasus 2: Fungsi IF untuk tanggal untuk memeriksa tanggal lebih besar atau kurang dari 30 hari:

Jika Anda ingin mengidentifikasi tanggal yang lebih besar atau kurang dari 30 hari dari tanggal sekarang, Anda dapat menggabungkan fungsi TODAY dengan fungsi IF.

Harap masukkan rumus ini:

Identifikasi tanggal yang lebih tua dari 30 hari: =IF(TODAY()-C4>30,"Older date","")

Identifikasi tanggal lebih dari 30 hari: =IF(C4-TODAY()>30, "Future date", "")

doc jika fungsi 14 doc jika fungsi 15

Catatan: Jika Anda ingin memasukkan kedua hasil ke dalam satu kolom, Anda perlu menggunakan fungsi IF bertumpuk seperti ini:

=IF(C4-TODAY()>30, "Future date", IF(TODAY()-C4>30, "Older date", ""))

doc jika fungsi 16


Contoh 4: Menggunakan fungsi IF dengan fungsi AND, OR bersama-sama

Ini adalah penggunaan umum bagi kami untuk menggabungkan fungsi IF, AND, OR bersama-sama di Excel.

Kasus 1: Menggunakan fungsi IF dengan fungsi AND untuk memeriksa apakah semua kondisi benar:

Saya ingin memeriksa apakah semua kondisi yang saya setel terpenuhi, seperti: B4 Merah, C4 Kecil dan D4> 200. Jika semua kondisi TURE, tandai hasilnya sebagai “Yes”; Jika salah satu kondisi FALSE, maka kembalikan "No".

Silakan terapkan rumus ini, dan Anda akan mendapatkan hasil seperti gambar berikut yang ditampilkan:

=IF(AND(B4="Red",C4="Small", D4>200),"Yes","No")

doc jika fungsi 17

Kasus 2: Menggunakan fungsi IF dengan fungsi OR untuk memeriksa salah satu kondisi yang benar:

Anda juga dapat menggunakan fungsi IF dan OR untuk memeriksa apakah salah satu kondisi benar, misalnya, saya ingin mengidentifikasi apakah sel di kolom B berisi teks "Biru" atau "Merah", jika ada teks di kolom B, Ya ditampilkan, jika tidak, Tidak dikembalikan.

Di sini, Anda harus menerapkan rumus ini, dan hasil di bawah ini akan ditampilkan:

=IF(OR(B4="Red",B4="Blue"),"Yes","No")

doc jika fungsi 18

Kasus 3: Menggunakan fungsi IF dengan fungsi AND dan OR secara bersamaan:

Contoh ini, saya akan menggabungkan fungsi IF dengan fungsi AND & OR pada saat bersamaan. Misalkan, Anda harus memeriksa kondisi berikut:

  • Condition 1: Column B = “Red” and Column D > 300;
  • Condition 2: Column B = “Blue” and Column D > 300.

Jika salah satu dari kondisi di atas terpenuhi, Pertandingan dikembalikan, jika tidak, Tidak.

Silakan gunakan rumus ini, dan Anda akan mendapatkan hasil di bawah ini sesuai kebutuhan:

=IF(AND(OR(B4="Red",B4= "Blue"), D4>300), "Match", "No")

doc jika fungsi 19


Contoh 5: Menggunakan fungsi IF Bersarang

Fungsi IF digunakan untuk menguji kondisi dan mengembalikan satu nilai jika kondisi terpenuhi dan nilai lain jika tidak terpenuhi. Namun, terkadang, Anda perlu memeriksa lebih dari satu kondisi pada saat yang sama dan mengembalikan nilai yang berbeda, Anda dapat menggunakan IF Bersarang untuk menyelesaikan tugas ini.

Pernyataan IF bersarang yang menggabungkan beberapa kondisi IF, itu berarti meletakkan pernyataan IF di dalam pernyataan IF lain dan mengulangi proses itu beberapa kali.

Sintaks untuk fungsi IF bersarang di Excel adalah:

=IF (condition1, result1, IF (condition2, result2, IF (condition3, result3,…)))

Catatan: Di Excel 2007 dan versi yang lebih baru, Anda bisa mengumpulkan hingga 64 fungsi IF dalam satu rumus, dan di Excel 2003 dan versi yang lebih lama, hanya 7 fungsi IF bertumpuk yang bisa digunakan.

Kasus 1: Fungsi IF bersarang untuk memeriksa beberapa kondisi:

Penggunaan klasik fungsi IF Bertumpuk adalah untuk menetapkan nilai huruf untuk setiap siswa berdasarkan nilai mereka. Misalnya, Anda memiliki meja dengan siswa dan nilai ujian mereka, sekarang Anda ingin mengklasifikasikan nilai dengan ketentuan berikut:

doc jika fungsi 20

Silakan terapkan rumus ini, dan Anda akan mendapatkan hasil di bawah ini, jika nilainya lebih besar atau sama dengan 90, nilainya "Sangat Baik", jika nilainya lebih besar atau sama dengan 80, nilainya "Baik", jika nilainya lebih besar atau sama dengan 60, nilainya adalah "Sedang", jika tidak, nilainya "Buruk".

=IF(C2>=90, "Excellent", IF(C2>=80, "Good", IF(C2>=60, "Medium", "Poor")))

doc jika fungsi 21

Penjelasan rumus diatas:

doc jika fungsi 22
  • IF(check if C2>=90, if true - returns "Excellent", or else
  • IF(check if C2>=80, if true - returns "Good", or else
  • IF(check if C2>=60, if true - returns "Medium", if false - returns "Poor")))

Kasus 2: Fungsi IF bersarang untuk menghitung harga berdasarkan kuantitas:

Fungsi Nested IF juga dapat digunakan untuk menghitung harga produk berdasarkan kuantitas.

Misalnya, Anda ingin memberi pelanggan potongan harga berdasarkan kuantitas, lebih banyak kuantitas yang mereka beli, lebih banyak diskon yang akan mereka dapatkan seperti gambar di bawah ini.

doc jika fungsi 23

Karena harga total sama dengan kuantitas dikalikan harga, jadi Anda harus mengalikan kuantitas yang ditentukan dengan nilai yang dikembalikan oleh Ifs bertingkat. Silakan gunakan rumus ini:

=D2*IF(D2>=101,16, IF(D2>=50, 21, IF(D2>=25, 26, IF( D2>=11, 30, IF(D2>=1, 39, "")))))

doc jika fungsi 24

Catatan: Anda juga dapat menggunakan referensi sel untuk mengganti angka harga statis, ketika data sumber berubah, Anda tidak perlu memperbarui rumus, silakan gunakan rumus ini: =D2*IF(D2>=101, B6, IF(D2>=50, B5, IF(D2>=25, B4, IF( D2>=11, B3, IF(D2>=1, B2, "")))))

doc jika fungsi 25

Tips: Menggunakan fungsi IF untuk membuat pengujian, Anda dapat menggunakan operator logika berikut:

Operator Arti Contoh Deskripsi
> Lebih besar dari =IF(A1>10, "OK",) Jika nomor di sel A1 lebih besar dari 10, rumus mengembalikan "OK"; jika tidak, 0 dikembalikan.
< Kurang dari =IF(A1<10, "OK", "") Jika nomor di sel A1 kurang dari 10, rumus mengembalikan "OK"; jika tidak, sel kosong dikembalikan.
>= Lebih dari atau sama dengan =IF(A1>=10, "OK", "Bad") Jika nomor di sel A1 lebih besar dari atau sama dengan 10, itu akan mengembalikan "OK"; jika tidak, "Buruk" ditampilkan.
<= Kurang dari atau sama dengan =IF(A1<=10, "OK", "No") Jika nomor di sel A1 kurang dari atau sama dengan 10, ia mengembalikan "OK"; jika tidak, "Tidak" akan dikembalikan.
= Sama dengan =IF(A1=10, "OK", "No") Jika nomor di sel A1 sama dengan 10, ia mengembalikan "OK"; jika tidak, ini akan menampilkan "Tidak".
<> Tidak sebanding dengan =IF(A1<>10, "No", "OK") Jika nomor di sel A1 tidak sama dengan 10, rumus mengembalikan "Tidak"; jika tidak - "OK".

Alat Produktivitas Kantor Terbaik

Kutools for Excel - Membantu Anda Menonjol Dari Kerumunan

Apakah Anda ingin menyelesaikan pekerjaan harian Anda dengan cepat dan sempurna? Kutools for Excel menghadirkan 300 fitur canggih yang canggih (Gabungkan buku kerja, jumlahkan menurut warna, pisahkan konten sel, ubah tanggal, dan sebagainya ...) dan hemat 80% waktu untuk Anda.

  • Dirancang untuk skenario kerja 1500, membantu Anda memecahkan 80% masalah Excel.
  • Kurangi ribuan klik keyboard dan mouse setiap hari, hilangkan mata dan tangan Anda yang lelah.
  • Menjadi ahli Excel dalam 3 menit. Tidak perlu lagi mengingat rumus dan kode VBA yang menyakitkan.
  • Uji coba gratis tanpa batas selama 30 hari. Jaminan uang kembali 60 hari. Upgrade dan dukungan gratis selama 2 tahun.
Ribbon of Excel (dengan Kutools for Excel diinstal)

Tab Office - Aktifkan Pembacaan dan Pengeditan dengan Tab di Microsoft Office (termasuk Excel)

  • Satu detik untuk beralih di antara lusinan dokumen terbuka!
  • Kurangi ratusan klik mouse untuk Anda setiap hari, ucapkan selamat tinggal pada tangan mouse.
  • Meningkatkan produktivitas Anda hingga 50% saat melihat dan mengedit banyak dokumen.
  • Membawa Tab Efisien ke Office (termasuk Excel), Sama Seperti Chrome, Firefox, dan Internet Explorer Baru.
Cuplikan Layar Excel (dengan Office Tab diinstal)

Say something here...
symbols left.
You are guest
or post as a guest, but your post won't be published automatically.
Loading comment... The comment will be refreshed after 00:00.

Be the first to comment.