Bagaimana cara mengirim kalender ke beberapa penerima secara individual di Outlook?

Biasanya, Anda dapat mengirim kalender ke penerima dengan cepat dan mudah menggunakan Kalender Email fitur di Outlook. Jika Anda ingin mengirim kalender yang dilampirkan sebagai file iCalendar ke beberapa kontak satu per satu, Anda perlu mengirimkannya satu per satu. Pada artikel ini, saya akan berbicara tentang cara mudah mengirim kalender ke beberapa penerima secara individual di Outlook.

Kirim kalender ke beberapa penerima satu per satu dengan kode VBA

Kirim kalender ke beberapa penerima satu per satu dengan kode VBA

Untuk mengirim kalender ke beberapa penerima secara terpisah, kode VBA berikut dapat membantu Anda, lakukan seperti ini:

1. Arahkan ke kontak panel, dan pilih kontak yang ingin Anda kirimi kalender.

2. Kemudian tahan ALT + F11 kunci untuk membuka Microsoft Visual Basic untuk Aplikasi jendela.

3. Klik Menyisipkan > Modul, salin dan tempel kode di bawah ini ke dalam modul kosong yang dibuka, lihat tangkapan layar:

Kode VBA: Kirim kalender ke beberapa penerima secara individu ：

Sub EmailCalendarToMultiplePersonsSeparately()
Dim xSelection As Outlook.Selection
Dim xCalendarFolder As Outlook.Folder
Dim xCalendarExporter As Outlook.CalendarSharing
Dim xStartDate, xEndDate As Date
Dim xCalendarFile As String
Dim xContactItem As Outlook.ContactItem
Dim xDistListItem As Outlook.DistListItem
Dim xItem As Object
Dim xMailItem As Outlook.MailItem
Dim xFilePath, xFileName, xEmailAddress As String
Dim xRecipient As Recipient
On Error Resume Next
xFilePath = CreateObject("WScript.Shell").SpecialFolders(16) & "\MyCalendar"
If Dir(xFilePath, vbDirectory) = "" Then MkDir xFilePath
If Outlook.Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olContactItem Then
    MsgBox "Please Select contacts first!", vbExclamation + vbOKOnly, "Kutools for Outlook"
    Exit Sub
End If
Set xSelection = Outlook.Application.ActiveExplorer.Selection
If xSelection Is Nothing Then Exit Sub
Set xCalendarFolder = Outlook.Application.Session.PickFolder
If xCalendarFolder Is Nothing Then Exit Sub
If xCalendarFolder.DefaultItemType <> olAppointmentItem Then Exit Sub
Set xCalendarExporter = xCalendarFolder.GetCalendarExporter
xStartDate = InputBox("Enter the start date:", "Kutools for Outlook", "")
If Len(Trim(xStartDate)) = 0 Then Exit Sub
xEndDate = InputBox("Enter the end date:", "Kutools for Outlook", "")
If Len(Trim(xEndDate)) = 0 Then Exit Sub
If xStartDate = #1/1/4501# Or xEndDate = #1/1/4501# Then Exit Sub
xFileName = "Calendar (" & Format(xStartDate, "YYYYMMDD") & " - " & Format(xEndDate, "YYYYMMDD") & ").ics"
xCalendarFile = xFilePath & "\" & xFileName
With xCalendarExporter
    .IncludeWholeCalendar = False
    .StartDate = xStartDate
    .EndDate = xEndDate
    .CalendarDetail = olFullDetails
    .IncludeAttachments = True
    .IncludePrivateDetails = False
    .RestrictToWorkingHours = False
    .SaveAsICal xCalendarFile
End With
For Each xItem In xSelection
    If xItem.Class = olContact Then
        Set xContactItem = xItem
        Set xMailItem = Outlook.Application.CreateItem(olMailItem)
        With xMailItem
            .To = xContactItem.Email1Address
            .Recipients.ResolveAll
            .Subject = xFileName
            .Attachments.Add xCalendarFile
            .Body = "Dear " & xContactItem.FullName & "," & vbCrLf & "Type body here..."
            .Display
        End With
    End If
    If xItem.Class = olDistributionList Then
        Set xDistListItem = xItem
        For i = 1 To xDistListItem.MemberCount
            Set xRecipient = xDistListItem.GetMember(i)
            Set xMailItem = Outlook.Application.CreateItem(olMailItem)
            With xMailItem
                .To = xRecipient.AddressEntry.Address
                .Recipients.ResolveAll
                .Subject = xFileName
                .Attachments.Add xCalendarFile
                .Body = "Dear " & xRecipient.Name & "," & vbCrLf & "Type body here..."
                .Display
            End With
        Next i
    End If
Next
End Sub

4. Setelah memasukkan kode, lalu tekan F5 kunci untuk menjalankan kode ini, dan a Pilih Folder kotak dialog muncul, pilih kalender yang ingin Anda kirim, lihat tangkapan layar:

5. Klik OK, dan kemudian tentukan rentang tanggal yang Anda inginkan untuk mengirim kalender di kotak prompt berikut ini, lihat tangkapan layar:

6. Dan kemudian, klik OK, email baru dengan lampiran kalender telah dibuat seperti gambar di bawah ini, lalu Anda hanya perlu mengirimkannya satu per satu.