Tutorial Excel: membagi teks, angka, dan sel tanggal (dipisahkan menjadi beberapa kolom)

Saat menggunakan Excel, Anda mungkin perlu membagi teks dari satu sel menjadi beberapa sel untuk beberapa tujuan. Tutorial ini dibagi menjadi tiga bagian: sel teks split, sel nomor split dan sel tanggal split. Setiap bagian memberikan contoh berbeda untuk membantu Anda mengetahui cara menangani pekerjaan pemisahan saat menghadapi masalah yang sama.

---

1 Pisahkan sel teks

Bagian ini mengumpulkan situasi yang akan Anda hadapi saat memisahkan sel teks menjadi beberapa kolom, dan menyediakan metode yang sesuai untuk Anda.

Contoh #1 Pisahkan sel dengan koma, spasi, atau pembatas lainnya

Untuk membagi sel teks menjadi beberapa kolom dengan pembatas tertentu seperti koma, spasi, tanda hubung, dan sebagainya, Anda dapat menerapkan salah satu metode di bawah ini.

Pisahkan sel dengan pembatas dengan fitur Text to Columns

Grafik Teks ke Kolom fitur, sebagai Excel built-in, sering digunakan dalam membelah sel. Seperti yang ditunjukkan pada tangkapan layar di bawah, untuk membagi sel di kolom String Teks dengan koma, Anda dapat menerapkan fitur Teks ke Kolom sebagai berikut.

1. Pilih rentang kolom yang ingin Anda pisahkan dengan koma, klik Data > Teks ke Kolom.

2. Dalam Convert Text to Columns Wizard - Langkah 1 dari 3 kotak dialog, pertahankan Terbatas tombol radio yang dipilih, lalu klik tombol Selanjutnya .

3. Dalam Convert Text to Columns Wizard - Langkah 2 dari 3 kotak dialog, tentukan pembatas sesuai dengan kebutuhan Anda (dalam hal ini, saya hanya mencentang Koma kotak centang), lalu klik tombol Selanjutnya .

4. Pada kotak dialog langkah terakhir, klik tombol untuk memilih sel untuk menampilkan teks yang dipisahkan, lalu klik tombol Finish .

Kemudian teks dalam rentang yang dipilih dipisahkan dengan koma dan ditempatkan di kolom yang berbeda seperti yang ditunjukkan di bawah ini.

Pisahkan sel dengan pembatas dengan rumus

Anda dapat menerapkan rumus di bawah ini untuk memisahkan teks dalam sel dengan pembatas tertentu di Excel.

Formula umum

=TRIM(MID(SUBSTITUTE(A1,delim,REPT(" ",LEN(A1))),(N-1)*LEN(A1)+1,LEN(A1)))

kasus

Kemudian lanjutkan untuk menerapkan formula ini.

1. Seperti yang ditunjukkan pada tangkapan layar di bawah, pertama, Anda perlu membuat baris pembantu dengan nomor 1, 2, 3 ... yang terletak di sel yang berbeda.

Note: Di sini 1, 2, 3... mewakili substring pertama, kedua, dan ketiga dari string teks.

2. Pilih sel di bawah sel nomor 1, salin atau masukkan rumus di bawah ini ke dalamnya dan tekan tombol Enter kunci untuk mendapatkan substring pertama dari string teks. Pilih sel hasil, seret nya Tuas IsiOtomatis kanan dan bawah untuk mendapatkan substring lainnya. Lihat tangkapan layar:

=TRIM(MID(SUBSTITUTE($B5,",",REPT(" ",LEN($B5))),(D$4-1)*LEN($B5)+1,LEN($B5)))

Note: Dalam rumusnya, ",” adalah pembatas yang digunakan untuk memisahkan string teks di B5. Anda dapat mengubahnya sesuai dengan kebutuhan Anda.

Pisahkan sel dengan pembatas dengan alat yang luar biasa

Di sini merekomendasikan Kutools untuk Excel'S Pisahkan Sel fitur untuk membantu Anda dengan mudah membagi sel menjadi kolom atau baris terpisah dengan pembatas tertentu di Excel.

1. Setelah menginstal Kutools untuk Excel, pilih rentang tempat Anda ingin membagi string teks, lalu klik Kutools > Gabungkan & Pisahkan > Pisahkan Sel.

2. Dalam Pisahkan Sel kotak dialog, Anda perlu mengkonfigurasi sebagai berikut.

3. Selanjutnya Pisahkan Sel kotak dialog, pilih sel untuk menampilkan substring, lalu klik OK.

Kemudian substring dipecah menjadi kolom atau baris yang berbeda berdasarkan yang Anda tentukan pada langkah 2 di atas.

Pisahkan menjadi kolom:

Pisahkan menjadi beberapa baris:

Contoh #2 Pisahkan sel dengan panjang tertentu

Untuk membagi string teks dengan panjang tertentu, metode berikut dapat membantu Anda.

Pisahkan sel dengan panjang tertentu dengan fitur Text to Columns

Grafik Teks ke Kolom fitur menyediakan Lebar tetap opsi untuk membantu Anda membagi string teks dalam sel yang dipilih dengan panjang tertentu di Excel.

Seperti yang ditunjukkan pada tangkapan layar di bawah, untuk membagi teks dalam rentang B5:B9 menjadi kolom setiap 3 karakter, Anda dapat melakukan hal berikut untuk menyelesaikannya.

1. Pilih sel tempat Anda ingin membagi string teks.

2. klik Data > Teks ke Kolom.

3. Dalam Konversi Teks ke Kolom Wizard – langkah 1 dari 3 kotak dialog, pilih Lebar tetap tombol radio dan klik Selanjutnya.

4. Kemudian Langkah 2 dari 3 kotak dialog muncul. Dalam Pratinjau data bagian, klik pada posisi yang diinginkan pada sumbu untuk membuat garis putus-putus (garis dengan panah). Setelah membuat semua garis putus, klik tombol Selanjutnya tombol untuk melanjutkan.

Dalam hal ini, saya membuat garis putus untuk setiap 3 karakter dalam string teks.

5. Pada wizard langkah terakhir, pilih sel untuk menampilkan teks yang dipisahkan, lalu klik tombol Finish .

Sekarang string teks dalam sel yang dipilih dibagi setiap 3 karakter seperti yang ditunjukkan pada gambar di bawah.

Pisahkan sel dengan panjang tertentu dengan alat yang luar biasa

Untuk membagi sel dengan panjang tertentu di Excel, Anda dapat menerapkan: Pisahkan Sel fitur dari Kutools untuk Excel untuk menyelesaikannya dengan mudah.

1. Pilih sel string teks yang ingin Anda pisahkan dengan panjang tertentu, klik Kutools > Gabungkan & Pisahkan > Pisahkan Sel.

2. Dalam Pisahkan Sel kotak dialog, Anda perlu mengkonfigurasi sebagai berikut.

3. Selanjutnya Pisahkan Sel kotak dialog, pilih sel untuk menempatkan teks yang membelah dan kemudian klik OK.

Kemudian string teks dalam sel yang dipilih dibagi dengan panjang tertentu dan ditempatkan di kolom yang berbeda.

Contoh #3 Pisahkan sel dengan kata tertentu

Seperti yang ditunjukkan pada tangkapan layar di bawah, untuk membagi string teks dalam rentang B5:B9 dengan seluruh kata "penjualan", Anda dapat menerapkan rumus yang disediakan di bagian ini.

Dapatkan substring sebelum kata tertentu dalam sel

Menerapkan rumus berdasarkan fungsi LEFT dan FIND dapat membantu mendapatkan substring sebelum kata tertentu dalam string teks.

Formula umum

=LEFT(A1,FIND("certain_word", A1)-1)

kasus

1. Pilih sel kosong, salin atau masukkan rumus di bawah ini ke dalamnya dan tekan tombol Enter kunci untuk mendapatkan substring sebelum kata tertentu. Pilih sel hasil ini, lalu seret Tuas IsiOtomatis bawah untuk menerapkan rumus ke sel lain.

=LEFT(B5,FIND("sales",B5)-1)

Dapatkan substring setelah kata dalam sel

Setelah mendapatkan substring sebelum kata, Anda perlu menerapkan rumus di bawah ini untuk mendapatkan substring setelahnya.

Formula umum

=TRIM(MID(A1,SEARCH("certain_word",A1)+LEN("certain_word"),255))

kasus

1. Pilih sel kosong di sebelah sel hasil pertama (D5).

2. Salin atau masukkan rumus di bawah ini ke dalamnya dan tekan tombol Enter kunci. Pilih sel hasil ini, seret Tuas IsiOtomatis turun untuk mendapatkan hasil lainnya.

=TRIM(MID(B5,SEARCH("sales",B5)+LEN("sales"),255))

Sekarang Anda telah membagi string teks menjadi kolom yang berbeda dengan seluruh kata.

Contoh #4 Pisahkan sel dengan jeda baris

Bagian ini menunjukkan metode yang berbeda untuk membantu Anda membagi sel teks menurut pemisah baris di Excel.

Pisahkan sel dengan jeda baris dengan fitur Teks ke Kolom

Fitur Text to Columns dapat diterapkan untuk memisahkan sel dengan jeda baris di Excel. Anda dapat melakukan sebagai berikut.

1. Pilih rentang sel tempat Anda ingin membagi teks menurut jeda baris.

2. klik Data > Teks ke Kolom.

3. Dalam Convert Text to Columns Wizard - Langkah 1 dari 3 kotak dialog, pilih Terbatas tombol radio dan kemudian klik Selanjutnya;

4. Dalam Langkah 2 dari 3 kotak dialog, hapus centang yang ada Pembatas pilihan, periksa Lainnya kotak centang, lalu tekan tombol Ctrl + J jalan pintas. Anda dapat melihat bahwa hanya sedikit titik yang ditampilkan di kotak teks, lalu di Pratinjau data kotak, teks dipisahkan oleh jeda baris. Klik Selanjutnya .

5. Pada wizard langkah terakhir, pilih sel tujuan untuk menampilkan teks yang dipisahkan, lalu klik tombol Finish .

Kemudian teks dalam sel yang dipilih dibagi menjadi kolom yang berbeda dengan jeda baris.

Pisahkan sel dengan jeda baris dengan rumus

Rumus berikut juga dapat membantu untuk membagi sel dengan jeda baris di Excel.

Menggunakan contoh yang sama seperti di atas, setelah membelah, Anda akan mendapatkan tiga substring di kolom yang berbeda.

Dapatkan substring sebelum jeda baris pertama

Pertama, kita dapat menerapkan rumus berdasarkan KIRI dan CARI berfungsi untuk membagi substring sebelum jeda baris pertama dalam sel.

Formula umum

=LEFT(cell, SEARCH(CHAR(10),cell,1)-1)

kasus

1. Pilih sel kosong (dalam hal ini D5), salin atau masukkan rumus di bawah ini ke dalamnya dan tekan tombol Enter kunci. Pilih sel hasil dan seret Tuas IsiOtomatis down untuk mendapatkan substring sebelum jeda baris pertama dari sel lain.

=KIRI(B5, SEARCH(CHAR(10),B5,1)-1)

Dapatkan substring antara jeda baris pertama dan kedua

Untuk mendapatkan substring antara jeda baris pertama dan kedua dalam sel, rumus berikut dapat membantu Anda.

Formula umum

=MID(cell,SEARCH(CHAR(10),cell)+1,SEARCH(CHAR(10),cell,SEARCH(CHAR(10),cell)+1)-SEARCH(CHAR(10),cell)-1)

kasus

1. Pilih sel (E5) di sebelah D5, salin atau masukkan rumus di bawah ini ke dalamnya dan tekan tombol Enter kunci. Pilih sel hasil dan seret Tuas IsiOtomatis down untuk mendapatkan substring antara jeda baris pertama dan kedua dari sel lain.

=MID(B5, SEARCH(CHAR(10),B5) + 1, SEARCH(CHAR(10),B5,SEARCH(CHAR(10),B5)+1) - SEARCH(CHAR(10),B5) - 1 )

Dapatkan substring setelah jeda baris kedua

Langkah pertama adalah mendapatkan substring setelah jeda baris kedua dengan rumus di bawah ini.

Formula umum

=RIGHT(cell,LEN(cell) - SEARCH(CHAR(10),cell, SEARCH(CHAR(10), cell) + 1))

kasus

1. Pilih sel (F5 dalam hal ini), salin atau masukkan rumus di bawah ini ke dalamnya dan tekan tombol Enter kunci. Pilih sel hasil dan seret Pegangan IsiOtomatisnya ke bawah untuk mendapatkan substring setelah jeda baris kedua dari sel lain.

=KANAN(B5,LEN(B5) - SEARCH(CHAR(10), B5, SEARCH(CHAR(10), B5) + 1))

Pisahkan sel dengan jeda baris dengan VBA

Bagian ini menyediakan kode VBA untuk membantu Anda dengan mudah membagi teks dalam sel yang dipilih dengan jeda baris di Excel.

1. tekan lain + F11 kunci untuk membuka Microsoft Visual Basic untuk Aplikasi jendela.

2. Dalam Microsoft Visual Basic untuk Aplikasi window, klik Menyisipkan > Modul. Kemudian salin VBA di bawah ini ke jendela Kode.

Kode VBA: pisahkan sel dengan jeda baris di Excel

Sub ExtendOffice_SplitRangeTex()
'Updated by Extendoffice 20211116
Dim xStr() As String
Dim xRg As Range
Dim xCell As Range
Dim xI As Integer
Set xRg = Application.InputBox("Please select the range of cells where you want to split by line break:", "Kutools for Excel", "", , , , , 8)
If xRg Is Nothing Then Exit Sub
For xI = 1 To xRg.Count
    Set xCell = xRg.Item(xI)
    xStr = VBA.Split(xCell.Value, vbLf)
    xCell.Resize(1, UBound(xStr) + 1).Offset(0, 1) = xStr
Next
End Sub

3. tekan F5 kunci untuk menjalankan kode. Kemudian a Kutools untuk Excel kotak dialog muncul, Anda harus memilih rentang sel yang ingin Anda pisahkan dengan jeda baris, dan akhirnya klik tombol OK .

Kemudian teks dalam sel yang dipilih dipecah menjadi kolom yang berbeda sekaligus dengan jeda baris.

Pisahkan sel dengan jeda baris dengan alat yang luar biasa

Di sini perkenalkan alat praktis - Pisahkan Sel kegunaan Kutools untuk Excel. Dengan alat ini, Anda dapat membagi teks dalam sel yang dipilih secara massal dengan jeda baris hanya dengan beberapa klik.

1. Pilih rentang sel tempat Anda ingin membagi teks menurut jeda baris.

2. klik Kutools > Gabungkan & Pisahkan > Pisahkan Sel untuk mengaktifkan fitur.

3. Dalam Pisahkan Sel kotak dialog, Anda perlu membuat pengaturan berikut.

4. Pada popping up berikutnya Pisahkan Sel kotak dialog, pilih sel kosong untuk menempatkan teks yang dipisahkan, dan klik OK.

Kemudian teks dalam sel yang dipilih dibagi menjadi kolom yang berbeda dengan jeda baris seperti yang ditunjukkan pada gambar di bawah.

Contoh #5 Pisahkan sel dengan pembatas pertama atau terakhir saja

Kadang-kadang, Anda mungkin perlu membagi sel menjadi dua bagian mengacu pada pembatas pertama atau terakhir saja, Anda dapat mencoba rumus di bawah ini.

Pisahkan sel dengan pembatas pertama dengan rumus

Seperti yang ditunjukkan pada tangkapan layar di bawah, untuk membagi setiap sel dalam rentang B5:B9 menjadi dua bagian dengan spasi pertama, Anda perlu menerapkan dua rumus.

Pisahkan substring sebelum spasi pertama

Untuk membagi substring sebelum spasi pertama, Anda dapat menggunakan rumus berdasarkan fungsi LEFT dan fungsi FIND.

Formula umum

=LEFT(cell,FIND("delimiter",cell)-1)

kasus

1. Pilih sel (D5 dalam hal ini) untuk menampilkan substring, salin atau masukkan rumus di bawah ini ke dalamnya dan tekan tombol Enter kunci. Pilih sel hasil lalu seret Tuas IsiOtomatis turun untuk mendapatkan substring dari sel lain.

=LEFT(B5,FIND(" ",B5)-1)

Pisahkan substring setelah spasi pertama

Kemudian terapkan rumus di bawah ini untuk mendapatkan substring setelah spasi pertama dalam sel.

Formula umum

=RIGHT(cell,LEN(cell)-FIND("delimiter",cell))

kasus

1. Salin atau masukkan rumus di bawah ini ke dalam sel E5 dan tekan tombol Enter kunci untuk mendapatkan hasil. Pilih sel hasil ini dan seret Tuas IsiOtomatis down untuk mendapatkan substring setelah spasi terakhir dari sel lain.

=RIGHT(B5,LEN(B5)-FIND(" ",B5))

Note: Dalam rumus, Anda dapat mengubah referensi sel ke string teks dan pembatas sesuai dengan kebutuhan Anda.

Pisahkan sel dengan pembatas terakhir dengan rumus

Untuk membagi teks dalam rentang sel (B5:B9) menjadi dua bagian dengan spasi terakhir seperti yang ditunjukkan pada tangkapan layar, dua rumus yang disediakan di bagian ini dapat membantu Anda menyelesaikannya.

Dapatkan teks di sebelah kiri pembatas terakhir

Untuk mendapatkan teks di sebelah kiri pembatas terakhir dalam sel, Anda dapat menerapkan rumus di bawah ini.

Formula umum

=LEFT(B5,SEARCH("^",SUBSTITUTE(cell,"delimiter","^",LEN(cell)-LEN(SUBSTITUTE(cell,"delimiter",""))))-1)

kasus

1. Pilih sel untuk menempatkan substring kiri, salin atau masukkan rumus di bawah ini ke dalamnya dan tekan tombol Enter kunci. Pilih sel hasil dan seret Tuas IsiOtomatis bawah untuk menerapkan rumus ke sel lain.

=LEFT(B5,SEARCH("^",SUBSTITUTE(B5," ","^",LEN(B5)-LEN(SUBSTITUTE(B5," ",""))))-1)

Dapatkan teks di sebelah kanan pembatas terakhir

Sekarang kita perlu menempatkan teks di sebelah kanan spasi terakhir dalam kasus ini.

Formula umum

=TRIM(RIGHT(SUBSTITUTE(cell,"delimiter",REPT("delimiter",LEN(cell))),LEN(cell)))

kasus

1. Pilih sel untuk menempatkan substring kanan, salin atau masukkan rumus di bawah ini ke dalamnya dan tekan tombol Enter kunci. Pilih sel hasil dan seret Pegangan IsiOtomatisnya ke bawah untuk menerapkan rumus ke sel lain.

=TRIM(RIGHT(SUBSTITUTE(B5," ",REPT(" ",LEN(B5))),LEN(B5)))

Note: Dalam rumus, Anda dapat mengubah referensi sel ke string teks dan pembatas sesuai dengan kebutuhan Anda.

Contoh #6 Pisahkan sel dengan huruf kapital

Bagian ini memperkenalkan fungsi yang ditentukan pengguna untuk membagi kata dalam sel dengan huruf kapital.

1. tekan lain + F11 kunci untuk membuka Microsoft Visual Basic untuk Aplikasi jendela.

2. Dalam Microsoft Visual Basic untuk Aplikasi window, klik Menyisipkan > Modul, lalu salin kode VBA di bawah ini ke jendela Kode.

Kode VBA: Pisahkan sel dengan huruf kapital di Excel

Function GetName(s As String, Num As Long) As String
'Updated by Extendoffice 20211116
  With CreateObject("VBSCript.RegExp")
    .Global = True
    .Pattern = "[A-Z][a-z]+|[A-Z]"
    GetName = .Execute(s).Item(Num - 1)
  End With
End Function

3. tekan lain + Q kunci untuk menutup Microsoft Visual Basic untuk Aplikasi jendela.

4. Pilih sel (D5 dalam hal ini) untuk menampilkan kata di sebelah kiri huruf kapital pertama, masukkan rumus di bawah ini ke dalamnya dan tekan tombol Enter kunci. Pilih sel hasil ini dan seret Tuas IsiOtomatis kanan kemudian ke bawah untuk mendapatkan kata-kata lain.

=IFERROR(GetName($B5,COLUMNS($D:D)),"")

Note: Dalam kode, $B5 adalah sel yang akan Anda bagi, $D:D adalah kolom dari sel hasil. Silakan ubah sesuai dengan data Anda sendiri.

Contoh #7 Pisahkan nama dalam sel

Misalkan Anda memiliki lembar kerja yang berisi kolom nama lengkap, dan ingin membagi nama lengkap menjadi kolom terpisah seperti membagi nama depan dan belakang dari nama lengkap, atau membagi nama depan, tengah atau belakang dari nama lengkap. Bagian ini mencantumkan langkah-langkah terperinci untuk membantu Anda memecahkan masalah ini.

Bagi nama lengkap menjadi nama depan dan belakang

Seperti yang ditunjukkan pada tangkapan layar di bawah, nama depan, nama tengah, dan nama belakang dipisahkan oleh satu spasi, untuk memisahkan hanya nama depan dan nama belakang dari nama lengkap dan meletakkannya di kolom yang berbeda, Anda dapat menerapkan salah satu dari metode berikut.

1) Pisahkan nama lengkap menjadi nama depan dan belakang dengan rumus

Anda perlu menerapkan dua rumus secara terpisah untuk membagi nama lengkap menjadi nama depan dan nama belakang.

Pisahkan nama depan dari nama lengkap

Anda dapat menerapkan rumus berdasarkan fungsi LEFT dan SEARCH untuk memisahkan nama depan dari nama lengkap.

Formula umum

=LEFT(cell, SEARCH(" ", cell) - 1)

1. Pilih sel untuk menampilkan nama depan.

2. Salin atau masukkan rumus di bawah ini ke dalamnya dan tekan tombol Enter kunci. Pilih sel hasil ini dan seret Tuas IsiOtomatis down untuk memisahkan nama depan dari nama lengkap lainnya.

=LEFT(B5, SEARCH(" ", B5) - 1)

Sekarang Anda telah memisahkan semua nama depan dari nama lengkap dalam rentang sel tertentu, lanjutkan untuk menerapkan rumus di bawah ini untuk membagi nama belakang.

Pisahkan nama belakang dari nama lengkap

Formula umum

=RIGHT(cell, LEN(cell) - SEARCH("^", SUBSTITUTE(cell," ", "^", LEN(cell) - LEN(SUBSTITUTE(cell, " ", "")))))

1. Pilih sel di sebelah sel nama depan.

2. Salin atau masukkan rumus di bawah ini ke dalamnya dan tekan tombol Enter kunci. Pilih sel hasil ini dan seret Pegangan IsiOtomatisnya ke bawah untuk mendapatkan nama belakang dari nama lengkap lainnya.

=RIGHT(B5, LEN(B5) - SEARCH("^", SUBSTITUTE(B5," ", "^", LEN(B5) - LEN(SUBSTITUTE(B5, " ", "")))))

Note: Dalam rumus, B5 adalah sel nama lengkap yang ingin Anda pisahkan. Anda dapat mengubahnya sesuai kebutuhan.

2) Pisahkan nama lengkap menjadi nama depan dan belakang dengan alat yang luar biasa

Rumus sulit diingat bagi banyak pengguna Excel. Di sini merekomendasikan Pisahkan Nama fitur dari Kutools untuk Excel. Dengan fitur ini, Anda dapat dengan mudah membagi nama lengkap menjadi nama depan dan nama belakang dengan mudah hanya dengan beberapa klik.

1. Pilih rentang sel nama lengkap, klik Kutools > Gabungkan & Pisahkan > Pisahkan Nama.

2. Dalam Pisahkan Nama kotak dialog, centang hanya Nama Depan dan Nama Belakang kotak di Jenis split bagian, lalu klik OK.

Tips: Rentang yang dipilih ditampilkan di Rentang untuk dibagi kotak, Anda dapat mengubahnya sesuai kebutuhan.

3. Kemudian lainnya Pisahkan Nama kotak dialog muncul, pilih sel tujuan dan klik OK.

Kemudian nama lengkap di sel yang dipilih akan dibagi menjadi nama depan dan nama belakang secara massal seperti yang ditunjukkan pada gambar di bawah.

Bagi nama lengkap menjadi nama depan, tengah dan belakang

Seperti yang ditunjukkan pada tangkapan layar di bawah, ada kolom nama lengkap dengan nama depan, nama tengah, dan nama belakang yang dipisahkan oleh satu spasi. Untuk membagi nama lengkap menjadi nama depan, nama tengah dan nama belakang dan meletakkannya di kolom yang berbeda, metode di bawah ini dapat membantu Anda.

1) Pisahkan nama lengkap menjadi nama depan, tengah dan belakang dengan Teks ke Kolom

Fitur bawaan – Teks ke Kolom dapat membantu Anda dengan mudah membagi nama lengkap menjadi nama depan, nama tengah, dan nama belakang di Excel.

Anda dapat ikuti langkah-langkah yang disebutkan di atas untuk menerapkan fitur Teks ke Kolom.

Note: Di wizard Langkah 2 dari 3, hanya centang Space kotak.

2) Pisahkan nama lengkap menjadi nama depan, tengah dan belakang dengan rumus

Anda juga dapat menerapkan rumus untuk membagi nama lengkap menjadi nama depan, nama tengah, dan nama belakang di Excel.

Rumus umum yang digunakan untuk membagi nama lengkap

Pisahkan nama depan

=LEFT(cell,SEARCH(" ", cell)-1)

Pisahkan nama tengahnya

=MID(cell, SEARCH(" ", cell) + 1, SEARCH(" ", cell, SEARCH(" ", cell)+1) - SEARCH(" ", cell)-1)

Pisahkan nama belakang

=RIGHT(cell,LEN(cell) - SEARCH(" ",cell, SEARCH(" ",cell,1)+1))

Kemudian terapkan rumus di sel yang berbeda untuk mendapatkan nama depan, nama tengah, dan nama belakang.

1. Di sel D5, masukkan rumus di bawah ini dan tekan tombol Enter kunci. Pilih sel hasil ini dan seret Pegangan IsiOtomatisnya ke bawah untuk mendapatkan nama depan dari nama lengkap lainnya.

=LEFT(B5,SEARCH(" ", B5)-1)

2. Masukkan rumus di bawah ini di sel E5 dan tekan tombol Enter kunci untuk mendapatkan nama tengah pertama. Pilih sel hasil dan seret Pegangan IsiOtomatisnya ke bawah untuk mendapatkan nama tengah lainnya.

=MID(B5, SEARCH(" ", B5) + 1, SEARCH(" ", B5, SEARCH(" ", B5)+1) - SEARCH(" ", B5)-1)

3. Untuk mendapatkan nama belakang, masukkan rumus di bawah ini ke dalam sel F5 dan tekan Enter, lalu pilih sel hasil dan seret Menangani IsiOtomatisnya ke sel yang Anda butuhkan.

=RIGHT(B5,LEN(B5) - SEARCH(" ",B5, SEARCH(" ",B5,1)+1))

3) Pisahkan nama lengkap menjadi nama depan, tengah, dan belakang dengan alat yang luar biasa

Berikut adalah pengantar untuk Kutools untuk Excel'S Pisahkan Nama fitur, yang memungkinkan Anda untuk membagi nama lengkap menjadi nama depan, nama tengah dan nama belakang sekaligus hanya dengan beberapa klik.

1. Pilih sel nama lengkap tempat Anda ingin membagi, lalu klik Kutools > Gabungkan & Pisahkan > Pisahkan Nama.

2. Dalam Pisahkan Nama kotak dialog, Anda perlu mengkonfigurasi sebagai berikut.

3. Pada popping up berikutnya Pisahkan Nama kotak dialog, pilih sel tujuan untuk menampilkan teks yang dipisahkan, lalu klik OK. Lihat demo di bawah ini.

Contoh #8 Pisahkan teks dan angka dalam sel

Misalkan ada daftar string teks dengan teks dan angka campuran seperti yang ditunjukkan pada gambar di bawah, untuk memisahkan teks dan angka dan meletakkannya di kolom yang berbeda, kami menyediakan empat metode untuk Anda.

Pisahkan teks dan angka dengan rumus

Dengan rumus berikut, Anda dapat memisahkan teks dan angka dari satu sel menjadi dua sel yang terpisah.

Rumus umum

Dapatkan teks dari sel

=LEFT(cell,MIN(FIND({0,1,2,3,4,5,6,7,8,9},cell&"0123456789"))-1)

Dapatkan nomor dari sel

=RIGHT(cell,LEN(B5)-MIN(FIND({0,1,2,3,4,5,6,7,8,9},cell&"0123456789"))+1)

Kemudian terapkan kedua rumus ini di sel yang berbeda untuk mendapatkan teks dan angka yang terpisah.

1. Pilih sel kosong untuk menempatkan teks string teks pertama dalam daftar, salin atau masukkan rumus di bawah ini dan tekan tombol Enter kunci. Pilih sel hasil dan seret Pegangan IsiOtomatisnya ke bawah untuk mendapatkan teks dari string teks lain dalam daftar.

=LEFT(B5,MIN(FIND({0,1,2,3,4,5,6,7,8,9},B5&"0123456789"))-1)

2. Pilih sel (E5) di sebelah sel hasil pertama (D5), salin atau masukkan rumus di bawah ini dan tekan Enter. Pilih sel hasil dan seret Pegangan IsiOtomatisnya ke bawah untuk mendapatkan nomor string teks lain dalam daftar.

=RIGHT(B5,LEN(B5)-MIN(FIND({0,1,2,3,4,5,6,7,8,9},B5&"0123456789"))+1)

Pisahkan teks dan angka dengan Flash Fill (versi 2013 dan yang lebih baru)

Jika Anda menggunakan Excel 2013 atau versi yang lebih baru, Anda dapat menerapkan: Isi Flash built-in untuk memisahkan teks dan angka dari satu sel menjadi dua kolom.

Note: Untuk membuat fitur Isi Kilat berfungsi, Anda perlu menempatkan kolom hasil di sebelah kolom string teks asli. Misalnya, jika string teks asli berada di kolom B, teks dan angka yang dipisahkan harus ditempatkan di kolom C dan D. Lihat tangkapan layar:

1. Ketikkan teks secara manual dari sel string teks pertama (D5) di sel C5.

2. Terus ketik teks sel string teks kedua (D6) di sel C6.

3. Aktifkan sel C7, klik Data > Isi Flash.

Kemudian teks dari string teks lainnya diisi dalam sel secara otomatis seperti yang ditunjukkan pada gambar di bawah.

4. Ulangi langkah 1 sampai 3 untuk mendapatkan angka pada kolom D.

Catatan:

Pisahkan teks dan angka dengan Fungsi yang Ditentukan Pengguna

Jika string teks dalam daftar tidak teratur, dua metode di atas dapat mengembalikan hasil yang salah seperti yang ditunjukkan pada gambar di bawah.

Di sini perkenalkan fungsi yang ditentukan pengguna untuk membantu Anda membagi teks dan angka dari sel menjadi dua kolom di mana pun angka berada dalam string teks. Lihat tangkapan layar:

1. tekan lain + F11 kunci.

2. Dalam pembukaan Microsoft Visual Basic untuk Aplikasi window, klik Menyisipkan > Modul, lalu salin VBA di bawah ini ke jendela Kode.

Kode VBA: Pisahkan teks dan angka dari sel menjadi dua kolom

Public Function SplitText(pWorkRng As Range, pIsNumber As Boolean) As String
'Update by Extendoffice 20211105
Dim xLen As Long
Dim xStr As String
xLen = VBA.Len(pWorkRng.Value)
For i = 1 To xLen
    xStr = VBA.Mid(pWorkRng.Value, i, 1)
    If ((VBA.IsNumeric(xStr) And pIsNumber) Or (Not (VBA.IsNumeric(xStr)) And Not (pIsNumber))) Then
        SplitText = SplitText + xStr
    End If
Next
End Function

3. tekan lain + Q kunci untuk menutup Microsoft Visual Basic untuk Aplikasi jendela.

4. Pilih sel untuk menampilkan teks dari string teks pertama, masukkan rumus di bawah ini dan tekan tombol Enter kunci. Pilih sel hasil ini dan seret Pegangan IsiOtomatisnya ke bawah untuk mendapatkan teks dari string teks lain dalam daftar yang sama.

=SplitText(B5,FALSE)

5. Pilih sel di sebelah sel hasil teks pertama untuk menampilkan angka, masukkan rumus di bawah ini dan tekan tombol Enter kunci. Pilih sel hasil ini dan seret Pegangan IsiOtomatisnya ke bawah untuk mendapatkan nomor string teks lainnya.

=SplitText(B5,TRUE)

Pisahkan teks dan angka dengan alat yang luar biasa

Di sini merekomendasikan cara termudah untuk membagi teks dan angka sekaligus dari sel menjadi dua kolom. MenerapkanPisahkan Sel fitur dari Kutools untuk Excel membantu Anda menangani masalah ini hanya dengan beberapa klik.

1. Pilih sel string teks tempat Anda ingin membagi teks dan angka menjadi dua kolom.

2. klik Kutools > Gabungkan & Pisahkan > Pisahkan Sel.

3. Dalam Pisahkan Sel kotak dialog, Anda perlu melakukan pengaturan berikut.

4. Selanjutnya Pisahkan Sel kotak dialog, pilih sel untuk menampilkan teks dan angka yang dipisahkan, lalu klik tombol OK .

Kemudian Anda dapat melihat teks dan angka di sel yang dipilih dibagi menjadi dua kolom sekaligus seperti yang ditunjukkan pada gambar di bawah.

---

2. Pisahkan sel angka

Bagian ini menjelaskan cara membagi sel angka dalam dua situasi: membagi angka dengan lebih dari satu digit menjadi digit individual dan membagi angka pada desimal untuk memisahkan bagian bilangan bulat dan desimal.

Contoh #1: Pisahkan sel dengan angka

Jika Anda ingin membagi angka dengan lebih dari satu digit menjadi satu digit di kolom yang berbeda, coba salah satu metode di bawah ini.

Pisahkan angka dalam sel menjadi digit individu dengan rumus

Rumus di bawah ini dapat membantu untuk membagi angka menjadi digit individu dan meletakkannya di kolom yang berbeda.

Formula umum

=MID($A1, COLUMNS($A$1:A$1), 1)

Argumen

1. Pilih sel kosong untuk menampilkan digit pertama, masukkan rumus di bawah ini dan tekan tombol Enter kunci.

=MID($B3, COLUMNS($B$3:B$3), 1)

2. Pilih sel hasil ini dan seret Pegangan IsiOtomatisnya ke sel untuk mendapatkan digit lainnya. Tetap pilih semua sel hasil, lalu seret Pegangan IsiOtomatis ke bawah untuk mendapatkan digit individual dari nomor lain.

Note: Dalam rumus ini, B3 adalah sel yang berisi angka untuk dibagi menjadi digit individual, dan Anda dapat mengubahnya sesuai kebutuhan.

Pisahkan angka dalam sel menjadi digit individu dengan VBA

Kode VBA di bawah ini juga dapat membantu membagi angka dalam sel menjadi digit individual di Excel. Anda dapat melakukan sebagai berikut.

1. tekan lain + F11 kunci untuk membuka Microsoft Visual Basic untuk Aplikasi jendela.

2. Dalam Microsoft Visual Basic untuk Aplikasi window, klik Menyisipkan > Modul, lalu salin VBA di bawah ini ke jendela Kode.

Kode VBA: pisahkan nomor menjadi digit individual di Excel

Sub SplitNumberIntoDigits()
'Updateby Extendoffice 2021118
Dim Rng As Range
Dim InputRng As Range, OutRng As Range
xTitleId = "Kutools for Excel"
Set InputRng = Application.Selection
Set InputRng = Application.InputBox("Range :", xTitleId, InputRng.Address, Type:=8)
Set OutRng = Application.InputBox("Out put to (single cell):", xTitleId, Type:=8)
 xInt = InputRng.Row

Application.ScreenUpdating = False

For Each Rng In InputRng
    xValue = Rng.Value
    xRow = (Rng.Row - xInt) + 1
    For I = 1 To VBA.Len(xValue)
        OutRng.Cells(xRow, I).Value = VBA.Mid(xValue, I, 1)
    Next
Next
Application.ScreenUpdating = True
End Sub

3. tekan F5 kunci untuk menjalankan kode, lalu a Kutools untuk Excel kotak dialog muncul, Anda harus memilih rentang sel nomor yang akan Anda bagi dan kemudian klik tombol OK .

4. Yang kedua Kutools untuk Excel kotak dialog muncul, Anda perlu memilih sel untuk menampilkan digit individual, lalu klik OK.

Note: Kode ini juga dapat membagi sebuah kata menjadi huruf-huruf tersendiri.

Kemudian angka dalam sel yang dipilih dibagi menjadi digit individu dan ditempatkan di kolom yang berbeda.

Mudah membagi angka menjadi digit individu dengan alat yang luar biasa

Kutools untuk Excel'S Pisahkan Sel fitur adalah alat yang berguna untuk membantu Anda dengan mudah membagi nomor menjadi digit individu di Excel.

1. Setelah menginstal Kutools untuk Excel, pilih rentang jumlah sel yang akan Anda bagi, klik Kutools > Gabungkan & Pisahkan > Pisahkan Sel.

2. Dalam Pisahkan Sel kotak dialog, lakukan pengaturan berikut.

3. Dalam pembukaan Pisahkan Sel kotak dialog, pilih sel kosong untuk menampilkan angka, lalu klik tombol OK .

Kemudian angka dalam sel yang dipilih dibagi menjadi digit individu sekaligus.

Contoh #2 Pisahkan angka pada desimal

Bagian ini membahas beberapa metode untuk membagi angka menjadi bagian bilangan bulat dan desimal di Excel.

Pisahkan angka di desimal dengan rumus

Fungsi TRUNC dapat diterapkan untuk membagi angka desimal di Excel. Anda dapat melakukan sebagai berikut.

Rumus umum

Dapatkan bagian bilangan bulat

=TRUNC(A1)

Dapatkan bagian desimal

=A1-TRUNC(A1)

Argumen

Sekarang Anda dapat menerapkan dua rumus ini untuk membagi angka dalam rentang sel tertentu pada desimal di Excel.

1. Pilih sel untuk menempatkan bagian bilangan bulat dari sel angka pertama, masukkan rumus di bawah ini dan tekan tombol Enter kunci. Pilih sel hasil dan seret Pegangan IsiOtomatisnya ke bawah untuk mendapatkan bilangan bulat dari sel angka lainnya.

= TRUNC(B5)

2. Pilih sel di sebelah sel hasil pertama untuk menempatkan bagian desimal, masukkan rumus di bawah ini dan tekan tombol Enter kunci. Pilih sel hasil ini dan seret Pegangan IsiOtomatisnya ke bawah untuk mendapatkan desimal dari sel angka lainnya.

=B5-TRUNC(B5)

Pisahkan angka pada desimal dengan Teks ke kolom

Anda dapat menerapkan Teks ke Kolom fitur untuk membagi angka pada desimal di Excel.

1. Pilih rentang sel angka yang akan Anda bagi dalam desimal, lalu klik Data > Teks ke Kolom.

2. Dalam Convert Text to Columns Wizard - Langkah 1 dari 3 kotak dialog, pilih Terbatas tombol radio dan klik Selanjutnya .

3. Dalam Langkah 2 dari 3 kotak dialog, centang hanya Lainnya kotak centang, masukkan titik ke dalam kotak teks, lalu klik tombol Selanjutnya .

4. Dalam Langkah 3 dari 3 kotak dialog, klik tombol untuk memilih sel tujuan untuk menampilkan bilangan bulat dan desimal yang dibagi, dan terakhir klik tombol Finish tombol. Lihat tangkapan layar:

Kemudian Anda dapat melihat bagian bilangan bulat dan desimal dipisahkan dari sel yang dipilih seperti yang ditunjukkan pada gambar di bawah. Namun, bagian desimal kehilangan tanda negatifnya yang mungkin diperlukan bagi pengguna.

Pisahkan angka pada desimal dengan Flash Fill (2013 dan versi yang lebih baru)

Dalam contoh di atas kami memperkenalkan penggunaan Isi Flash berfungsi untuk membagi teks dan angka dalam sel, dan di sini kami akan memperkenalkan metode yang sama untuk membagi angka pada desimal.

1. Masukkan beberapa contoh. Dalam hal ini, kita masukkan bagian integer B5 di C5, masukkan bagian integer B6 di C6. Lihat tangkapan layar:

Note: Untuk bilangan negatif, jangan lupa untuk memasukkan tanda minus secara bersamaan.

3. Pilih sel termasuk beberapa contoh di kolom yang ingin Anda isi, klik Data > Isi Flash.

Kemudian bilangan bulat diekstraksi dari sel nomor yang ditentukan seperti yang ditunjukkan pada gambar di bawah.

4. Ulangi langkah di atas untuk membagi desimal dari sel angka yang sama.

---

3. Pisahkan sel tanggal

Situasi lain yang sering ditemui adalah untuk membagi sel tanggal. Jika Anda perlu membagi sel tanggal menjadi hari, bulan, dan tahun yang terpisah, atau memisahkan sel tanggal menjadi tanggal dan waktu yang terpisah, gunakan solusi berikut tergantung pada kebutuhan Anda.

Contoh #1 Pisahkan sel tanggal menjadi hari, bulan, dan tahun yang terpisah

Dengan asumsi bahwa Anda memiliki daftar tanggal dalam rentang B5:B9, dan ingin membagi setiap nilai tanggal menjadi tiga kolom terpisah untuk hari, bulan, dan tahun. Berikut menyediakan tiga metode untuk membantu Anda mencapai hasil pemisahan tanggal.

Pisahkan sel tanggal menjadi hari, bulan, dan tahun dengan rumus

Anda dapat menerapkan tiga formula berdasarkan TANGGAL fungsi, BULAN fungsi dan TAHUN fungsi untuk membagi tanggal menjadi hari, bulan dan tahun yang terpisah di Excel.

Rumus umum

=DATE(A1)

=MONTH(A1)

=YEAR(A1)

Argumen

1. Buat tiga kolom untuk menempatkan hari, bulan, dan tahun yang terpisah.

2. Pilih sel pertama di kolom Hari, masukkan rumus di bawah ini dan tekan tombol Enter kunci untuk mendapatkan hari sel tanggal pertama (B5). Pilih sel hasil ini dan seret Pegangan IsiOtomatisnya ke bawah untuk mendapatkan hari dari sel tanggal lainnya.

=DAY(B5)

3. Lakukan operasi yang sama seperti langkah 1 untuk menerapkan rumus berikut dalam: Bulan dan Tahun kolom untuk mendapatkan bulan dan tahun terpisah dari sel tanggal.

Dapatkan bulan kencan

=MONTH(B5)

Dapatkan tahun kencan

=YEAR(B5)

Pisahkan sel tanggal menjadi hari, bulan, dan tahun dengan Teks ke Kolom

Anda dapat ikuti langkah-langkah di atas untuk menerapkan fitur Teks ke Kolom untuk membagi sel tanggal menjadi hari, bulan dan tahun yang terpisah di Excel.

Note: Dalam Langkah 2 dari 3 kotak dialog, centang hanya Lainnya kotak, dan ketik a / simbol di kotak teks.

Pisahkan sel tanggal menjadi hari, bulan, dan tahun dengan alat yang luar biasa

Demo di bawah ini menunjukkan cara membagi tanggal menjadi bulan, hari, dan tahun yang terpisah dengan Pisahkan Sel fitur dari Kutools untuk Excel.

Fitur ini membantu Anda mencapai hasil pemisahan tanggal secara massal hanya dengan beberapa klik.

Klik untuk mengetahui lebih banyak tentang fitur ini.

Contoh #2 Pisahkan tanggal dan waktu dalam sel

Misalkan ada daftar waktu tanggal di B5:B9, dan Anda ingin membagi tanggal dan waktu menjadi kolom terpisah, bagian ini akan menunjukkan berbagai cara untuk membantu Anda menyelesaikannya.

Pisahkan tanggal dan waktu dalam sel dengan rumus

Anda dapat menerapkan rumus berikut untuk membagi tanggal dan waktu ke dalam kolom yang berbeda di Excel.

1. Siapkan dua kolom untuk menempatkan tanggal dan waktu.

2. Anda perlu mengatur sel kolom tanggal ke Tanggal format, dan atur sel kolom waktu ke Waktu Format.

3. Pilih sel pertama di Tanggal kolom, masukkan rumus di bawah ini dan tekan tombol Enter kunci untuk mendapatkan tanggal B5. Pilih sel hasil ini dan seret Pegangan IsiOtomatisnya ke bawah untuk mendapatkan tanggal lainnya.

=INT(B5)

4. Terapkan rumus berikut di kolom waktu untuk mendapatkan waktu di B5:B9.

=B5-D5

Pisahkan tanggal dan waktu dalam sel dengan Flash Fill (versi 2013 dan yang lebih baru)

Jika Anda menggunakan Excel 2013 dan versi yang lebih baru, Anda dapat menerapkan fitur Isi Kilat bawaan untuk membagi tanggal dan waktu ke dalam kolom yang berbeda.

1. Buat kolom Tanggal dan Waktu dan masukkan beberapa contoh yang Anda inginkan sebagai output. Dalam Tanggal kolom, kita masukkan tanggal B5 di C5, dan masukkan tanggal B6 di C6. Dalam Waktu kolom, kita masukkan waktu B5 di D5 dan masukkan waktu B6 di D6. Lihat tangkapan layar:

2. Pilih kolom Tanggal (termasuk beberapa contoh) yang ingin Anda isi, klik Data > Isi Flash.

3. Pilih kolom Waktu (termasuk beberapa contoh) yang ingin Anda isi, lalu aktifkan Isi Flash fitur juga. Kemudian tanggal dan waktu di B5:B9 dibagi menjadi kolom terpisah seperti yang ditunjukkan pada demo di bawah ini.

Sekarang, Anda telah belajar bagaimana membagi sel di Excel dengan metode yang berbeda dalam situasi yang berbeda. Anda akan dapat membuat keputusan terbaik untuk menentukan metode mana yang Anda pilih sesuai dengan skenario spesifik Anda.