Note: The other languages of the website are Google-translated. Back to English

Oktet terpisah dari alamat IP di Excel

Pernahkah Anda mencoba membagi alamat IP menjadi kolom terpisah di lembar kerja Excel? Mungkin fitur Text to Column dapat membantu Anda menyelesaikan pekerjaan ini dengan cepat, namun pada artikel ini, saya akan membahas beberapa rumus untuk menyelesaikan tugas ini di Excel.


Pisahkan oktet alamat IP menjadi kolom terpisah di Excel

Biasanya, di Excel, fungsi LEFT, MID, LEN dan FIND dapat membantu Anda mengekstrak setiap oktet dari alamat IP ke kolom yang berbeda. Silakan lakukan dengan langkah-langkah berikut:

Pisahkan oktet pertama dari alamat IP:

Untuk mengekstrak oktet pertama dari alamat IP, harap terapkan rumus di bawah ini ke dalam sel kosong:

=LEFT(A2,FIND(".",A2)-1)

Dan kemudian, seret pegangan isi ke sel yang ingin Anda terapkan rumus ini, dan semua oktet pertama dari alamat IP telah diekstraksi, lihat tangkapan layar:

Penjelasan rumusnya:

TEMUKAN (".", A2) -1: Fungsi FIND ini mengembalikan posisi titik pertama dari sel A2, mengurangi 1 berarti mengecualikan titik itu sendiri, Anda akan mendapatkan hasil 2.

LEFT(A2,FIND(".",A2)-1)=LEFT(A2, 2):Fungsi LEFT digunakan untuk mengekstrak 2 karakter dari sisi kiri string di sel A2.


Pisahkan oktet kedua dari alamat IP:

Untuk mendapatkan oktet kedua dari alamat IP, silakan salin atau masukkan rumus berikut ke dalam sel kosong:

=MID(A2,FIND(".",A2)+1,FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1)

Kemudian, seret gagang isian ke sel untuk mengisi rumus ini, iklan Anda akan mendapatkan hasil yang Anda butuhkan, lihat tangkapan layar:

Penjelasan rumusnya:

1. TEMUKAN (".", A2) +1: Fungsi FIND ini mengembalikan posisi titik pertama dari sel A2, menambahkan 1 cara untuk mengekstraksi dari karakter berikutnya, Anda akan mendapatkan hasil berupa angka 4. Bagian rumus ini dikenali sebagai argumen start_num dari fungsi MID.

2. FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1: Bagian ini dikenali sebagai argumen num_chars dalam fungsi MID.

  • FIND (".", A2, FIND (".", A2) +1) = FIND (".", A2,4): Fungsi FIND ini akan mengembalikan posisi titik kedua. Dan Anda akan mendapatkan nomor 6.
  • FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1=6-3-1: Kurangi posisi titik pertama dari posisi titik kedua, lalu kurangi 1 dari hasil artinya menghilangkan titik terdepan. Dan hasilnya adalah 2.

3. MID(A2,FIND(".",A2)+1,FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1)=MID(A2, 4, 2): Terakhir, fungsi MID ini digunakan untuk mengekstrak 2 karakter yang dimulai dari karakter keempat dari sel A2.


Pisahkan oktet ketiga dari alamat IP:

Untuk mengekstrak oktet ketiga dari alamat IP, fungsi MID dan FIND juga dapat membantu Anda, silakan masukkan atau salin rumus berikut ke dalam sel kosong:

=MID(A2,FIND(".",A2,FIND(".",A2)+1)+1,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1))

Kemudian, seret gagang isian ke bawah untuk mendapatkan hasil yang Anda butuhkan, dan hanya oktet ketiga dari alamat IP yang telah dipisahkan, lihat tangkapan layar:

Penjelasan rumusnya:

1. FIND(".",A2,FIND(".",A2)+1)+1: Fungsi FIND bersarang ini digunakan untuk mendapatkan posisi titik kedua di sel A2, menambahkan 1 cara ke ekstraksi dari karakter berikutnya, dan Anda akan mendapatkan angka 7. Bagian ini dikenali sebagai argumen start_num dari fungsi MID.

2. FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1): Bagian dari rumus ini dikenali sebagai argumen num_chars dari fungsi MID.

  • FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)=FIND(".",A2, 7): Fungsi FIND bersarang ini digunakan untuk mendapatkan posisi titik ketiga di sel A2, ini mengembalikan angka 8.
  • FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1)=8-7: Kurangi posisi titik kedua dari posisi titik ketiga, Dan hasilnya adalah 1.

3.MID(A2,FIND(".",A2,FIND(".",A2)+1)+1,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1))=MID(A2, 7, 1): Fungsi MID ini akan mendapatkan 1 karakter yang dimulai dari karakter ketujuh dari sel A2.


Pisahkan oktet keempat dari alamat IP:

Rumus di bawah ini dapat membantu mengekstrak oktet terakhir dari alamat IP, silakan salin atau masukkan rumus ke dalam sel kosong:

=MID(A2,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)+1,LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1))

Dan kemudian, seret pegangan isian untuk mengisi rumus ini ke sel lain yang Anda butuhkan, Anda akan mendapatkan hasil seperti gambar di bawah ini:

Penjelasan rumusnya:

1. FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)+1: Fungsi FIND bersarang ini digunakan untuk mendapatkan posisi titik ketiga di sel A2, menambahkan 1 cara ke ekstraksi dari karakter berikutnya, dan Anda akan mendapatkan angka 9. Bagian ini dikenali sebagai argumen start_num dari fungsi MID.

2. LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1):

  • LEN (A2): Fungsi LEN mengembalikan jumlah total karakter di sel A2. Ini akan mendapatkan nomor 11.
  • LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)=11-8: Panjang total sel A2 mengurangi posisi titik ketiga untuk mendapatkan jumlah karakter yang tersisa. Ini akan mendapatkan angka 3.

3. MID(A2,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)+1,LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1))=MID(A2, 9, 3): Akhirnya fungsi MID ini akan mendapatkan 3 karakter yang dimulai dari karakter kesembilan dari sel A2.


Fungsi relatif yang digunakan:

  • LEFT:
  • Fungsi LEFT mengekstrak sejumlah karakter dari sisi kiri string yang disediakan.
  • MID:
  • Fungsi MID digunakan untuk mencari dan mengembalikan sejumlah karakter tertentu dari tengah string teks yang diberikan.
  • FIND:
  • Fungsi FIND digunakan untuk menemukan string di dalam string lain, dan mengembalikan posisi awal string di dalam string lain.
  • LEN:
  • Fungsi LEN mengembalikan jumlah karakter dalam string teks.

Artikel lainnya:

  • Pisahkan Teks Dan Angka Dalam Satu Sel Di Excel
  • Misalkan data sel dicampur dengan teks dan angka, bagaimana Anda bisa membaginya menjadi sel kolom terpisah? Tutorial ini akan menunjukkan kepada Anda langkah-langkah mendetail untuk menurunkannya dengan rumus.

Alat Produktivitas Kantor Terbaik

Kutools for Excel - Membantu Anda Menonjol Dari Kerumunan

Apakah Anda ingin menyelesaikan pekerjaan harian Anda dengan cepat dan sempurna? Kutools for Excel menghadirkan 300 fitur canggih yang canggih (Gabungkan buku kerja, jumlahkan berdasarkan warna, pisahkan konten sel, tanggal konversi, dan seterusnya...) dan hemat 80% waktu untuk Anda.

  • Dirancang untuk 1500 skenario kerja, membantu Anda memecahkan 80% masalah Excel.
  • Kurangi ribuan klik keyboard dan mouse setiap hari, hilangkan mata dan tangan Anda yang lelah.
  • Menjadi ahli Excel dalam 3 menit. Tidak perlu lagi mengingat rumus dan kode VBA yang menyakitkan.
  • Uji coba gratis tanpa batas selama 30 hari. Jaminan uang kembali 60 hari. Upgrade dan dukungan gratis selama 2 tahun.
Ribbon of Excel (dengan Kutools for Excel diinstal)

Tab Office - Aktifkan Pembacaan dan Pengeditan dengan Tab di Microsoft Office (termasuk Excel)

  • Satu detik untuk beralih di antara lusinan dokumen terbuka!
  • Kurangi ratusan klik mouse untuk Anda setiap hari, ucapkan selamat tinggal pada tangan mouse.
  • Meningkatkan produktivitas Anda sebesar 50% saat melihat dan mengedit banyak dokumen.
  • Membawa Tab Efisien ke Office (termasuk Excel), Sama Seperti Chrome, Firefox, dan Internet Explorer Baru.
Cuplikan Layar Excel (dengan Office Tab diinstal)
Urutkan komentar berdasarkan
komentar (1)
Rated 5 dari 5 · peringkat 1
Komentar ini diminimalkan oleh moderator di situs
Ini bekerja dengan indah, terima kasih atas informasi ini !!
Rated 5 dari 5
Belum ada komentar yang diposting di sini
Tinggalkan komentar anda
Posting sebagai Tamu
×
Beri peringkat pos ini:
0   Karakter
Lokasi yang Disarankan

Ikuti kami

Hak Cipta © 2009 - www.extendoffice.com. | Seluruh hak cipta. Dipersembahkan oleh ExtendOffice. | Peta Situs
Microsoft dan logo Office adalah merek dagang atau merek dagang terdaftar dari Microsoft Corporation di Amerika Serikat dan / atau negara lain.
Dilindungi oleh Sectigo SSL