Bagaimana cara mendapatkan alamat email pengirim dari satu atau lebih email di Outlook?

Pernahkah Anda mencoba mengekstrak alamat email dari bidang "Dari" dari satu atau beberapa email yang diterima di Outlook? Artikel ini menyediakan kode VBA untuk membantu Anda menangani tugas ini.

Dapatkan alamat email pengirim dari satu atau beberapa email di Outlook

Silakan jalankan kode VBA berikut untuk mengekstrak alamat email dari bidang "Dari" dari satu atau beberapa email yang diterima di Outlook.

1. Buka folder email, pilih pesan email dari mana Anda ingin mendapatkan alamat email pengirim. tekan lain + F11 kunci untuk membuka Microsoft Visual Basic untuk Aplikasi jendela.

Tips: Untuk memilih beberapa email, tahan tombol Ctrl lalu pilih email satu per satu.

2. Dalam Microsoft Visual Basic untuk Aplikasi window, klik Menyisipkan > Modul, lalu salin kode VBA berikut ke jendela Module (code).

Kode VBA: ekstrak alamat email pengirim dari satu atau beberapa email di Outlook

Sub GetSmtpAddressOfSelectionEmail()
  Dim xExplorer As Explorer
  Dim xSelection As Selection
  Dim xItem As Object
  Dim xMail As MailItem
  Dim xAddress As String
  Dim xFldObj As Object
  Dim FilePath As String
  Dim xFSO As Scripting.FileSystemObject
  On Error Resume Next
  Set xExplorer = Application.ActiveExplorer
  Set xSelection = xExplorer.Selection
  For Each xItem In xSelection
    If xItem.Class = olMail Then
      Set xMail = xItem
      xAddress = xAddress & VBA.vbCrLf & "  " & GetSmtpAddress(xMail)
    End If
  Next
  If MsgBox("Sender SMTP Address is: " & xAddress & vbCrLf & vbCrLf & "Do you want to export the address list to a txt file? ", vbYesNo, "Kutools for Outlook") = vbYes Then
    Set xFldObj = CreateObject("Shell.Application").BrowseforFolder(0, "Select a Folder", 0, 16)
    Set xFSO = New Scripting.FileSystemObject
    If xFldObj Is Nothing Then Exit Sub
    FilePath = xFldObj.Items.Item.Path & "\Address.txt"
    Close #1
    Open FilePath For Output As #1
    Print #1, "Sender SMTP Address is: " & xAddress
    Close #1
    Set xFSO = Nothing
    Set xFldObj = Nothing
    MsgBox "Address list has been exported to：" & FilePath, vbOKOnly + vbInformation, "Kutools for Outlook"
  End If
End Sub
Function GetSmtpAddress(Mail As MailItem)
  Dim xNameSpace As Outlook.NameSpace
  Dim xEntryID As String
  Dim xAddressEntry As AddressEntry
  Dim PR_SENT_REPRESENTING_ENTRYID As String
  Dim PR_SMTP_ADDRESS As String
  Dim xExchangeUser As exchangeUser
  On Error Resume Next
  GetSmtpAddress = ""
  Set xNameSpace = Application.Session
  If Mail.sender.Type <> "EX" Then
    GetSmtpAddress = Mail.sender.Address
  Else
    PR_SENT_REPRESENTING_ENTRYID = "http://schemas.microsoft.com/mapi/proptag/0x00410102"
    xEntryID = Mail.PropertyAccessor.BinaryToString(Mail.PropertyAccessor.GetProperty(PR_SENT_REPRESENTING_ENTRYID))
    Set xAddressEntry = xNameSpace.GetAddressEntryFromID(xEntryID)
    If xAddressEntry Is Nothing Then Exit Function
    If xAddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Or xAddressEntry.AddressEntryUserType = olExchangeRemoteUserAddressEntry Then
      Set xExchangeUser = xAddressEntry.GetExchangeUser()
      If xExchangeUser Is Nothing Then Exit Function
      GetSmtpAddress = xExchangeUser.PrimarySmtpAddress
    Else
      PR_SMTP_ADDRESS = "http://schemas.microsoft.com/mapi/proptag/0x39FE001E"
      GetSmtpAddress = xAddressEntry.PropertyAccessor.GetProperty(PR_SMTP_ADDRESS)
    End If
  End If
End Function

3. klik Tools > Referensi, lalu periksa Runtime Microsoft Scripting kotak di Referensi – Proyek1 kotak dialog.

4. tekan F5 kunci untuk menjalankan kode. Kemudian a Kutools untuk Outlook kotak dialog muncul, daftar semua alamat email pengirim dari email yang dipilih.

Tips:

Jika Anda perlu mengekspor daftar alamat ke file txt, klik tombol Yes .

Atau klik Tidak tombol untuk mengakhiri proses.