Bagaimana cara membalas secara normal di folder item terkirim dari Outlook? 

Biasanya, ketika Anda mengklik fitur Balas di folder Item terkirim untuk mengirim pesan tambahan lain untuk orang-orang yang telah Anda kirim, alamat email Anda sendiri akan ditampilkan di kolom Kepada seperti gambar berikut yang ditampilkan. Ini mungkin mengganggu jika Anda mengubah alamat setiap kali. Bagaimana cara membuat Outlook menggunakan alamat penerima asli, bukan milik Anda?

Balas secara normal di folder Item Terkirim dari Outlook dengan fitur Balas Semua

Balas secara normal di folder Item Terkirim dari Outlook dengan kode VBA

---

Balas secara normal di folder Item Terkirim dari Outlook dengan fitur Balas Semua

Di Outlook, file Membalas semua fitur dapat membantu Anda untuk memecahkan masalah ini, lakukan seperti ini:

Jika Anda perlu membalas email terkirim untuk dikirim kembali untuk mempertahankan alamat penerima asli, klik Membalas semua tombol, dan alamat penerima asli terletak di Untuk bidang seperti gambar berikut yang ditampilkan:

---

Balas secara normal di folder Item Terkirim dari Outlook dengan kode VBA

Terkadang, Anda mungkin lupa file Membalas semua fitur saat membalas pesan terkirim, sehingga kode VBA di bawah ini dapat membantu Anda membalas secara normal di folder Item Terkirim dengan menggunakan fitur Reply. Lakukan dengan langkah-langkah berikut:

1. Tahan ALT + F11 kunci untuk membuka Microsoft Visual Basic untuk Aplikasi jendela.

2. di Microsoft Visual Basic untuk Aplikasi jendela, klik dua kali Sesi Pandangan ini dari Project1 (VbaProject.OTM) panel untuk membuka mode, lalu salin dan tempel kode berikut ke dalam modul kosong.

Kode VBA: Balas secara normal di folder Item Terkirim dari Outlook:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3. Kemudian, simpan kode, dan mulai ulang Outlook untuk menerapkan efek kode, sekarang, saat mengklik membalas untuk mengirim ulang email masuk Item terkirim folder, alamat penerima asli ditampilkan di kolom Ke sesuai kebutuhan Anda.