Bagaimana cara mengekspor alamat email berdasarkan domain tertentu di Outlook?

Jika Anda ingin mengekspor alamat email dengan domain tertentu dari semua kontak di Outlook Anda, silakan baca tutorial ini yang akan membantu Anda menerapkan kode VBA untuk mengekstrak semua alamat email di domain tertentu ke file teks seperti gambar di bawah ini. .

Ekspor alamat email berdasarkan domain tertentu di Outlook dengan kode VBA

Untuk mengekstrak semua alamat email dengan domain tertentu dari semua kontak, lakukan dengan langkah-langkah berikut:

1. Buat file teks baru dan beri nama untuk itu, lihat tangkapan layar:

2. Tahan ALT + F11 kunci untuk membuka Microsoft Visual Basic untuk Aplikasi jendela.

3. Lalu klik Menyisipkan > Modul, dan tempel kode berikut di Module Window.

Kode VBA: Ekspor alamat email berdasarkan domain tertentu

Dim GDomain As String
Dim GFileSystem As Object
Dim GFilePath As String
Dim GFileObj As Object
Private Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hWnd As Long, _
  ByVal ipOperation As String, ByVal lpFile As String, _
  ByVal lpParameters As String, ByVal lpDirectory As String, _
  ByVal nShowCmd As Long) As Long

Sub ExportListOfEmailAddressesInSpecificDomain()
'Updateby ExtendOffice
Dim xStore As Store
Dim xFolder As Folder
On Error Resume Next
GDomain = InputBox("Enter domain(@***.com):", "Kutools for Outlook")
If Len(GDomain) <> 0 Then
  GFilePath = "C:\Users\skyyang\Desktop\Email Addresses with specific domain.txt" 'Specify the file path
  Set GFileSystem = CreateObject("Scripting.FileSystemObject")
  Set GFileObj = GFileSystem.CreateTextFile(GFilePath, True)
  For Each xStore In Application.Session.Stores
    For Each xFolder In xStore.GetRootFolder.Folders
      If xFolder.DefaultItemType = olContactItem Then
        Call ProcessFolders(xFolder)
      End If
    Next
  Next
  GFileObj.Close
  ShellExecute 0&, vbNullString, GFilePath, vbNullString, vbNullString, 1
End If
End Sub

Sub ProcessFolders(ByVal Fld As Outlook.Folder)
Dim xContactItems As Items
Dim I As Long
Dim xContact As ContactItem
Dim xSubFolder As Folder
On Error Resume Next
Set xContactItems = Fld.Items
For I = xContactItems.Count To 1 Step -1
  If xContactItems(I).Class = olContact Then
    Set xContact = xContactItems(I)
    If InStr(xContact.Email1Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email1Address & vbCrLf)
    ElseIf InStr(xContact.Email2Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email2Address & vbCrLf)
    ElseIf InStr(xContact.Email3Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email3Address & vbCrLf)
    End If
  End If
Next
If Fld.Folders.Count > 0 Then
  For Each xSubFolder In Fld.Folders
    If xSubFolder.DefaultItemType = olContactItem Then
      Call ProcessFolders(xSubFolder)
    End If
  Next
End If
End Sub

Note: Pada kode di atas, ubah jalur file "C:\Users\skyyang\Desktop\Alamat Email dengan domain tertentu.txt" untuk Anda sendiri.

4. Lalu, tekan F5 kunci untuk menjalankan kode ini. Sebuah kotak prompt muncul, silakan ketik domain email yang ingin Anda ekspor berdasarkan alamat email, lihat tangkapan layar: