Loncat ke daftar isi utama

Bagaimana cara mencetak tugas berdasarkan kategori di Outlook?

Misalkan, ada berbagai kategori warna di tugas Outlook Anda, dan sekarang, Anda ingin mencetak daftar tugas berdasarkan kategori di halaman berbeda. Bagaimana Anda bisa menyelesaikan pekerjaan ini di Outlook?

Cetak tugas berdasarkan kategori di halaman berbeda secara manual satu per satu

Tugas cetak berdasarkan kategori di halaman berbeda dengan kode VBA


Cetak tugas berdasarkan kategori di halaman berbeda secara manual satu per satu

Di Outlook, Anda dapat mencetak tugas secara manual berdasarkan kategori berbeda di halaman berbeda satu per satu, lakukan seperti ini:

1. Luncurkan Outlook, dan masuk ke panel Tugas dan pilih folder tugas yang ingin Anda cetak, lalu tekan Ctrl + E untuk mengaktifkan Pencarian kotak, dan kemudian di bawah Pencarian tab, klik Dikategorikan ikon, dan pilih satu kategori warna yang perlu Anda cetak, lihat tangkapan layar:

tugas cetak dokumen menurut kategori 1

2. Dan kemudian, semua tugas dengan kategori warna tertentu terdaftar sekaligus, lihat tangkapan layar:

tugas cetak dokumen menurut kategori 2

3. Lalu, lanjutkan dengan mengklik File > Mencetak untuk mencetak daftar tugas ini seperti gambar berikut yang ditampilkan:

tugas cetak dokumen menurut kategori 3

4. Ulangi langkah di atas untuk mencetak daftar tugas dengan kategori warna lain satu per satu secara manual.


Tugas cetak berdasarkan kategori di halaman berbeda dengan kode VBA

Berikut adalah kode VBA yang dapat membantu Anda mencetak tugas berdasarkan kategori di halaman berbeda sekaligus, lakukan dengan langkah-langkah berikut:

1. Pergi ke tugas panel dan pilih folder tugas yang ingin Anda cetak.

2. Lalu, tahan ALT + F11 kunci untuk membuka Microsoft Visual Basic untuk Aplikasi jendela.

3. Dan kemudian, klik Menyisipkan > Modul, salin dan tempel kode di bawah ini ke dalam modul kosong yang dibuka:

Kode VBA: Tugas cetak berdasarkan kategori di halaman berbeda:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesnโ€™t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. Lalu klik Tools > Referensi dalam Microsoft Visual Basic untuk Aplikasi jendela, di muncul keluar Referensi-Proyek 1 kotak dialog, periksa Perpustakaan Objek Microsoft Excel dan Runtime Microsoft Scripting opsi dari Referensi yang Tersedia kotak daftar, lihat tangkapan layar:

tugas cetak dokumen menurut kategori 4

5. Dan kemudian, klik OK tombol, sekarang, tekan F5 kunci untuk menjalankan kode ini, setelah menyelesaikan kode, daftar tugas dengan kategori berbeda akan dicetak di halaman berbeda.


Alat Produktivitas Kantor Terbaik

Kutools untuk Outlook - Lebih dari 100 Fitur Canggih untuk Meningkatkan Outlook Anda

๐Ÿค– Asisten Surat AI: Email profesional instan dengan keajaiban AI--satu klik untuk mendapatkan balasan jenius, nada sempurna, penguasaan multibahasa. Ubah email dengan mudah! ...

๐Ÿ“ง Email Otomatis: Di Luar Kantor (Tersedia untuk POP dan IMAP)  /  Jadwal Kirim Email  /  Auto CC/BCC Sesuai Aturan Saat Mengirim Email  /  Penerusan Otomatis (Aturan Lanjutan)   /  Tambah Salam Otomatis   /  Secara Otomatis Membagi Email Multi-Penerima menjadi Pesan Individual ...

๐Ÿ“จ email Management: Mengingat Email dengan Mudah  /  Blokir Email Penipuan berdasarkan Subjek dan Lainnya  /  Hapus Email Duplikat  /  Pencarian  /  Konsolidasi Folder ...

๐Ÿ“ Lampiran ProPenyimpanan Batch  /  Pelepasan Batch  /  Kompres Batch  /  Penyimpanan otomatis   /  Lepaskan Otomatis  /  Kompres Otomatis ...

๐ŸŒŸ Antarmuka Ajaib: ๐Ÿ˜ŠLebih Banyak Emoji Cantik dan Keren   /  Tingkatkan Produktivitas Outlook Anda dengan Tampilan Tab  /  Minimalkan Outlook Daripada Menutup ...

๐Ÿ‘ Keajaiban sekali klik: Balas Semua dengan Lampiran Masuk  /   Email Anti-Phishing  /  ๐Ÿ•˜Tampilkan Zona Waktu Pengirim ...

๐Ÿ‘ฉ๐Ÿผโ€๐Ÿคโ€๐Ÿ‘ฉ๐Ÿป Kontak & Kalender: Batch Tambahkan Kontak Dari Email yang Dipilih  /  Bagi Grup Kontak menjadi Grup Individual  /  Hapus Pengingat Ulang Tahun ...

Lebih 100 Fitur Tunggu Eksplorasi Anda! Klik Di Sini untuk Menemukan Lebih Banyak.

 

 

Comments (0)
No ratings yet. Be the first to rate!
There are no comments posted here yet
Please leave your comments in English
Posting as Guest
Rate this post:
0   Characters
Suggested Locations