Ikuti langkah-langkah di bawah ini untuk menyalin struktur folder Outlook ke desktop atau windows explorer.

1. Pada Panel Navigasi, klik untuk menyorot folder tertentu yang struktur foldernya akan Anda salin, dan tekan lain + F11 kunci untuk membuka jendela Microsoft Visual Basic for Applications.

2. klik Tools > Referensi untuk membuka kotak dialog Referensi. Kemudian di kotak dialog centang Runtime Microsoft Scripting pilihan, dan klik OK tombol. Lihat tangkapan layar:

3. klik Menyisipkan > Modul, dan salin dan tempel kode VBA di bawah ini ke jendela modul baru.

VBA: Salin struktur folder Outlook ke windows explorer

Dim xFSO As Scripting.FileSystemObject
Sub CopyOutlookFldStructureToWinExplorer()
    ExportAction "Copy"
End Sub
  
Sub ExportAction(xAction As String)
Dim xFolder As Outlook.Folder
Dim xFldPath As String
xFldPath = SelectAFolder()
If xFldPath = "" Then
    MsgBox "You did not select a folder. Export cancelled.", vbInformation + vbOKOnly, "Kutools for Outlook"
Else
    Set xFSO = New Scripting.FileSystemObject
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    ExportOutlookFolder xFolder, xFldPath
End If
Set xFolder = Nothing
Set xFSO = Nothing
End Sub

Sub ExportOutlookFolder(ByVal OutlookFolder As Outlook.Folder, xFldPath As String)
Dim xSubFld As Outlook.Folder
Dim xItem As Object
Dim xPath As String
Dim xFilePath As String
Dim xSubject As String
Dim xCount As Integer
Dim xFilename As String
On Error Resume Next
xPath = xFldPath & "\" & OutlookFolder.Name
'?????????,??????
If Dir(xPath, 16) = Empty Then MkDir xPath
For Each xItem In OutlookFolder.Items
    xSubject = ReplaceInvalidCharacters(xItem.Subject)
    xFilename = xSubject & ".msg"
    xCount = 0
    xFilePath = xPath & "\" & xFilename
    If xFSO.FileExists(xFilePath) Then
        xCount = xCount + 1
        xFilename = xSubject & " (" & xCount & ").msg"
        xFilePath = xPath & "\" & xFilename
    End If
    xItem.SaveAs xFilePath, olMSG
Next
For Each xSubFld In OutlookFolder.Folders
    ExportOutlookFolder xSubFld, xPath
Next
Set OutlookFolder = Nothing
Set xItem = Nothing
End Sub

Function SelectAFolder() As String
Dim xSelFolder As Object
Dim xShell As Object
On Error Resume Next
Set xShell = CreateObject("Shell.Application")
Set xSelFolder = xShell.BrowseForFolder(0, "Select a folder", 0, 0)
If Not TypeName(xSelFolder) = "Nothing" Then
    SelectAFolder = xSelFolder.self.Path
End If
Set xSelFolder = Nothing
Set xShell = Nothing
End Function
  
Function ReplaceInvalidCharacters(Str As String) As String
Dim xRegEx
Set xRegEx = CreateObject("vbscript.regexp")
xRegEx.Global = True
xRegEx.IgnoreCase = False
xRegEx.Pattern = "\||\/|\<|\>|""|:|\*|\\|\?"
ReplaceInvalidCharacters = xRegEx.Replace(Str, "")
End Function

4. tekan F5 atau klik Run tombol untuk menjalankan VBA ini.

5. Pada kotak dialog Telusuri Folder yang muncul, pilih folder tertentu tempat Anda akan meletakkan struktur folder yang disalin, dan klik OK tombol. Lihat tangkapan layar:

Sekarang masuk ke folder yang ditentukan, Anda akan melihat struktur folder disalin ke hard disk yang ditentukan. Lihat tangkapan layar:

Note: item folder, seperti email, janji temu, tugas, dll. juga disalin ke folder terkait di hard disk.

Bagaimana cara menyalin struktur folder ke file data pst baru di Outlook?