Loncat ke daftar isi utama

Bagaimana cara membuat daftar 10 atau n teratas dinamis di Excel?

Daftar teratas digunakan untuk menentukan peringkat perusahaan atau individu berdasarkan nilai. Misalkan, Anda memiliki daftar nilai siswa dari suatu kelas, sekarang, Anda ingin membuat daftar 10 siswa teratas yang dinamis seperti gambar di bawah ini. Pada artikel ini, saya akan memperkenalkan beberapa rumus untuk membuat daftar 10 atau n teratas di lembar kerja Excel.


Buat daftar 10 teratas dinamis di Excel

Di Excel 2019 dan versi yang lebih lama, untuk mengekstrak daftar 10 teratas atau daftar 10 teratas dengan kriteria, Anda harus menerapkan rumus berikut:

Rumus untuk membuat daftar 10 teratas yang dinamis

1. Pertama, Anda harus mengekstrak 10 nilai teratas dari rentang data, gunakan rumus di bawah ini ke dalam sel kosong - G2, dan seret gagang isian ke bawah untuk mendapatkan 10 nilai teratas, lihat tangkapan layar:

=LARGE($B$2:$B$20,ROWS(B$2:B2))
Note: Dalam rumus ini, B2: B20 adalah daftar data tempat Anda ingin mendapatkan 10 nilai teratas, dan B2 adalah sel pertama dari daftar data.

2. Kemudian, lanjutkan menerapkan rumus berikut ke dalam sel - F2, dan tekan Ctrl + Shift + Enter kunci bersama untuk mendapatkan hasil pertama, lihat tangkapan layar:

=INDEX($A$2:$A$20,SMALL(IF($B$2:$B$20=G2,ROW($B$2:$B$20)-ROW($B$1)),COUNTIF($G$2:G2,G2)))
Note: Dalam rumus di atas, A2: A20 adalah daftar data yang ingin Anda tarik nama dari 10 nilai teratas, B2: B20 adalah daftar data yang berisi semua nilai, G2 adalah sel dengan nilai terbesar yang diekstraksi dari kolom B dan B1 adalah sel header dari daftar nilai.

3. Setelah mendapatkan hasil pertama, pilih sel rumus dan seret gagang isian ke bawah untuk mendapatkan nama lain sekaligus, lihat tangkapan layar:


Rumus untuk membuat daftar 10 teratas dinamis dengan kriteria

Terkadang, Anda mungkin perlu mendapatkan daftar 10 teratas berdasarkan kriteria. Misalnya, untuk mendapatkan 10 nama teratas dan skor Kelas1 seperti gambar di bawah ini.

1. Untuk mendapatkan daftar 10 teratas, Anda juga harus mengekstrak 10 skor teratas dengan rumus ini:

=LARGE(IF($B$2:$B$25=$F$2,$C$2:$C$25),ROW(I2)-ROW(I$1))

2. Lalu tekan Ctrl + Shift + Enter kunci bersama untuk mendapatkan hasil pertama, lalu seret rumus ini ke bawah untuk menampilkan nilai lain, lihat tangkapan layar:

3. Kemudian, silakan salin dan tempel rumus berikut ke dalam sel - I2, dan tekan Ctrl + Shift + Enter kunci secara bersamaan untuk mengekstrak hasil pertama, lalu seret rumus ini untuk mengisinya ke sel lain, dan 10 nama teratas ditampilkan seperti gambar di bawah ini:

=INDEX($A$2:$A$25,SMALL(IF(($C$2:$C$25=J2)*($B$2:$B$25=$F$2),ROW($C$2:$C$25)-ROW($C$1)),COUNTIF(J2:$J$2,J2)))

Buat daftar 10 teratas dinamis di Office 365

Rumus di atas mungkin sulit untuk kita pahami, jika Anda menggunakan Office 365, dengan fungsi INDEX, SORT dan SEQUENCE, Anda dapat membuat rumus sederhana untuk menyelesaikan tugas ini.

Rumus untuk membuat daftar 10 teratas yang dinamis

Untuk mendapatkan 10 daftar data, gunakan rumus di bawah ini:

=INDEX(SORT(A2:B20,2,-1),SEQUENCE(10),{1,2})

Dan kemudian, cukup tekan Enter kunci, semua data dari daftar 10 teratas ditampilkan sekaligus, lihat tangkapan layar:

Tips:

Fungsi SORT:

=SORT(array, [sort_index], [sort_order], [by_col])

  • susunan: Rentang sel yang ingin Anda urutkan;
  • [urutan_indeks]: Nomor kolom atau baris yang akan diurutkan ke dalam larik. Misalnya, untuk mengurutkan menurut kolom kedua dari rentang data, indeks pengurutan akan menjadi 2;
  • [urutan_urutan]: Angka 1 (atau dihilangkan) menunjukkan untuk mengurutkan dalam urutan menaik; angka -1, urutkan dalam urutan menurun;
  • [oleh_kol]: Arah pengurutan. TRUE, urutkan menurut kolom, FALSE atau dihilangkan, urutkan menurut baris.

Dalam rumus, kami menggunakan fungsi SORT sebagai berikut:

URUTKAN(A2:B20,2,-1): Berarti mengurutkan rentang sel A2:A20 pada kolom kedua dalam urutan menurun.


Fungsi URUTAN:

=SEQUENCE(baris, [kolom], [mulai], [langkah])

  • baris: Jumlah baris yang akan dikembalikan,
  • [kolom]: Jumlah kolom yang akan dikembalikan. Jika dihilangkan, itu akan mengembalikan satu kolom.
  • [Mulailah]: Angka pertama dalam urutan. Jika dihilangkan, itu akan dimulai pada 1.
  • [melangkah]: Kenaikan antara setiap nomor. Jika dikecualikan, setiap kenaikan akan menjadi 1.

Dalam rumus ini, kami menggunakan SEQUENCE(10) untuk membuat daftar dari 1 hingga 10.

Terakhir, masukkan fungsi SORT dan SEQUENCE ke dalam fungsi INDEX: =INDEX(SORT(A2:B20,2,-1),SEQUENCE(10),{1,2}), ini akan mengembalikan 10 catatan pertama dari rentang data dan mengembalikan kolom 1 dan 2.


Rumus untuk membuat daftar 10 teratas dinamis dengan kriteria

Untuk menampilkan daftar 10 teratas dengan kriteria, Anda harus menyematkan fungsi FILTER ke dalam fungsi SORT seperti ini:

=INDEX(SORT(FILTER(A2:C25,B2:B25=F2),3,-1),SEQUENCE(10),{1,3})

Dan cukup tekan Enter key, semua data dari daftar 10 teratas berdasarkan kriteria yang diberikan ditampilkan sekaligus, lihat tangkapan layar:

Tips:

Fungsi FILTER:

=FILTER(array, sertakan, [jika_kosong])

  • susunan: Rentang sel yang akan difilter.
  • memasukkan: Kondisi yang Anda gunakan untuk memfilter array untuk mendapatkan hasil array TRUE atau FALSE, sehingga nilai TRUE akan dipertahankan dalam filter.
  • [jika_kosong]: Nilai yang akan ditampilkan jika tidak ada hasil yang cocok yang dikembalikan.

Dalam rumus ini: =FILTER(A2:C25,B2:B25=F2) digunakan untuk memfilter dalam rentang A2:C25, di mana nilai dari B2:B25 sama dengan sel tertentu F2.

Alat Produktivitas Kantor Terbaik

Fitur Populer: Temukan, Sorot, atau Identifikasi Duplikat   |  Hapus Baris Kosong   |  Gabungkan Kolom atau Sel tanpa Kehilangan Data   |   Putaran tanpa Formula ...
Pencarian Super: VLookup Beberapa Kriteria    VLookup Nilai Berganda  |   VLookup di Beberapa Lembar   |   Pencarian Fuzzy ....
Daftar Drop-down Lanjutan: Buat Daftar Drop Down dengan Cepat   |  Daftar Drop Down yang Bergantung   |  Multi-pilih Drop Down List ....
Manajer Kolom: Tambahkan Jumlah Kolom Tertentu  |  Pindahkan Kolom  |  Alihkan Status Visibilitas Kolom Tersembunyi  |  Bandingkan Rentang & Kolom ...
Fitur Unggulan: Fokus Kisi   |  Tampilan Desain   |   Bar Formula Besar    Manajer Buku Kerja & Lembar   |  Perpustakaan Sumberdaya (Teks otomatis)   |  Pemetik tanggal   |  Gabungkan Lembar Kerja   |  Enkripsi/Dekripsi Sel    Kirim Email berdasarkan Daftar   |  Filter Super   |   Filter Khusus (filter tebal/miring/coret...) ...
15 Perangkat Teratas12 Teks Tools (Tambahkan Teks, Hapus Karakter, ...)   |   50 + Grafik jenis (Gantt Chart, ...)   |   40+ Praktis Rumus (Hitung usia berdasarkan ulang tahun, ...)   |   19 Insersi Tools (Masukkan Kode QR, Sisipkan Gambar dari Jalur, ...)   |   12 Konversi Tools (Angka ke Kata, Konversi Mata Uang, ...)   |   7 Gabungkan & Pisahkan Tools (Lanjutan Gabungkan Baris, Pisahkan Sel, ...)   |   ... dan banyak lagi

Tingkatkan Keterampilan Excel Anda dengan Kutools for Excel, dan Rasakan Efisiensi yang Belum Pernah Ada Sebelumnya. Kutools for Excel Menawarkan Lebih dari 300 Fitur Lanjutan untuk Meningkatkan Produktivitas dan Menghemat Waktu.  Klik Di Sini untuk Mendapatkan Fitur yang Paling Anda Butuhkan...

tab kte 201905


Tab Office Membawa antarmuka Tab ke Office, dan Membuat Pekerjaan Anda Jauh Lebih Mudah

  • Aktifkan pengeditan dan pembacaan tab di Word, Excel, PowerPoint, Publisher, Access, Visio, dan Project.
  • Buka dan buat banyak dokumen di tab baru di jendela yang sama, bukan di jendela baru.
  • Meningkatkan produktivitas Anda sebesar 50%, dan mengurangi ratusan klik mouse untuk Anda setiap hari!
Comments (0)
No ratings yet. Be the first to rate!
There are no comments posted here yet
Please leave your comments in English
Posting as Guest
×
Rate this post:
0   Characters
Suggested Locations