Bagaimana cara mendapatkan daftar folder di Outlook?

Terkadang struktur pohon semua folder email (termasuk folder pribadi yang dibuat) di Panel Navigasi bisa melakukan beberapa bantuan untuk pengguna Outlook selama pekerjaan mereka. Untuk daftar cepat seluruh folder struktur pohon, kode VBA dapat membantu Anda. Dalam tutorial ini, Anda dapat mempelajari cara mendapatkan daftar folder dengan mudah menggunakan kode VBA.

Dapatkan daftar folder di Outlook dengan kode VBA

Dapatkan daftar folder di Outlook dengan kode VBA

Untuk mendapatkan daftar folder di Outlook dengan kode VBA, lakukan hal berikut.

1. tekan lain + F11 pada keyboard untuk membuka Microsoft Visual Basic untuk Aplikasi jendela.

2. Kemudian klik dua kali file Project1 > Objek Microsoft Outlook > Sesi Pandangan ini untuk membuka Project1 - ThisOutlookSession jendela. Lihat tangkapan layar:

3. Kemudian salin dan tempel kode VBA di bawah ini ke dalam jendela Project1 - ThisOutlookSession.

VBA: dapatkan daftar folder di Outlook

Option Explicit
Sub GetFoldersList()
    On Error GoTo On_Error
    
    Dim Report As String
    Dim Folder As Outlook.Folder
       
    For Each Folder In Application.Session.Folders
        Report = Report & "---------------------------------------------------------------------------" & vbCrLf
        Call RecurseFolders(Folder, "", Report)
    Next
    Call CreateReportEmail("Outlook Folders List", Report)
    
Exiting:
    Exit Sub
On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
End Sub
Sub RecurseFolders(CurrentFolder As Outlook.Folder, TabChars, ByRef Report As String)
    Dim SubFolder As Outlook.Folder
    Dim FolderName, StoreName As String
    
    FolderName = CurrentFolder.Name
    StoreName = CurrentFolder.Store.DisplayName
    
    Report = Report & TabChars & FolderName & " (Store: " & StoreName & ")" & vbCrLf
    
    For Each SubFolder In CurrentFolder.Folders
        Call RecurseFolders(SubFolder, TabChars & vbTab, Report)
    Next SubFolder
End Sub
Sub CreateReportEmail(Title As String, Report As String)
    Dim aMail As MailItem
    
    Set aMail = Application.CreateItem(olMailItem)
        
    aMail.Subject = Title
    aMail.Body = Report
    
    aMail.Display
End Sub

4. tekan F5 pada keyboard untuk mulai menjalankan kode VBA.

5. Sekarang a Makro kotak dialog muncul, klik Run .

6. Tunggu Macro berjalan. Kemudian daftar semua folder email Anda akan segera dicantumkan di jendela pesan baru yang dibuat. Anda dapat dengan mudah mencetaknya. Lihat tangkapan layar:

Note: Kode VBA ini dapat diterapkan ke Outlook 2007, 2010, dan 2013.

---

Kutools for Outlook - Menghadirkan 100 Fitur Canggih ke Outlook, dan Membuat Pekerjaan Lebih Mudah!

• CC / BCC Otomatis dengan aturan saat mengirim email; Maju Otomatis Beberapa Email secara khusus; Balas otomatis tanpa server pertukaran, dan lebih banyak fitur otomatis ...
• Peringatan BCC - tunjukkan pesan ketika Anda mencoba membalas semua jika alamat email Anda ada di daftar BCC; Ingatkan Saat Lampiran Hilang, dan lebih banyak fitur pengingat ...
• Balas (Semua) Dengan Semua Lampiran di percakapan surat; Balas Banyak Email dalam hitungan detik; Tambah Salam Otomatis saat membalas; Tambahkan Tanggal ke dalam subjek ...
• Alat Lampiran: Kelola Semua Lampiran di Semua Email, Lepaskan Otomatis, Kompres Semua, Ganti Nama Semua, Simpan Semua ... Laporan Cepat, Hitung Email yang Dipilih...
• Email Sampah yang Kuat dengan kebiasaan; Hapus Duplikat Email dan Kontak... Memungkinkan Anda melakukan lebih cerdas, lebih cepat, dan lebih baik di Outlook.

Read More ... Unduh sekarang...