Ekstrak nama file dari jalur di Excel
Tutorial ini menjelaskan cara menerapkan rumus untuk mengekstrak nama file dengan atau tanpa ekstensi dari jalur file di sel tertentu di Excel.
Ekstrak nama file dengan ekstensi dari jalur
Ekstrak nama file tanpa ekstensi dari jalur
Ekstrak nama file dengan ekstensi dari jalur
Seperti gambar di bawah ini yang ditampilkan, ada daftar yang berisi jalur file yang berbeda, dan Anda hanya ingin mengekstrak nama file dengan ekstensi dari mereka, rumus berikut akan membantu Anda menyelesaikan masalah.
Formula umum
=MID(A1,FIND("*",SUBSTITUTE(A1,"\","*",LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,LEN(A1))
kasus
A1: Mewakili sel yang berisi jalur file yang akan Anda ekstrak nama file darinya.
Bagaimana cara menggunakan rumus ini?
1. Pilih sel kosong untuk menampilkan nama file. Dalam hal ini, saya memilih sel D3.
2. Masukkan rumus di bawah ini ke dalamnya dan tekan Enter kunci. Pilih sel hasil, lalu seret Fill Handle ke bawah untuk menerapkannya ke sel lain.
=MID(B3,FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))+1,LEN(B3))
Sekarang semua nama file dengan ekstensi di jalur file tertentu diekstrak seperti gambar di atas yang ditampilkan.
Catatan:
- Dalam rumus ini, B3 adalah sel yang berisi jalur file. Harap ubah sesuai kebutuhan Anda.
- Jika nama file tidak lebih dari 99 karakter, rumus pendek di bawah ini juga dapat digunakan untuk menyelesaikan masalah. Lihat gambar di bawah yang ditampilkan.
=TRIM(RIGHT(SUBSTITUTE(A2,"\",REPT(" ",100)),99))
Bagaimana rumus ini bekerja?
=MID(B3,FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))+1,LEN(B3))
1. FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))
- LEN(B3): Fungsi LEN menghitung panjang total dalam "D: \\ files \ work \ Q1 \ Jan \ text.txt" dan mengembalikan hasilnya sebagai 30;
- LEN(SUBSTITUTE(B3,"\","")): Fungsi SUBSTITUTE menggantikan karakter "\" dengan apa-apa. Hasilnya adalah "D: filesworkQ1Jantext.txt". Dan kemudian fungsi LEN menghitung panjang total "D: filesworkQ1Jantext.txt" dan mendapatkan hasil 24;
- SUBSTITUTE(B3,"\","*",30-24): Fungsi SUBSTITUTE menggantikan karakter ketiga (30-24 = 6) "\" dalam "D: \\ files \ work \ Q1 \ Jan \ text.txt" dengan satu karakter "*". Berikut hasilnya adalah "D: \\ files \ work \ Q1 \ Jan * text.txt";
- FIND("*","D:\\files\work\Q1\Jan*text.txt"): Fungsi FIND menempatkan posisi karakter "*" di "D: \\ files \ work \ Q1 \ Jan * text.txt" dan akhirnya mengembalikan 22. Di sini berarti karakter "*" berada di posisi ke-22 di " D: \\ files \ work \ Q1 \ Jan * text.txt ".
2. =MID(B3,22+1,LEN(B3))
- Seperti penjelasan di atas yang ditunjukkan, LEN (B3) mengembalikan hasil sebagai 30, di sini fungsi MID dapat ditampilkan sebagai = MID ("D: \\ files \ work \ Q1 \ Jan \ text.txt", 23,30). Ini berarti fungsi MID mengekstrak 30 karakter dari string "D: \\ files \ work \ Q1 \ Jan \ text.txt", dimulai dari karakter ke-23. Berikut hasilnya adalah text.txt.
Ekstrak nama file tanpa ekstensi dari jalur
Keadaan lain, Anda mungkin hanya perlu mengekstrak nama file tanpa ekstensi dari jalur seperti gambar di bawah ini. Bagian ini akan memberikan rumus panjang untuk membantu Anda memahami.
Formula umum
=IFERROR(MID(A1,FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,FIND(CHAR(1),SUBSTITUTE(A1,".",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,".",""))))-FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))-1),"")
kasus
A1: Mewakili sel yang berisi jalur file yang akan Anda ekstrak nama file darinya.
CHAR (1): CHAR (1) di sini dapat diganti dengan nomor CHAR apa pun yang Anda butuhkan. Atau dapat diganti dengan simbol tertentu yang diapit oleh tanda kutip seperti "*".
Bagaimana cara menggunakan rumus ini?
1. Pilih sel kosong untuk menampilkan nama file tanpa ekstensi.
2. Masukkan rumus di bawah ini ke dalamnya dan tekan Enter kunci. Pilih sel hasil, lalu seret Fill Handle ke bawah untuk menerapkannya ke sel lain.
=IFERROR(MID(B4,FIND(CHAR(1),SUBSTITUTE(B4,"\",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,"\",""))))+1,FIND(CHAR(1),SUBSTITUTE(B4,".",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,".",""))))-FIND(CHAR(1),SUBSTITUTE(B4,"\",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,"\",""))))-1),"")
Note: Dalam rumus ini, B3 adalah sel yang berisi jalur file. Harap ubah sesuai kebutuhan Anda.
Fungsi terkait
Fungsi MID Excel
Fungsi Excel MID digunakan untuk menemukan dan mengembalikan sejumlah karakter tertentu dari tengah string teks yang diberikan.
Fungsi Excel FIND
Fungsi Excel FIND digunakan untuk menemukan string di dalam string lain, dan mengembalikan posisi awal string di dalam string lain.
Fungsi pengganti Excel
Fungsi Excel SUBSTITUTE menggantikan teks atau karakter dalam string teks dengan teks atau karakter lain.
Fungsi LEN Excel
Fungsi Excel LEN mengembalikan jumlah karakter dalam string teks.
Fungsi IFERROR Excel
Fungsi IFERROR digunakan untuk mengembalikan hasil kustom saat rumus mengevaluasi kesalahan, dan mengembalikan hasil normal saat tidak ada kesalahan yang terjadi.
Rumus terkait
Ekstrak Beberapa Garis Dari Sel A
Jika Anda memiliki daftar string teks yang dipisahkan oleh jeda baris (yang terjadi dengan menekan Alt + Memasukkan kunci saat memasukkan teks), dan ingin mengekstrak baris teks ini ke dalam beberapa sel, rumus dalam tutorial ini akan membantu Anda kebaikan.
Ekstrak Baris Teks Terakhir Dari Sel Multi-Baris
Untuk mengekstrak baris teks terakhir dari string teks yang dipisahkan oleh jeda baris, rumus dalam tutorial ini dapat membantu Anda menangani tugas ini di Excel.
Ekstrak Kata N Dari String Teks Di Excel
Artikel ini menjelaskan cara menggunakan rumus untuk mengekstrak kata ke-n tertentu dari string teks dalam sel di Excel.
Ekstrak Dua Kata Terakhir Dari Sel Di Excel
Tutorial ini menjelaskan cara menggunakan rumus untuk mengekstrak dua kata terakhir dari sel di Excel.
Ekstrak Kata yang Dimulai Dengan Karakter Tertentu Di Excel
Tutorial ini memberikan rumus dengan langkah-langkah detail untuk membantu Anda mengekstrak kata yang dimulai dengan karakter tertentu dari string teks dalam sel di Excel.
Ekstrak Semua Kata Tapi Pertama atau Terakhir
Dalam tutorial ini, Anda akan belajar bagaimana menggunakan rumus untuk mengekstrak semua kata dari sel kecuali yang pertama atau terakhir di Excel.
Alat Produktivitas Kantor Terbaik
Kutools for Excel - Membantu Anda Menonjol Dari Kerumunan
Kutools for Excel Membanggakan Lebih dari 300 Fitur, Memastikan Apa yang Anda Butuhkan Hanya Dengan Sekali Klik...
Tab Office - Aktifkan Pembacaan dan Pengeditan dengan Tab di Microsoft Office (termasuk Excel)
- Satu detik untuk beralih di antara lusinan dokumen terbuka!
- Kurangi ratusan klik mouse untuk Anda setiap hari, ucapkan selamat tinggal pada tangan mouse.
- Meningkatkan produktivitas Anda sebesar 50% saat melihat dan mengedit banyak dokumen.
- Menghadirkan Tab Efisien ke Office (termasuk Excel), Sama Seperti Chrome, Edge, dan Firefox.