Bagaimana cara menyimpan kategori saat membalas atau meneruskan email di Outlook?

Biasanya, ketika Anda membalas atau meneruskan email yang telah saya kategorikan, kategori tersebut akan dihapus secara otomatis pada email yang dikirim. Jika Anda ingin mempertahankan kategori pada email keluar dalam membalas atau meneruskan, artikel ini akan memperkenalkan metode untuk menghadapinya.

Pertahankan kategori saat membalas atau meneruskan email dengan kode VBA

Pertahankan kategori saat membalas atau meneruskan email dengan kode VBA

1. Tahan ALT + F11 kunci untuk membuka Microsoft Visual Basic untuk Aplikasi jendela.

2. di Microsoft Visual Basic untuk Aplikasi jendela, klik dua kali Sesi Pandangan ini dari Project1 (VbaProject.OTM) panel untuk membuka mode, lalu salin dan tempel kode berikut ke dalam modul kosong.

Kode VBA: Pertahankan kategori saat membalas atau meneruskan email:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

doc simpan kategori reply 1

3. Kemudian simpan dan tutup jendela kode ini, tutup dan mulai ulang Outlook, sekarang, saat Anda membalas atau meneruskan email dengan kategori, kategori tersebut akan disimpan di pesan keluar di Item terkirim, lihat tangkapan layar:

doc simpan kategori reply 2