Loncat ke daftar isi utama

Bagaimana cara mengirim beberapa draf sekaligus di Outlook?

Jika ada beberapa pesan draf di folder Draf Anda, dan sekarang, Anda ingin mengirimnya sekaligus tanpa mengirim satu per satu. Bagaimana Anda bisa menangani pekerjaan ini dengan cepat dan mudah di Outlook?

Kirim semua pesan draf sekaligus di Outlook dengan kode VBA

Kirim semua pesan draf sekaligus di Outlook dengan kode VBA

Kode VBA berikut dapat membantu Anda mengirim semua atau draf email yang dipilih dari folder Draf sekaligus, lakukan seperti ini:

1. Tahan ALT + F11 kunci untuk membuka Microsoft Visual Basic untuk Aplikasi jendela.

2. Lalu klik Menyisipkan > Modul, salin dan tempel kode di bawah ini ke dalam modul kosong yang dibuka, lihat tangkapan layar:

Kode VBA: Kirim semua draf email sekaligus di Outlook:

Sub SendAllDraftEmails()
Dim xAccount As Account
Dim xDraftFld As Folder
Dim xItemCount As Integer
Dim xCount As Integer
Dim xDraftsItems As Outlook.Items
Dim xPromptStr As String
Dim xYesOrNo As Integer
Dim i As Long
Dim xCurFld As Folder
Dim xTmpFld As Folder
On Error Resume Next
xItemCount = 0
xCount = 0
Set xTmpFld = Nothing
Set xCurFld = Application.ActiveExplorer.CurrentFolder
For Each xAccount In Outlook.Application.Session.Accounts
    Set xDraftFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderDrafts)
    xItemCount = xItemCount + xDraftFld.Items.Count
    If xDraftFld.EntryID = xCurFld.EntryID Then
        Set xTmpFld = xCurFld.Parent
    End If
Next xAccount
Set xDraftFld = Nothing
If xItemCount > 0 Then
   xPromptStr = "Are you sure to send out all the drafts?"
    xYesOrNo = MsgBox(xPromptStr, vbQuestion + vbYesNo, "Kutools for Outlook")
    If xYesOrNo = vbYes Then
        If Not xTmpFld Is Nothing Then
            Set Application.ActiveExplorer.CurrentFolder = xTmpFld
        End If
        VBA.DoEvents
        For Each xAccount In Outlook.Application.Session.Accounts
            Set xDraftFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderDrafts)
            Set xDraftsItems = xDraftFld.Items
            For i = xDraftsItems.Count To 1 Step -1
                If xDraftsItems.Item(i).Recipients.Count <> 0 Then
                    xDraftsItems.Item(i).sEnd
                    xCount = xCount + 1
                End If
            Next
        Next xAccount
        VBA.DoEvents
        Set Application.ActiveExplorer.CurrentFolder = xCurFld
        MsgBox "Successfully sent " & xCount & " messages", vbInformation, "Kutools for Outlook"
    End If
Else
    MsgBox "No Drafts!", vbInformation + vbOKOnly, "Kutools for Outlook"
End If
End Sub

3. Kemudian simpan kodenya, dan tekan F5 kunci untuk menjalankan kode ini, kotak prompt akan muncul untuk mengingatkan Anda jika mengirim semua draf, klik Yes, lihat tangkapan layar:

4. Dan kotak dialog akan muncul untuk mengingatkan Anda berapa banyak draf email yang telah dikirim, lihat tangkapan layar:

5. Dan kemudian klik OK tombol, semua email di Konsep folder akan dikirim sekaligus, lihat tangkapan layar:

Catatan:

1. Kode di atas akan mengirim semua draf email dari semua akun di Outlook Anda.

2. Jika Anda hanya ingin mengirim beberapa email tertentu dari folder Draf, harap terapkan kode VBA berikut:

Kode VBA: Kirim email yang dipilih dari folder Draf:

Sub SendSelectedDraftEmails()
Dim xSelection As Selection
Dim xPromptStr As String
Dim xYesOrNo As Integer
Dim i As Long
Dim xAccount As Account
Dim xCurFld As Folder
Dim xDraftsFld As Folder
Dim xTmpFld As Folder
Dim xArr() As String
Dim xCount As Integer
Dim xMail As MailItem
On Error Resume Next
xCount = 0
Set xTmpFld = Nothing
Set xCurFld = Application.ActiveExplorer.CurrentFolder
For Each xAccount In Outlook.Application.Session.Accounts
    Set xDraftsFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderDrafts)
    If xDraftsFld.EntryID = xCurFld.EntryID Then
        Set xTmpFld = xCurFld.Parent
    End If
Next xAccount
If xTmpFld Is Nothing Then
    MsgBox "The current folder is not a draft folder", vbInformation, "Kutools for Outlook"
    Exit Sub
End If
Set xSelection = Outlook.Application.ActiveExplorer.Selection
If xSelection.Count > 0 Then
    xPromptStr = "Are you sure to send out the selected " & xSelection.Count & " draft item(s)?"
    xYesOrNo = MsgBox(xPromptStr, vbQuestion + vbYesNo, "Kutools for Outlook")
    If xYesOrNo = vbYes Then
        ReDim xArr(xSelection.Count - 1)
        For i = 1 To xSelection.Count
            xArr(i - 1) = xSelection.Item(i).EntryID
        Next
        Set Application.ActiveExplorer.CurrentFolder = xTmpFld
        VBA.DoEvents
        For i = 0 To UBound(xArr)
            Set xMail = Application.Session.GetItemFromID(xArr(i))
            If xMail.Recipients.Count <> 0 Then
                xMail.sEnd
                xCount = xCount + 1
            End If
        Next
        VBA.DoEvents
        Set Application.ActiveExplorer.CurrentFolder = xCurFld
        MsgBox "Successfully sent " & xCount & " messages", vbInformation, "Kutools for Outlook"
    End If
Else
    MsgBox "No items selected!", vbInformation, "Kutools for Outlook"
End If
End Sub

Artikel Terkait:

Bagaimana Cara Mengirim Email Ke Beberapa Penerima Secara Individual Di Outlook?

Bagaimana cara mengirim email massal yang dipersonalisasi ke daftar dari Excel melalui Outlook?

Bagaimana cara mengirim kalender ke beberapa penerima secara individual di Outlook?

Bagaimana cara mengirim email ke beberapa penerima tanpa mereka mengetahuinya di Outlook?

Alat Produktivitas Kantor Terbaik

Kutools untuk Outlook - Lebih dari 100 Fitur Canggih untuk Meningkatkan Outlook Anda

🤖 Asisten Surat AI: Email profesional instan dengan keajaiban AI--satu klik untuk mendapatkan balasan jenius, nada sempurna, penguasaan multibahasa. Ubah email dengan mudah! ...

📧 Email Otomatis: Di Luar Kantor (Tersedia untuk POP dan IMAP)  /  Jadwal Kirim Email  /  Auto CC/BCC Sesuai Aturan Saat Mengirim Email  /  Penerusan Otomatis (Aturan Lanjutan)   /  Tambah Salam Otomatis   /  Secara Otomatis Membagi Email Multi-Penerima menjadi Pesan Individual ...

📨 email Management: Mengingat Email dengan Mudah  /  Blokir Email Penipuan berdasarkan Subjek dan Lainnya  /  Hapus Email Duplikat  /  Pencarian  /  Konsolidasi Folder ...

📁 Lampiran Pro: Penyimpanan Batch  /  Pelepasan Batch  /  Kompres Batch  /  Penyimpanan otomatis   /  Lepaskan Otomatis  /  Kompres Otomatis ...

🌟 Antarmuka Ajaib: 😊Lebih Banyak Emoji Cantik dan Keren   /  Tingkatkan Produktivitas Outlook Anda dengan Tampilan Tab  /  Minimalkan Outlook Daripada Menutup ...

👍 Keajaiban sekali klik: Balas Semua dengan Lampiran Masuk  /   Email Anti-Phishing  /  🕘Tampilkan Zona Waktu Pengirim ...

👩🏼‍🤝‍👩🏻 Kontak & Kalender: Batch Tambahkan Kontak Dari Email yang Dipilih  /  Bagi Grup Kontak menjadi Grup Individual  /  Hapus Pengingat Ulang Tahun ...

Lebih 100 Fitur Tunggu Eksplorasi Anda! Klik Di Sini untuk Menemukan Lebih Banyak.

 

 

Comments (15)
No ratings yet. Be the first to rate!
JamesWood
JamesWood
This comment was minimized by the moderator on the site
Hi guys. Thought I'd share. Here's my code for sending all drafts:
Sub SendAllDrafts() 'By

If MsgBox("Are you sure you want to send ALL the items in your drafts folder?", _
vbQuestion + vbYesNo) <> vbYes Then Exit Sub

Dim myNamespace As Outlook.NameSpace 'Change view to Inbox to avoid inline error
Set myNamespace = Application.GetNamespace("MAPI") 'Change view to Inbox to avoid inline error
Set Application.ActiveExplorer.CurrentFolder = _
myNamespace.GetDefaultFolder(olFolderInbox) 'Change view to Inbox to avoid inline error

Dim fldDraft As MAPIFolder, msg As Outlook.MailItem, intCount As Integer
Set fldDraft = Outlook.GetNamespace("MAPI").GetDefaultFolder(olFolderDrafts) 'Sends all drafts in your main drafts folder. For a subfolder, add .Folders("folder name")
intCount = 0
Do While fldDraft.Items.count > 0
Set msg = fldDraft.Items(1)
msg.Send
intCount = intCount + 1
Loop
If Not (msg Is Nothing) Then Set msg = Nothing
Set fldDraft = Nothing
MsgBox intCount & " messages sent", vbInformation + vbOKOnly

End Sub
Reply
Report
0
0
James
James
This comment was minimized by the moderator on the site
This code sends all drafts in a subfolder called Merge Tools (it asks you before sending). I'm sure you guys can edit it to suit your needs though. It's far simpler. Enjoy :)
Sub SendAllMergeToolsDrafts()

If MsgBox("Are you sure you want to send ALL the items in your Merge Tools drafts folder?", _
vbQuestion + vbYesNo) <> vbYes Then Exit Sub

Dim myNamespace As Outlook.NameSpace 'Change view to Inbox to avoid inline error
Set myNamespace = Application.GetNamespace("MAPI") 'Change view to Inbox to avoid inline error
Set Application.ActiveExplorer.CurrentFolder = _
myNamespace.GetDefaultFolder(olFolderInbox) 'Change view to Inbox to avoid inline error

Dim fldDraft As MAPIFolder, msg As Outlook.MailItem, intCount As Integer
Set fldDraft = Outlook.GetNamespace("MAPI").GetDefaultFolder(olFolderDrafts).Folders("Merge Tools") 'Sends all drafts in the Merge Tools folder only
intCount = 0
Do While fldDraft.Items.count > 0
Set msg = fldDraft.Items(1)
msg.Send
intCount = intCount + 1
Loop
If Not (msg Is Nothing) Then Set msg = Nothing
Set fldDraft = Nothing
MsgBox intCount & " messages sent", vbInformation + vbOKOnly

End Sub
Reply
0
0
Julian
Julian
This comment was minimized by the moderator on the site
Hi, quick question maybe you have an Idea. We have an external application that saves all mails to the drafts folder. if i run the macro we have the problem, that only the first mail in the list is beeing sent correctly, all other mails are deferred because it adds quote marks ' ' to the mail adress.Is there a way to avoid this?
Reply
Report
0
0
Lukas
Lukas
This comment was minimized by the moderator on the site
Can you explain why the last mail (i = 1) is recreated in a new MailItem instead of just .Send?

Thanks.
Reply
0
0
denbo
denbo
This comment was minimized by the moderator on the site
We used the script to send all draft emails at once for a batch of statement emails generated from sage 200. The emails in the sent items look fine but customers are are receiving them with the body text in Chinese! Any ideas what could be happening here?
Reply
Report
0
0
Bill
Bill
This comment was minimized by the moderator on the site
Anybody get some emails sent to the deleted folder doing this?
Reply
0
0
Frank
Frank     Bill
This comment was minimized by the moderator on the site
Same problem: if you select 4 messages, after sending three of them ar in trash folder (because of the "xDraftsItems.Item(i).Delete" statement)
Reply
0
0
skyyang
skyyang     Bill
This comment was minimized by the moderator on the site
Hi, Bill,
Do you want to send multiple selected emails from deleted foder?
Please give your problem more detailed, thank you!
Reply
Report
0
0
Darewin
Darewin     skyyang
This comment was minimized by the moderator on the site
Hi skyyang, Im facing the same problem. I draft usually 15-20 emails and then use this code to send them all at once, but later realise that one of those emails do not get sent, rather they are sent to my 'Deleted' folder. Even the prompt says the correct number of emails for eg: '20 emails sent' but when I check, only 19 would have been sent, one I will find it lying in my deleted items folder. I want all the emails to be sent to their recipients without error. Can you please tell me why this happens. Please help.
Reply
0
0
skyyang
skyyang     Darewin
This comment was minimized by the moderator on the site
Hi, Darewin,We have updated the above codes, please try again, thank you!
Reply
Report
0
0
Donnie
Donnie
This comment was minimized by the moderator on the site
I have multiple exchange accounts. I want to have one of the accounts that isn't my default to be the sender. Where would I insert this in the code? Thanks!
Reply
0
0
Cathleen
Cathleen
This comment was minimized by the moderator on the site
Copied as per above but when I press F5 nothing happens
Reply
0
0
skyyang
skyyang     Cathleen
This comment was minimized by the moderator on the site
Hi, Cathleen,
The above code works fine in my Outlook, which Outlook version do you use?
Reply
Report
0
0
Colin
Colin
This comment was minimized by the moderator on the site
Brilliant, worked a charm, thank you :)
Reply
0
0
Günther Haas
Günther Haas     Colin
This comment was minimized by the moderator on the site
einfach nur perfekt. Herzlichen Dank
Reply
0
0
There are no comments posted here yet
Please leave your comments in English
Guest
Posting as Guest
×
Rate this post:
Reset
0   Characters
Suggested Locations