Bagaimana cara menandai email secara otomatis berdasarkan lampiran tertentu dalam pandangan?

Saat menerima beberapa email dengan lampiran penting tertentu, Anda mungkin perlu menandainya, sehingga Anda dapat dengan cepat dan mudah menemukannya untuk mengalir. Artikel ini, saya akan berbicara tentang cara mudah untuk secara otomatis menandai email yang memiliki lampiran dengan nama tertentu.

Secara otomatis menandai email berdasarkan lampiran tertentu dengan kode VBA

Secara otomatis menandai email berdasarkan lampiran tertentu dengan kode VBA

Untuk menandai otomatis email yang berisi lampiran tertentu, harap gunakan kode VBA berikut:

1. Luncurkan Outlook, lalu tahan file ALT + F11 kunci untuk membuka Microsoft Visual Basic untuk Aplikasi jendela.

2. di Microsoft Visual Basic untuk Aplikasi jendela, klik dua kali Sesi Pandangan ini dari Project1 (VbaProject.OTM) panel untuk membuka mode baru, lalu salin dan tempel kode berikut ke dalam modul kosong.

Kode VBA: Tandai email secara otomatis berdasarkan lampiran tertentu:

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    If Item.Class <> olMail Then Exit Sub
    FlagEmail_SpecificAttachments Item
End Sub

Sub FlagEmail_SpecificAttachments(Mail As Outlook.MailItem)
    Dim xAttachment As Outlook.Attachment
    Dim xExt As String
    Dim xFileName As String
    If Mail.Attachments.Count = 0 Then Exit Sub
    For Each xAttachment In Mail.Attachments
        xExt = SplitPath(xAttachment.FileName, 2)
        xFileName = SplitPath(xAttachment.FileName, 1)
        Select Case xExt
            Case "txt", "xlsx", "docx", "pdf"  'Add the file extension as you need
                If InStr(LCase(xFileName), LCase("KTO")) > 0 Then 'Change the text of the attachment name
                    With Mail
                        .ReminderSet = True
                        .ReminderTime = Now + 1
                        .MarkAsTask olMarkTomorrow
                        .Save
                    End With
                End If
        End Select
    Next
End Sub

Public Function SplitPath(FullPath As String, ResultFlag As Integer) As String
Dim xSplitPos As Integer, xDotPos As Integer
xSplitPos = InStrRev(FullPath, "/")
xDotPos = InStrRev(FullPath, ".")
Select Case ResultFlag
    Case 0
        SplitPath = Left(FullPath, xSplitPos - 1)
    Case 1
        If xDotPos = 0 Then xDotPos = Len(FullPath) + 1
        SplitPath = Mid(FullPath, xSplitPos + 1, xDotPos - xSplitPos - 1)
    Case 2
        If xDotPos = 0 Then xDotPos = Len(FullPath)
        SplitPath = Mid(FullPath, xDotPos + 1)
    Case Else
    Err.Raise vbObjectError + 1, "SplitPath Function", "Invalid Parameter!"
End Select
End Function

Note: Pada kode di atas, Anda dapat mengubah ekstensi file dan nama file lampiran sesuai kebutuhan Anda.

3. Kemudian simpan kode, dan mulai ulang Outlook untuk membuat kode berlaku, sekarang, saat menerima email yang nama lampirannya berisi teks yang ditentukan, Outlook akan otomatis menandai email ini untuk ditindaklanjuti, lihat tangkapan layar: