Bagaimana cara menghapus jenis lampiran tertentu dari email di Outlook?

Pernahkah Anda mencoba menghapus lampiran di beberapa email yang dipilih berdasarkan jenis file di Outlook? Seperti, menghapus semua file lampiran docx atau png dari email yang dipilih. Bagaimana Anda bisa menyelesaikan pekerjaan ini di Outlook?

Hapus jenis lampiran tertentu dari email dengan kode VBA

Hapus jenis lampiran tertentu dari email dengan kode VBA

Untuk menghapus jenis lampiran tertentu dari email yang dipilih, kode VBA berikut dapat membantu Anda, lakukan seperti ini:

1. Pilih email yang ingin Anda hapus jenis lampirannya di milis.

2. Tahan ALT + F11 kunci untuk membuka Microsoft Visual Basic untuk Aplikasi jendela.

3. Lalu klik Menyisipkan > Modul, salin dan tempel kode di bawah ini ke dalam modul kosong yang dibuka, lihat tangkapan layar:

Kode VBA: Hapus jenis lampiran tertentu dari email:

Sub DeleteSpecificTypeOfAttachments()
Dim xSelection As Outlook.Selection
Dim xItem As Object
Dim xMailItem As Outlook.MailItem
Dim xAttachment As Outlook.Attachment
Dim xFileType As String
Dim xType As String
Dim xFSO As Scripting.FileSystemObject
Dim I As Integer
On Error Resume Next
Set xSelection = Outlook.Application.ActiveExplorer.Selection
Set xFSO = New Scripting.FileSystemObject
xType = ""
xType = InputBox("Attachment Type:", "Kutools for Outlook", xType, 8)
If Len(Trim(xType)) = 0 Then Exit Sub
For Each xItem In xSelection
    If xItem.Class = olMail Then
        Set xMailItem = xItem
       If xMailItem.Attachments.Count > 0 Then
            For I = xMailItem.Attachments.Count To 1 Step -1
                Set xAttachment = xMailItem.Attachments.Item(I)
                xFileType = xFSO.GetExtensionName(xAttachment.FileName)
                If InStr(xFileType, Trim(xType)) > 0 Then
                    xAttachment.Delete
                End If
            Next I
            xMailItem.Save
        End If
    End If
Next
Set xMailItem = Nothing
Set xFSO = Nothing
End Sub

4. Dan kemudian masih di Microsoft Visual Basic untuk Aplikasi window, klik Tools > Referensi untuk pergi ke Referensi-Proyek 1 kotak dialog, dan centang Runtime Microsoft Scripting pilihan dari Referensi yang Tersedia kotak daftar, lihat tangkapan layar:

doc hapus lampirkan dengan tipe 1

5. Lalu klik OK untuk menutup dialog, sekarang, tekan F5 kunci untuk menjalankan kode ini, dan kotak prompt muncul, masukkan jenis lampiran yang ingin Anda hapus, lihat tangkapan layar:

doc hapus lampirkan dengan tipe 2