Bagaimana cara memindahkan rapat terkirim ke folder tertentu di Outlook secara otomatis?

Biasanya, setelah mengirim email atau rapat, keduanya akan ditempatkan di folder Item Terkirim. Jadi, folder Item Terkirim akan sangat berantakan dan tidak praktis. Artikel ini, saya akan memperkenalkan metode untuk memindahkan rapat terkirim ke folder lain secara otomatis setelah rapat dikirim.

Secara otomatis memindahkan pertemuan yang dikirim ke folder tertentu dengan kode VBA

Secara otomatis memindahkan pertemuan yang dikirim ke folder tertentu dengan kode VBA

Untuk memindahkan semua undangan rapat yang dikirim ke folder lain secara otomatis, kode berikut dapat membantu Anda, lakukan seperti ini:

1. Tahan ALT + F11 kunci untuk membuka Microsoft Visual Basic untuk Aplikasi jendela.

2. di Microsoft Visual Basic untuk Aplikasi jendela, klik dua kali Sesi Pandangan ini dari Project1 (VbaProject.OTM) panel untuk membuka mode, lalu salin dan tempel kode berikut ke dalam modul kosong.

Kode VBA: Secara otomatis memindahkan pertemuan terkirim ke folder tertentu

Private WithEvents GExplorer As Outlook.Explorer
Public WithEvents GSentFolder As Outlook.Folder
Public WithEvents GSentItems As Outlook.Items
Private Sub Application_Startup()
    Set GExplorer = Outlook.Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
Dim xFolder As Folder, xRootFolder As Folder
Dim xRootFldName As String
Dim xPos As Integer
    On Error Resume Next
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    xPos = VBA.InStr(3, xFolder.FolderPath, "\")
    If xPos > 0 Then
        xRootFldName = VBA.Mid(xFolder.FolderPath, 3, xPos - 3)
    Else
        xRootFldName = VBA.Mid(xFolder.FolderPath, 3, Len(xFolder.FolderPath) - 2)
    End If
    Set xRootFolder = Outlook.Application.Session.Folders(xRootFldName)
    Set GSentFolder = xRootFolder.Folders("Sent Items")
    Set GSentItems = GSentFolder.Items
End Sub
Private Sub GSentItems_ItemAdd(ByVal Item As Object)
    Dim xMeetingItem As Outlook.MeetingItem
    Dim xTargetFolder As Outlook.Folder
    On Error Resume Next
    If Item.Class <> olMeetingRequest Then Exit Sub
    Set xMeetingItem = Item
    Set xTargetFolder = GSentFolder.Folders("Meetings")
    If xTargetFolder Is Nothing Then
        Set xTargetFolder = GSentFolder.Folders.Add("Meetings")
    End If
    xMeetingItem.Move xTargetFolder
End Sub

doc pindah mengirim rapat 1

3. Kemudian, simpan dan tutup jendela kode. Sekarang, ketika email rapat dikirim, itu akan dipindahkan ke folder baru bernama Rapat bawah Item terkirim folder secara otomatis, lihat tangkapan layar:

doc pindah mengirim rapat 2