Pisahkan string teks pada karakter tertentu dalam sel di Excel
Tutorial ini menjelaskan cara membagi string teks pada karakter tertentu menjadi sel kolom terpisah dengan rumus di Excel.
Bagaimana cara membagi string teks pada karakter tertentu dalam sel di Excel?
Misalkan Anda memiliki daftar string teks di kolom B seperti gambar di bawah ini, dan Anda ingin membagi teks pada karakter "-" dan menampilkannya dalam tiga kolom terpisah. Dalam hal ini, rumus di bawah ini dapat membantu Anda.
Rumus umum
Rumus umum untuk memisahkan teks kiri
=LEFT(text_string,FIND("Char", text_string)-1)
Rumus umum untuk memisahkan teks tengah
=MID(text_string, FIND("Char", text_string) + 1, FIND("Char", text_string,FIND("Char", text_string)+1) - FIND("Char", text_string) - 1)
Rumus umum untuk memisahkan teks yang benar
=RIGHT(text_string,LEN(text_string) - FIND("Char", text_string, FIND("Char", text_string) + 1))
Argumen rumus di atas
Teks_string: String teks yang ingin Anda pisahkan teksnya;
Arang: Karakter yang akan Anda pisahkan berdasarkan teks.
Bagaimana cara menggunakan rumus ini?
Pertama, pisahkan string teks pertama berdasarkan karakter tertentu
1. Pilih sel kosong untuk menampilkan hasilnya. Di sini saya pilih C3.
2. Masukkan rumus di bawah ini ke dalamnya dan tekan Enter kunci. Dan kemudian seret sel dengan rumus KIRI Anda sepenuhnya ke bawah untuk menerapkannya ke sel lain.
=LEFT(B3,FIND("-",B3)-1)
Kedua, pisahkan string teks tengah berdasarkan karakter tertentu
1. Pilih sel kosong seperti D3 untuk menampilkan hasilnya.
2. Masukkan rumus di bawah ini ke dalamnya dan tekan Enter kunci. Pilih sel hasil, seret Fill Handle ke bawah untuk menerapkan rumus ke sel lain.
=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)
Terakhir, pisahkan string teks terakhir berdasarkan karakter tertentu
1. Pilih sel kosong seperti E3 untuk menampilkan hasilnya.
2. Masukkan rumus di bawah ini ke dalamnya dan tekan Enter kunci. Pilih sel hasil, seret Fill Handle ke bawah untuk menerapkan rumus ke sel lain.
=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))
Sekarang string teks di setiap sel kolom B telah dipecah menjadi tiga bagian.
Tips: Jika Anda hanya ingin membagi string teks menjadi dua bagian berdasarkan karakter tertentu, setelah memisahkan bagian pertama dengan rumus KIRI di atas, Anda dapat menerapkan rumus KANAN di bawah ini untuk mengekstrak bagian kedua seperti gambar di bawah ini.
=RIGHT(B3,LEN(B3)-FIND("-",B3))
Bagaimana rumus ini bekerja?
=LEFT(B3,FIND("-",B3)-1)
- FIND("-",B3): Fungsi FIND mengembalikan posisi awal karakter "-" dalam string teks KTE-Jan-359. Hasilnya adalah 4.
- LEFT(B3,4-1): Fungsi LEFT mengekstrak 3 karakter (4-1 = 3) dari sisi kiri string teks KTE-Jan-359. Inilah hasilnya KTE.
Note: Karena karakter pertama "-" berada di posisi ke-4 dari string teks, Anda perlu mengurangi 1 untuk mengecualikannya dari ekstraksi.
=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)
- FIND("-",B3) + 1: Fungsi FIND mengembalikan posisi awal karakter "-" dalam string teks KTE-Jan-359. Berikut hasilnya adalah 4.
Note: Karena karakter pertama "-" berada di posisi ke-4 dari string teks, Anda perlu menambahkan 1 hingga 4 untuk mengekstrak teks setelahnya, dan akhirnya kita akhiri dengan 4 + 1 = 5. - FIND("-",B3,FIND("-",B3)+1) di sini ditampilkan sebagai FIND ("-", KTE-Jan-359,4 + 1): Fungsi Find menemukan posisi karakter "-" mulai dari karakter ke-5 di KTE-Jan-359. Dan mengembalikan hasilnya sebagai 8.
- MID(B3, 5, 8 - 4 - 1): MID (KTE-Jan-359,5,3) artinya fungsi MID mengekstrak 3 karakter angka dimulai dari karakter ke 5 pada string teks KTE-Jan-359. Dan hasilnya adalah Jan.
=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))
- LEN(B3): Fungsi LEN menghitung panjang total string teks KTE-Jan-359, dan mengembalikan hasilnya sebagai 11.
- FIND("-",B3,FIND("-",B3)+1): Fungsi Find menemukan posisi karakter "-" mulai dari karakter ke-5 di KTE-Jan-359. Dan mengembalikan hasilnya sebagai 8.
- RIGHT(B3,11 - 8)): Fungsi RIGHT mengekstrak 3 (11-8) karakter dari sisi kanan KTE-Jan-359. Di sini hasilnya adalah 359.
Fungsi terkait
Fungsi Excel LEFT
Fungsi LEFT mengekstrak sejumlah karakter dari sisi kiri string yang disediakan.
Fungsi Excel FIND
Fungsi FIND digunakan untuk menemukan string di dalam string lain, dan mengembalikan posisi awal string di dalam string lain.
Fungsi MID Excel
Fungsi MID digunakan untuk mencari dan mengembalikan sejumlah karakter tertentu dari tengah string teks yang diberikan.
Fungsi Excel RIGHT
Fungsi KANAN mengekstrak sejumlah karakter tertentu dari sisi kanan string teks.
Fungsi LEN Excel
Fungsi Excel LEN mengembalikan jumlah karakter dalam string teks.
Rumus terkait
Pisahkan dimensi menjadi dua bagian di Excel
Artikel ini menjelaskan cara menggunakan rumus untuk memisahkan dimensi dalam sel menjadi dua bagian tanpa unit (panjang dan lebar individual).
Pisahkan angka dari unit pengukuran
Artikel ini menjelaskan cara menggunakan rumus untuk memisahkan angka dari kesatuan pengukuran.
Pisahkan teks dan angka dalam sel di Excel
Jika Anda ingin membagi teks dan angka dalam sel menjadi sel kolom yang berbeda dengan rumus, tutorial ini akan membantu Anda.
Pisahkan Teks Dengan Pembatas Dalam Sel Di Excel
Di artikel ini, kami menyediakan panduan langkah demi langkah untuk membantu Anda memisahkan teks dalam sel dengan pembatas tertentu di Excel.
Alat Produktivitas Kantor Terbaik
Kutools for Excel - Membantu Anda Menonjol Dari Kerumunan
Kutools for Excel Membanggakan Lebih dari 300 Fitur, Memastikan Apa yang Anda Butuhkan Hanya Dengan Sekali Klik...
Tab Office - Aktifkan Pembacaan dan Pengeditan dengan Tab di Microsoft Office (termasuk Excel)
- Satu detik untuk beralih di antara lusinan dokumen terbuka!
- Kurangi ratusan klik mouse untuk Anda setiap hari, ucapkan selamat tinggal pada tangan mouse.
- Meningkatkan produktivitas Anda sebesar 50% saat melihat dan mengedit banyak dokumen.
- Menghadirkan Tab Efisien ke Office (termasuk Excel), Sama Seperti Chrome, Edge, dan Firefox.
