Excel CHOOSE fungsi
- Ex1 - Penggunaan dasar: menggunakan CHOOSE berfungsi sendiri untuk memilih nilai dari argumen daftar
- Ex2 - Kembalikan hasil berbeda berdasarkan beberapa kondisi
- Ex3 - Kembalikan hasil kalkulasi berbeda berdasarkan kondisi
- Ex4 - Pilih acak dari daftar
- Ex5 - Gabungkan CHOOSE dan VLOOKUP berfungsi untuk mengembalikan nilai di kolom kiri
- Ex6 - Kembalikan hari kerja atau bulan berdasarkan tanggal tertentu
- Ex7 - Kembali ke hari kerja / akhir pekan berikutnya berdasarkan hari ini
Deskripsi Produk
Grafik CHOOSE fungsi mengembalikan nilai dari daftar argumen nilai berdasarkan nomor indeks yang diberikan. Sebagai contoh, CHOOSE(3,”Apple”,”Peach”,”Orange”) mengembalikan Oranye, nomor indeks adalah 3, dan Oranye adalah nilai ketiga setelah nomor indeks dalam fungsi.
sintaks dan Argumen
Sintaks rumus
CHOOSE(index_num, value1, [value2], …) |
kasus
|
Value1, value2… Bisa berupa angka, teks, rumus, referensi sel, atau nama yang ditentukan.
Nilai pengembalian
Grafik CHOOSE fungsi mengembalikan nilai dari daftar berdasarkan posisi yang diberikan.
Penggunaan dan Contoh
Di bagian ini, saya mencantumkan beberapa contoh sederhana namun representatif untuk menjelaskan penggunaan file CHOOSE fungsi.
Ex1 - Penggunaan dasar: menggunakan CHOOSE berfungsi sendiri untuk memilih nilai dari argumen daftar
Formula 1:
=CHOOSE(3,"a","b","c","d")
Kembali: c, yang merupakan argumen ketiga setelah index_num dari 3 di CHOOSE fungsi.
Catatan: menggunakan tanda kutip ganda yang mengelilingi nilai jika itu adalah teks.
Formula 2:
=CHOOSE(2,A1,A2,A3,A4)
Kembali: Kate, nilai A2. Karena index_num adalah 2, dan A2 adalah nilai kedua di CHOOSE fungsi.
Formula 3:
=CHOOSE(4,8,9,7,6)
Kembali: 6, argumen daftar ke-4 dalam fungsi tersebut.
Ex2 - Kembalikan hasil berbeda berdasarkan beberapa kondisi
Misalkan Anda memiliki daftar penyimpangan untuk setiap produk yang perlu diberi label berdasarkan kondisi seperti gambar di bawah ini.
Biasanya, Anda dapat menggunakan fungsi IF untuk menangani, tetapi di sini saya perkenalkan cara menggunakan CHOOSE berfungsi untuk mengatasi masalah ini dengan mudah
Formula:
=CHOOSE((B7>0)+(B7>1)+(B7>5),"Top","Middle","Bottom")
Menjelaskan:
(B7>0)+(B7>1)+(B7>5): index_num, B7 adalah 2, yang lebih besar dari 0 dan 1 tetapi kurang dari 5, jadi kita mendapatkan hasil antara:
=CHOOSE(True+Ture+False,"Top","Middle","Bottom")
Seperti yang kita ketahui, True = 1, False = 0, sehingga rumusnya dapat dilihat sebagai:
=CHOOSE(1+1+0,"Top","Middle","Bottom")
kemudian
=CHOOSE(2,"Top","Middle","Bottom")
Hasil: Tengah
Ex3 - Kembalikan hasil kalkulasi berbeda berdasarkan kondisi
Misalkan Anda perlu menghitung rabat untuk setiap produk berdasarkan jumlah dan harga seperti gambar di bawah ini yang ditampilkan:
Formula:
=CHOOSE((B8>0)+(B8>100)+(B8>200)+(B8>300),B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)
Menjelaskan:
(B8>0)+(B8>100)+(B8>200)+(B8>300): index_number, B8 adalah 102, yang lebih besar dari 100 tetapi kurang dari 201, jadi di bagian ini, ia mengembalikan hasil yang ditunjukkan sebagai:
=CHOOSE(true+true+false+false,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)
=CHOOSE(1+1+0+0,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)
kemudian
=CHOOSE(2,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)
B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5: nilai yang akan dipilih, rabat sama dengan harga * jumlah * rabat persen, karena di sini index_num adalah 2, ia memilih B8 * C8 * 0.2
Pengembalian: 102 * 2 * 0.2 = 40.8
Di Excel, terkadang, Anda mungkin perlu memilih nilai secara acak dari daftar yang diberikan, file CHOOSE fungsi dapat menyelesaikan pekerjaan ini.
Pilih satu nilai secara acak dari daftar:
Formula:
=CHOOSE(RANDBETWEEN(1,5),$D$2,$D$3,$D$4,$D$5,$D$6)
Menjelaskan:
RANDBETWEEN(1,5): index_num, dapatkan nomor secara acak antara 1 hingga 5
$D$2,$D$3,$D$4,$D$5,$D$6: daftar nilai yang akan dipilih
Ex5 - Gabungkan CHOOSE dan VLOOKUP berfungsi untuk mengembalikan nilai di kolom kiri
Umumnya, kami menggunakan fungsi VLOOKUP =VLOOKUP (value, table, col_index, [range_lookup]) untuk mengembalikan nilai berdasarkan nilai yang diberikan dari rentang tabel. Tapi dengan VLOOKUP fungsi, itu akan mengembalikan nilai kesalahan sedangkan kolom kembali ada di sebelah kiri kolom pencarian seperti gambar di bawah ini yang ditampilkan:
Dalam hal ini, Anda dapat menggabungkan file CHOOSE berfungsi dengan fungsi VLOOKUP untuk memecahkan masalah.
Formula:
=VLOOKUP(E1,CHOOSE({1,2},B1:B7,A1:A7),2,FALSE)
Menjelaskan:
CHOOSE({1,2},B1:B7,A1:A7): sebagai argumen table_range dalam fungsi VLOOKUP. {1,2} berarti menampilkan 1 atau 2 sebagai argumen index_num berdasarkan argumen col_num dalam fungsi VLOOKUP. Di sini, col_num dalam fungsi VLOOKUP adalah 2, jadi CHOOSE fungsi tampilan sebagai CHOOSE(2, B1:B7,A1:A7), berarti memilih nilai dari A1: A7.
Ex6 - Kembalikan hari kerja atau bulan berdasarkan tanggal tertentu
Dengan CHOOSE fungsi, Anda juga dapat mengembalikan hari kerja dan bulan relatif berdasarkan tanggal tertentu.
Formula 1: kembali hari kerja dengan tanggal
=CHOOSE(WEEKDAY(),"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday")
Menjelaskan:
WEEKDAY(): argumen index_num, untuk mendapatkan nomor hari kerja dari tanggal yang ditentukan, misalnya, WEEKDAY (A5) mengembalikan 6, maka argumen index_num adalah 6.
"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday": argumen daftar nilai, dimulai dengan "Minggu" karena nomor hari kerja "1" menunjukkan "Minggu".
Formula 2: kembali bulan dengan tanggal
=CHOOSE(MONTH(),"Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")
Menjelaskan:
MONTH(): Argumen index_num, yang mendapatkan nomor bulan dari tanggal yang ditentukan, misalnya, MONTH (A5) mengembalikan 3.
Ex7 - Kembali ke hari kerja / akhir pekan berikutnya berdasarkan hari ini
Dalam pekerjaan sehari-hari, Anda mungkin ingin menghitung hari kerja atau akhir pekan berikutnya berdasarkan hari ini. Di sini CHOOSE fungsi juga dapat membantu Anda.
Misalnya, hari ini 12/20/2018, Kamis, sekarang Anda perlu mendapatkan hari kerja dan akhir pekan berikutnya.
Formula 1: dapatkan tanggal hari ini
=TODAY()
Hasil: 12/20/2018
Formula 2: dapatkan nomor hari kerja hari ini
=WEEKDAY(TODAY())
Hasil: 5 (sementara hari ini 12/20/2018)
Daftar nomor hari kerja seperti gambar di bawah ini yang ditampilkan:
Formula 3: dapatkan hari kerja berikutnya
=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)
Menjelaskan:
Today(): mengembalikan tanggal sekarang
WEEKDAY(TODAY()): argumen index_num di CHOOSE fungsi, dapatkan nomor hari kerja hari ini, misalnya, Minggu adalah 1, Senin adalah 2…
1,1,1,1,1,3,2: argumen daftar nilai di CHOOSE fungsi. Misalnya, jika hari kerja (hari ini ()) mengembalikan 1 (Minggu), ia memilih 1 bentuk daftar nilai, maka seluruh rumus berubah menjadi = Hari Ini () + 1, yang berarti menambahkan 1 hari untuk kembali Senin depan. Jika hari kerja (hari ini ()) mengembalikan 6 (Jumat), ia memilih 3 dari daftar nilai, karena Jumat berjarak 3 hari dari Senin depan.
Hasil (sementara hari ini 12/20/2018):
=12/20/2018+CHOOSE(5,1,1,1,1,1,3,2)
= 12/20/2018 + 1
= 12/21/2018
Formula 4: dapatkan hari akhir pekan berikutnya
=TODAY()+CHOOSE(WEEKDAY(TODAY()),6,5,4,3,2,1,1)
Menjelaskan:
6,5,4,3,2,1,1: argumen daftar nilai di CHOOSE fungsi. Misalnya, jika hari kerja (hari ini ()) mengembalikan 1 (Minggu), ia memilih 6 dari daftar nilai, maka seluruh rumus berubah menjadi = Hari Ini () + 6, yang berarti menambahkan 6 hari dan kembali Sabtu depan.
Hasil:
=12/20/2018+CHOOSE(5,6,5,4,3,2,1,1)
= 12/20/2018 + 2
= 12/22/2018
Alat Produktivitas Kantor Terbaik
Kutools for Excel - Membantu Anda Menonjol Dari Kerumunan
Kutools for Excel Membanggakan Lebih dari 300 Fitur, Memastikan Apa yang Anda Butuhkan Hanya Dengan Sekali Klik...
Tab Office - Aktifkan Pembacaan dan Pengeditan dengan Tab di Microsoft Office (termasuk Excel)
- Satu detik untuk beralih di antara lusinan dokumen terbuka!
- Kurangi ratusan klik mouse untuk Anda setiap hari, ucapkan selamat tinggal pada tangan mouse.
- Meningkatkan produktivitas Anda sebesar 50% saat melihat dan mengedit banyak dokumen.
- Menghadirkan Tab Efisien ke Office (termasuk Excel), Sama Seperti Chrome, Edge, dan Firefox.