Bagaimana cara mengubah tanda tangan secara otomatis berdasarkan penerima di Outlook?

Penulis: Siluvia Terakhir Dimodifikasi: 2022-08-01

Secara default, Outlook memiliki fungsi bawaan bagi pengguna untuk secara otomatis mengubah tanda tangan saat mengirim email melalui akun email yang berbeda. Namun di luar itu, di sini saya akan menunjukkan kepada Anda metode mengubah tanda tangan secara otomatis berdasarkan penerima yang berbeda di bidang Ke di Outlook.

Ubah tanda tangan berdasarkan penerima secara otomatis dengan kode VBA

Ubah tanda tangan berdasarkan penerima secara otomatis dengan kode VBA

Ikuti langkah-langkah di bawah ini untuk menerapkan tanda tangan yang berbeda ke penerima yang sesuai saat mengirim email di Outlook.

1. Pertama, Anda perlu menonaktifkan fitur tanda tangan terlampir otomatis di Outlook. Silakan klik File > Opsi untuk membuka Pilihan Outlook jendela.

2. Dalam Pilihan Outlook jendela, pilih surat di panel kiri, lalu klik Tanda tangan tombol di Tulis pesan bagian. Lihat tangkapan layar:

3. Dalam Tanda Tangan dan Alat Tulis kotak dialog, pergi ke Pilih tanda tangan default bagian bawah Tanda Tangan Email tab, pilih akun email di Akun email daftar drop-down, lalu pilih (Tidak ada) dari Pesan baru dan Balasan / penerusan daftar drop-down. Ulangi langkah-langkah ini hingga semua akun email disetel ke (Tidak ada). Kemudian klik OK .

Note: Anda juga dapat membuat tanda tangan yang Anda butuhkan di sini Tanda Tangan dan Alat Tulis kotak dialog.

4. Klik OK tombol saat mengembalikan Pilihan Outlook jendela.

5. tekan lain + F11 kunci untuk membuka Microsoft Visual Basic untuk Aplikasi jendela.

6. Dalam Microsoft Visual Basic untuk Aplikasi jendela, klik dua kali Sesi Pandangan ini di panel kiri untuk membuka jendela Kode, dan salinan di bawah kode VBA ke jendela. Lihat tangkapan layar:

Kode VBA: Secara otomatis mengubah tanda tangan berdasarkan penerima di Outlook

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
'Updated by ExtendOffice 2022/08/01
Dim xMailItem As MailItem
Dim xRecipients As Recipients
Dim xRecipient As Recipient
Dim xRcpAddress As String
Dim xSignatureFile, xSignaturePath As String
Dim xFSO As Scripting.FileSystemObject
Dim xDoc As Document
Dim xFindStr As String
On Error Resume Next
Set xFSO = New Scripting.FileSystemObject
If Item.Class <> olMail Then Exit Sub
Set xMailItem = Item
Set xRecipients = xMailItem.Recipients
xSignaturePath = CreateObject("WScript.Shell").SpecialFolders(5) + "\Microsoft\Signatures\"
For Each xRecipient In xRecipients
    If xRecipient.AddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Then
        xRcpAddress = xRecipient.AddressEntry.GetExchangeUser.PrimarySmtpAddress
    Else
        xRcpAddress = xRecipient.AddressEntry.Address
    End If
    Select Case xRcpAddress
        Case "Email Address 1"
            xSignatureFile = xSignaturePath & "aaa.htm"
            Exit For
        Case "Email Address 2", "Email Address 3"
            xSignatureFile = xSignaturePath & "bbb.htm"
            Exit For
        Case "Email Address 4"
            xSignatureFile = xSignaturePath & "ccc.htm"
            Exit For
    End Select
Next
VBA.DoEvents
Set xDoc = xMailItem.GetInspector.WordEditor
xFindStr = "From: " & xMailItem.Recipients.Item(1).Name & " <" & xRcpAddress & ">"
If VBA.InStr(1, xMailItem.Body, xFindStr) <> 0 Then
    xDoc.Application.Selection.HomeKey Unit:=wdStory, Extend:=wdMove
    With xDoc.Application.Selection.Find
        .ClearFormatting
        .Text = xFindStr
        .Execute Forward:=True
    End With
    With xDoc.Application.Selection
        .MoveLeft wdCharacter, 2
        .InsertParagraphAfter
        .MoveDown Unit:=wdLine, Count:=1
    End With
Else
    With xDoc.Application.Selection
        .EndKey Unit:=wdStory, Extend:=wdMove
        .InsertParagraphAfter
        .MoveDown Unit:=wdLine, Count:=1
    End With
End If
xDoc.Application.Selection.InsertFile FileName:=xSignatureFile, Link:=False, Attachment:=False
End Sub

Catatan:

1). Di kode VBA, harap ganti "Alamat Email 1/2/3/4”Dengan alamat email tertentu dari penerima.
2). "aaa.htm""bbb.htm"Dan"ccc.htm" adalah tanda tangan tertentu yang akan Anda kirim ke penerima yang sesuai.
3). Dalam hal ini, tanda tangan "aaa"Akan dikirim ke"Alamat Email 1", Tanda tangan"bbb"Akan dikirim ke"Alamat Email 2"Dan"Alamat Email 3", dan “Alamat Email 4"Akan menerima email yang disematkan dengan tanda tangan"ccc". Silakan ubah sesuai kebutuhan Anda.
4). Jika ada beberapa penerima dalam satu email, kode hanya mempertimbangkan penerima pertama. Dalam hal ini, penerima lain akan menerima email dengan tanda tangan yang sama dengan penerima pertama.

7. Lalu klik Tools > Referensi untuk pergi ke Referensi-Proyek kotak dialog. Dalam dialog, harap centang kedua Perpustakaan objek Microsoft Word dan Runtime Microsoft Scripting opsi, lalu klik OK tombol, lihat tangkapan layar:

8. tekan lain + Q kunci untuk menutup Microsoft Visual Basic untuk Aplikasi jendela.

Mulai sekarang, setelah membuat email dan menekan tombol Send, tanda tangan yang sesuai akan secara otomatis dimasukkan di akhir badan email berdasarkan alamat email penerima di kolom To.

Jika Anda ingin memasukkan stempel waktu sebagai tanda tangan ke badan email saat membuat / membalas / meneruskan email baru di Outlook Anda, Anda dapat mengaktifkan Tambahkan tanda tangan tanggal saat membuat baru, membalas dan meneruskan email pilihan dari Kutools untuk Outlook untuk mencapainya. Lihat tangkapan layar:
Unduh dan coba sekarang (jejak gratis 30 hari)