Tutorial Excel: Perhitungan DateTime (hitung selisih, umur, tambah/kurangi)

Di Excel, perhitungan waktu tanggal sering digunakan, seperti menghitung selisih antara dua tanggal/waktu, menambah atau mengurangi waktu tanggal, mendapatkan usia berdasarkan tanggal lahir dan sebagainya. Di sini, di tutorial ini, daftar hampir skenario tentang perhitungan datetime dan menyediakan metode terkait untuk Anda.

Navigasi Tutorial Ini

1. Hitung perbedaan antara dua tanggal/waktu 1.1 Hitung perbedaan hari/bulan/tahun antara dua tanggal 1.11 Hitung perbedaan antara dua tanggal dalam hari/bulan/tahun/minggu 1.12 Hitung bulan abaikan tahun dan hari antara dua tanggal 1.13 Hitung hari mengabaikan tahun dan bulan antara dua tanggal 1.14 Hitung perbedaan antara dua tanggal dan kembalinya tahun, bulan dan hari 1.15 Hitung perbedaan antara tanggal dan hari ini 1.16 Hitung hari kerja dengan atau tanpa hari libur antara dua tanggal 1.17 Hitung akhir pekan antara dua tanggal 1.18 Hitung hari kerja tertentu antara dua tanggal 1.19 Hitung sisa hari dalam bulan/tahun

1.2 Hitung selisih antara dua kali 1.21 Hitung selisih antara dua kali 1.22 Hitung perbedaan antara dua kali dalam jam/menit/detik 1.23 Hitung selisih jam hanya antara dua kali (tidak melebihi 24 jam) 1.24 Hitung selisih menit hanya antara dua kali (tidak melebihi 60 menit) 1.25 Hitung selisih detik hanya antara dua kali (tidak melebihi 60 detik) 1.26 Hitung perbedaan antara dua kali dan kembalinya jam, menit, detik 1.27 Hitung perbedaan antara dua waktu kencan 1.28 Hitung perbedaan waktu dengan milidetik 1.29 Hitung jam kerja antara dua tanggal tidak termasuk akhir pekan

1.3 Hitung selisih antara dua datetime dengan Kutools for Excel 1.31 Hitung perbedaan antara dua waktu dengan Data & Time Helper 1.32 Menghitung perbedaan akhir pekan/hari kerja/hari kerja tertentu antara dua waktu dengan Formula Helper

1.4 Gabungkan dua kolom jika kosong 1.41 Menggunakan fungsi JIKA 1.42 Menggunakan VBA

2. Tambah atau kurangi tanggal dan waktu 2.1 Menambah atau mengurangi hari/bulan/tahun/minggu/hari kerja ke tanggal 2.11 Menambah atau mengurangi hari ke tanggal 2.12 Menambah atau mengurangi bulan ke tanggal 2.13 Menambah atau mengurangi tahun pada tanggal 2.14 Menambah atau mengurangi minggu ke tanggal 2.15 Menambah atau mengurangi hari kerja termasuk atau tidak termasuk hari libur 2.16 Menambah atau mengurangi tahun, bulan, hari tertentu hingga tanggal

2.2 Menambah atau mengurangi jam/menit/detik ke waktu 2.21 Menambah atau mengurangi jam/menit/detik ke waktu tanggal 2.22 Jumlah kali selama 24 jam 2.23 Tambahkan jam kerja ke tanggal tidak termasuk akhir pekan dan hari libur

2.3 Tambahkan atau kurangi tanggal/waktu dengan Kutools for Excel

2.4 Ekstensi 2.41 Centang atau sorot jika tanggal kedaluwarsa 2.42 Mengembalikan akhir bulan berjalan/hari pertama bulan depan

3. Hitung usia 3.1 Hitung usia berdasarkan tanggal 3.11 Hitung usia berdasarkan tanggal lahir yang diberikan 3.12 Hitung usia dalam format tahun, bulan dan hari dengan tanggal lahir yang diberikan 3.13 Hitung usia berdasarkan tanggal lahir sebelum 1/1/1900

3.2 Menghitung usia berdasarkan kelahiran dengan menggunakan Kutools for Excel

3.3 Hitung usia atau dapatkan tanggal lahir berdasarkan nomor seri 3.31 Dapatkan ulang tahun dari nomor ID 3.32 Hitung usia dari nomor ID

 

Dalam tutorial ini, saya membuat beberapa contoh untuk menjelaskan metode, Anda dapat mengubah referensi yang Anda butuhkan ketika Anda menggunakan kode atau rumus VBA di bawah ini.

---

1. Hitung perbedaan antara dua tanggal/waktu

Menghitung perbedaan antara dua tanggal atau dua kali mungkin merupakan masalah paling normal dari perhitungan datetime yang Anda temui dalam pekerjaan Excel sehari-hari. Contoh pengikut di bawah ini dapat membantu Anda meningkatkan efisiensi ketika Anda menghadapi masalah yang sama.

1.11 Hitung perbedaan antara dua tanggal dalam hari/bulan/tahun/minggu

Fungsi Excel DATEDIF dapat digunakan untuk menghitung perbedaan antara dua tanggal dalam hari, bulan, tahun, dan minggu dengan cepat.

Klik untuk detail lebih lanjut tentang TANGGAL fungsi

Perbedaan hari antara dua tanggal

Untuk mendapatkan perbedaan hari antara dua tanggal di sel A2 dan B2, gunakan rumus seperti ini

=DATEDIF(A2,B2,"d")

Tekan Enter kunci untuk mendapatkan hasil.

Perbedaan bulan antara dua tanggal

Untuk mendapatkan perbedaan bulan antara dua tanggal di sel A5 dan B5, gunakan rumus seperti ini

=DATEDIF(A5,B5,"m")

Tekan Enter kunci untuk mendapatkan hasil.

Perbedaan tahun antara dua tanggal

Untuk mendapatkan perbedaan tahun antara dua tanggal di sel A8 dan B8, gunakan rumus seperti ini:

=DATEDIF(A8,B8,"y")

Tekan Enter kunci untuk mendapatkan hasil.

Perbedaan minggu antara dua tanggal

Untuk mendapatkan perbedaan minggu antara dua tanggal di sel A11 dan B11, gunakan rumus seperti ini

=DATEDIF(A11,B11,"d")/7

Tekan Enter kunci untuk mendapatkan hasil.

Catatan:

1) Bila Anda menggunakan rumus di atas untuk mendapatkan perbedaan minggu, mungkin mengembalikan hasil dalam format tanggal, Anda perlu memformat hasilnya ke umum atau nomor yang Anda butuhkan.

2) Bila Anda menggunakan rumus di atas untuk mendapatkan selisih minggu, mungkin akan kembali ke angka desimal, jika Anda ingin mendapatkan bilangan minggu bilangan bulat, Anda dapat menambahkan fungsi ROUNDDOWN sebelumnya seperti yang ditunjukkan di bawah ini untuk mendapatkan selisih minggu bilangan bulat:

=ROUNDDOWN(DATEDIF(A11,B11,"d")/7,0)

1.12 Hitung bulan abaikan tahun dan hari antara dua tanggal

Jika Anda hanya ingin menghitung perbedaan bulan dengan mengabaikan tahun dan hari antara dua tanggal seperti yang ditunjukkan gambar di bawah, berikut adalah rumus yang dapat membantu Anda.

=DATEDIF(A2,B2,"ym")

Tekan Enter kunci untuk mendapatkan hasil.

A2 adalah tanggal mulai, dan B2 adalah tanggal akhir.

1.13 Hitung hari mengabaikan tahun dan bulan antara dua tanggal

Jika Anda hanya ingin menghitung perbedaan hari dengan mengabaikan tahun dan bulan antara dua tanggal seperti gambar di bawah ini, berikut adalah rumus yang dapat membantu Anda.

=DATEDIF(A5,B5,"md")

Tekan Enter kunci untuk mendapatkan hasil.

A5 adalah tanggal mulai, dan B5 adalah tanggal akhir.

1.14 Hitung perbedaan antara dua tanggal dan kembalinya tahun, bulan dan hari

Jika Anda ingin mendapatkan perbedaan antara dua tanggal dan pengembalian xx tahun, xx bulan, dan xx hari seperti yang ditunjukkan gambar di bawah, berikut juga rumus yang disediakan.

=DATEDIF(A8, B8, "y") &" years, "&DATEDIF(A8, B8, "ym") &" months, " &DATEDIF(A8, B8, "md") &" days"

Tekan Enter kunci untuk mendapatkan hasil.

A8 adalah tanggal mulai, dan B8 adalah tanggal akhir.

1.15 Hitung perbedaan antara tanggal dan hari ini

Untuk secara otomatis menghitung perbedaan antara tanggal dan hari ini, cukup ubah tanggal_akhir dalam rumus di atas menjadi HARI INI(). Di sini ambil untuk menghitung perbedaan hari antara tanggal yang lalu dan hari ini sebagai contoh.

=DATEDIF(A11,TODAY(),"d")

Tekan Enter kunci untuk mendapatkan hasil.

Note: jika Anda ingin menghitung perbedaan antara tanggal mendatang dan hari ini, ubah tanggal_mulai menjadi hari ini, dan jadikan tanggal mendatang sebagai tanggal_akhir seperti ini:

=DATEDIF(TODAY(),A14,"d")

Perhatikan bahwa tanggal_mulai harus lebih kecil dari tanggal_akhir dalam fungsi DATEDIF, jika tidak, ia akan kembali ke #NUM! nilai kesalahan.

1.16 Hitung hari kerja dengan atau tanpa hari libur antara dua tanggal

Terkadang, Anda mungkin perlu menghitung jumlah hari kerja dengan atau tanpa hari libur di antara dua tanggal yang ditentukan.

Di bagian ini, Anda akan menggunakan fungsi NETWORKDAYS.INTL:

Klik NETWORKDAYS.INTL untuk mengetahui argumen dan penggunaannya.

Hitung hari kerja dengan hari libur

Untuk menghitung hari kerja dengan hari libur antara dua tanggal di sel A2 dan B2, gunakan rumus seperti ini:

=NETWORKDAYS.INTL(A2,B2)

Tekan Enter kunci untuk mendapatkan hasil.

Hitung hari kerja tanpa hari libur

Untuk menghitung hari kerja dengan hari libur antara dua tanggal di sel A2 dan B2, dan mengecualikan hari libur dalam rentang D5:D9, gunakan rumus seperti ini:

=NETWORKDAYS.INTL(A5,B5,1,D5:D9)

Tekan Enter kunci untuk mendapatkan hasil.

Catatan:

Dalam rumus di atas, mereka mengambil hari Sabtu dan Minggu sebagai akhir pekan, jika Anda memiliki hari akhir pekan yang berbeda, silakan ubah argumen [akhir pekan] sesuai kebutuhan.

1.17 Hitung akhir pekan antara dua tanggal

Jika Anda ingin menghitung jumlah akhir pekan di antara dua tanggal, fungsi SUMPRODUCT atau SUM dapat membantu Anda.

Untuk menghitung akhir pekan (Sabtu dan Minggu) antara dua tanggal di sel A12 dan B12:

=SUMPRODUCT(--(WEEKDAY(ROW(INDIRECT(A12&":"&B12)),2)>5))

Or

=SUM(INT((WEEKDAY(A12-{1,7})+B12-A12)/7))

Tekan Enter kunci untuk mendapatkan hasil.

1.18 Hitung hari kerja tertentu antara dua tanggal

Untuk menghitung jumlah hari kerja tertentu seperti Senin antara dua tanggal, kombinasi fungsi INT dan WEEKDAY dapat membantu Anda.

Sel A15 dan B15 adalah dua tanggal yang ingin Anda hitung di antara hari Senin, gunakan rumus seperti ini:

=INT((WEEKDAY(A15- 2)-A15 +B15)/7)

Tekan Enter kunci untuk mendapatkan hasil.

Ubah jumlah hari kerja dalam fungsi WEEKDAY untuk menghitung hari kerja yang berbeda:

1 adalah Minggu, 2 adalah Senin, 3 adalah Selasa, 4 adalah Rabu, 5 adalah Kamis, 6 adalah Jumat dan 7 adalah Sabtu)

1.19 Hitung sisa hari dalam bulan/tahun

Terkadang, Anda mungkin ingin mengetahui sisa hari dalam bulan atau tahun berdasarkan tanggal yang disediakan seperti yang ditunjukkan oleh tangkapan layar di bawah ini:

Dapatkan sisa hari di bulan ini

Klik EOBULAN untuk mengetahui argumen dan penggunaan.

Untuk mendapatkan sisa hari bulan berjalan di sel A2, gunakan rumus seperti ini:

=EOMONTH(A2,0)-A2

Tekan Enter tombol, dan seret pegangan pengisian otomatis untuk menerapkan rumus ini ke sel lain jika diperlukan.

olymp trade indonesiaTip: hasilnya dapat ditampilkan sebagai format tanggal, cukup ubah sebagai format umum atau angka.

Dapatkan sisa hari di tahun ini

Untuk mendapatkan sisa hari tahun berjalan di sel A2, gunakan rumus seperti ini:

=DATE(YEAR(A2),12,31)-A2

Tekan Enter tombol, dan seret pegangan pengisian otomatis untuk menerapkan rumus ini ke sel lain jika diperlukan.

---

1.21 Hitung selisih antara dua kali

Untuk mendapatkan perbedaan antara dua kali, berikut adalah dua rumus sederhana yang dapat membantu Anda.

Misalkan di sel A2 dan B2 berisi start_time dan end_time secara terpisah, menggunakan rumus sebagai berikut:

=B2-A2

=TEXT(B2-A2,"hh:mm:ss")

Tekan Enter kunci untuk mendapatkan hasil.

Catatan:

• Jika Anda menggunakan end_time-start_time, Anda dapat memformat hasilnya ke format waktu lain yang Anda butuhkan dalam dialog Format Cells.
• Jika Anda menggunakan TEXT(end_time-first_time,"time_format"), masukkan format waktu yang Anda inginkan agar hasilnya ditampilkan dalam rumus, seperti TEXT(end_time-first_time,"h") mengembalikan 16.
• Jika end_time lebih kecil dari start_time, kedua rumus mengembalikan nilai kesalahan. Untuk mengatasi masalah ini, Anda dapat menambahkan ABS di depan rumus ini, seperti ABS(B2-A2), ABS(TEXT(B2-A2,"hh:mm:ss")), lalu memformat hasilnya sebagai waktu.

1.22 Hitung perbedaan antara dua kali dalam jam/menit/detik

Jika Anda ingin menghitung perbedaan antara dua kali dalam jam, menit, atau detik seperti gambar di bawah ini, ikuti bagian ini.

Dapatkan perbedaan jam antara dua kali

Untuk mendapatkan perbedaan jam antara dua waktu di A5 dan B5, gunakan rumus seperti ini:

=INT((B5-A5)*24)

Tekan Enter kunci, lalu format hasil format waktu sebagai umum atau angka.

Jika Anda ingin mendapatkan perbedaan jam desimal, gunakan (end_time-start_time)*24.

Dapatkan perbedaan menit antara dua kali

Untuk mendapatkan perbedaan menit antara dua kali di A8 dan B8, gunakan rumus seperti ini:

=INT((B8-A8)*1440)

Tekan Enter kunci, lalu format hasil format waktu sebagai umum atau angka.

Jika Anda ingin mendapatkan perbedaan menit desimal, gunakan (end_time-start_time)*1440.

Dapatkan perbedaan detik antara dua kali

Untuk mendapatkan selisih detik antara dua waktu di A5 dan B5, gunakan rumus seperti ini:

=(B11-A11)*86400)

Tekan Enter kunci, lalu format hasil format waktu sebagai umum atau angka.

1.23 Hitung selisih jam hanya antara dua kali (tidak melebihi 24 jam)

Jika perbedaan antara dua waktu tidak melebihi 24 jam, fungsi JAM dapat dengan cepat mendapatkan perbedaan jam antara dua waktu tersebut.

Klik HOUR untuk lebih jelasnya tentang fungsi ini.

Untuk mendapatkan perbedaan jam antara waktu di sel A14 dan B14, gunakan fungsi JAM seperti ini:

=HOUR(B14-A14)

Tekan Enter kunci untuk mendapatkan hasil.

Start_time harus lebih kecil dari end_time, jika tidak, rumus mengembalikan #NUM! nilai kesalahan.

1.24 Hitung selisih menit hanya antara dua kali (tidak melebihi 60 menit)

Fungsi MENIT dapat dengan cepat mendapatkan satu-satunya perbedaan menit antara dua waktu ini dan mengabaikan jam dan detik.

Klik MENIT untuk lebih jelasnya tentang fungsi ini.

Untuk mendapatkan hanya perbedaan menit antara waktu di sel A17 dan B17, gunakan fungsi MENIT seperti ini:

=MINUTE(B17-A17)

Tekan Enter kunci untuk mendapatkan hasil.

Start_time harus lebih kecil dari end_time, jika tidak, rumus mengembalikan #NUM! nilai kesalahan.

1.25 Hitung selisih detik hanya antara dua kali (tidak melebihi 60 detik)

Fungsi SECOND dapat dengan cepat mendapatkan satu-satunya perbedaan detik antara dua waktu ini dan mengabaikan jam dan menit.

Klik KEDUA untuk lebih jelasnya tentang fungsi ini.

Untuk mendapatkan hanya selisih detik antara waktu di sel A20 dan B20, gunakan fungsi SECOND seperti ini:

=SECOND(B20-A20)

Tekan Enter kunci untuk mendapatkan hasil.

Start_time harus lebih kecil dari end_time, jika tidak, rumus mengembalikan #NUM! nilai kesalahan.

1.26 Hitung perbedaan antara dua kali dan kembalinya jam, menit, detik

Jika Anda ingin menunjukkan perbedaan antara dua kali xx jam xx menit xx detik, silakan gunakan fungsi TEXT seperti yang ditunjukkan di bawah ini:

Klik TEKS untuk mewujudkan argumen dan penggunaan fungsi ini.

Untuk menghitung perbedaan antara waktu di sel A23 dan B23, gunakan rumus sebagai berikut:

=TEXT(B23-A23,"h"" hours ""m"" minutes ""s"" seconds""").

Tekan Enter kunci untuk mendapatkan hasil.

Catatan:

Rumus ini juga hanya menghitung perbedaan jam tidak melebihi 24 jam, dan waktu_akhir harus lebih besar dari waktu_mulai, jika tidak, akan mengembalikan #VALUE! nilai kesalahan.

1.27 Hitung perbedaan antara dua waktu kencan

Jika ada dua kali dalam format mm/dd/yyyy jj:mm:dd, untuk menghitung selisihnya, Anda dapat menggunakan salah satu rumus di bawah ini sesuai kebutuhan.

Dapatkan perbedaan waktu antara dua tanggal dan hasil kembali dalam format jj:mm:dd

Ambil dua tanggal waktu di sel A2 dan B2 sebagai contoh, gunakan rumus seperti ini:

=B2-A2

Tekan Enter kunci, mengembalikan hasil dalam format datetime, lalu format hasil ini sebagai [j]: mm: dd dalam kategori khusus di bawah Jumlah tab Format Cells dialog.
 

Dapatkan perbedaan antara dua tanggal dan waktu kembali, jam, menit, detik

Ambil dua tanggal waktu di sel A5 dan B5 sebagai contoh, gunakan rumus seperti ini:

=INT(B5-A5) & " Days, " & HOUR(B5-A5) & " Hours, " & MINUTE(B5-A5) & " Minutes, " & SECOND(B5-A5) & " Seconds "

Tekan Enter kunci untuk mendapatkan hasil.

Catatan: di kedua rumus, end_datetime harus lebih besar dari start_datetime, jika tidak, rumus mengembalikan nilai kesalahan.

1.28 Hitung perbedaan waktu dengan milidetik

Pertama, Anda perlu tahu cara memformat sel untuk menunjukkan milidetik:

Pilih sel yang ingin Anda tampilkan milidetik dan hak untuk memilih Format Cells untuk mengaktifkan Format Cells dialog, pilih Kustom dalam Kategori list di bawah tab Number, dan ketik ini jj: mm: ss.000 ke dalam kotak teks.

Gunakan rumus:

Di sini untuk menghitung perbedaan antara dua kali di sel A8 dan B8, gunakan rumus sebagai:

=ABS(B8-A8)

Tekan Enter kunci untuk mendapatkan hasil.

1.29 Hitung jam kerja antara dua tanggal tidak termasuk akhir pekan

Terkadang, Anda mungkin perlu menghitung jam kerja di antara dua tanggal, tidak termasuk akhir pekan (Sabtu dan Minggu).

Di sini jam kerja ditetapkan 8 jam setiap hari, dan untuk menghitung jam kerja antara dua tanggal yang disediakan di sel A16 dan B16, gunakan rumus seperti ini:

=NETWORKDAYS(A16,B16) * 8

Tekan Enter kunci dan kemudian format hasilnya sebagai umum atau angka.

Untuk contoh lebih lanjut tentang menghitung jam kerja antara dua tanggal, silakan kunjungi Dapatkan Jam Kerja Antara Dua Tanggal Di Excel

---

Jika Anda memiliki Kutools for Excel diinstal di Excel, 90 persen dari perhitungan perbedaan datetime dapat diselesaikan dengan cepat tanpa mengingat rumus apa pun.

1.31 Hitung perbedaan antara dua waktu dengan Data & Time Helper

Untuk menghitung perbedaan antara dua tanggal waktu di Excel, cukup: Pembantu Tanggal & Waktu cukup.

1. Pilih sel tempat Anda menempatkan hasil yang dihitung, dan klik Kutools > Pembantu Formula > Pembantu Tanggal & Waktu.

2. Dalam bermunculan Pembantu Tanggal & Waktu dialog, ikuti pengaturan di bawah ini:

1. Memeriksa Perbedaan pilihan;
2. Pilih tanggal mulai dan waktu berakhir di Masukan argumen bagian, Anda juga dapat langsung memasukkan datetime secara manual ke dalam kotak input, atau klik ikon kalender untuk memilih tanggal;
3. Pilih jenis hasil keluaran dari daftar drop-down;
4. Pratinjau hasilnya di Hasil bagian.

3. klik Ok. Hasil yang dihitung dikeluarkan, dan seret gagang IsiOtomatis ke sel yang juga perlu Anda hitung.

olymp trade indonesiaTip:

Jika Anda ingin mendapatkan perbedaan antara dua waktu dan menampilkan hasilnya sebagai hari, jam, dan menit Kutools for Excel, lakukan seperti di bawah ini:

Pilih sel tempat Anda ingin menempatkan hasilnya, dan klik Kutools > Pembantu Formula > Tanggal Waktu > Hitung hari, jam dan menit antara dua tanggal.

Lalu di Rumus Pembantu dialog, tentukan tanggal mulai dan tanggal akhir, lalu klik Ok.

Dan hasil selisih akan ditampilkan sebagai hari, jam, dan menit.

Klik Pembantu Tanggal & Waktu untuk mengetahui lebih banyak penggunaan fitur ini.

Klik Kutools for Excel untuk mengetahui semua fitur add-in ini.

Klik Free download untuk mendapatkan 30-hari uji coba gratis Kutools for Excel

1.32 Menghitung perbedaan akhir pekan/hari kerja/hari kerja tertentu antara dua waktu dengan Formula Helper

Jika Anda ingin menghitung akhir pekan, hari kerja, atau hari kerja tertentu dengan cepat di antara dua waktu, Kutools for Excel'S Pembantu Formula kelompok dapat membantu Anda.

1. Pilih sel yang akan menempatkan hasil perhitungan, klik Kutools > Statistik > Jumlah hari non-kerja antara dua tanggal/Jumlah hari kerja antara dua tanggal/Hitung jumlah hari tertentu dalam seminggu.

2. Dalam bermunculan Rumus Pembantu dialog, tentukan tanggal mulai dan tanggal akhir, jika Anda menerapkan Hitung jumlah hari tertentu dalam seminggu, Anda juga perlu menentukan hari kerja.

Untuk menghitung hari kerja tertentu, Anda dapat merujuk ke catatan untuk menggunakan 1-7 untuk menunjukkan Minggu-Sabtu.

3. klik Ok, lalu seret tuas IsiOtomatis ke sel yang perlu menghitung jumlah akhir pekan/hari kerja/hari kerja tertentu jika perlu.

Klik Kutools for Excel untuk mengetahui semua fitur add-in ini.

Klik Free download untuk mendapatkan 30-hari uji coba gratis Kutools for Excel

---

2. Tambah atau kurangi tanggal dan waktu

Kecuali untuk menghitung perbedaan antara dua datetimes, penambahan atau pengurangan juga merupakan perhitungan datetime normal di Excel. Misalnya, Anda mungkin ingin mendapatkan tanggal jatuh tempo berdasarkan tanggal produksi dan jumlah hari penyimpanan untuk suatu produk.

2.11 Menambah atau mengurangi hari ke tanggal

Untuk menambah atau mengurangi jumlah hari tertentu pada suatu tanggal, berikut adalah dua metode yang berbeda.

Misalkan untuk menambahkan 21 hari ke tanggal di sel A2, silakan pilih salah satu metode di bawah ini untuk menyelesaikannya,

Metode 1 tanggal+hari

Pilih sel dan ketik rumus:

=A+21

Tekan Enter kunci untuk mendapatkan hasil.

Jika ingin mengurangi 21 hari, ubah saja tanda plus (+) menjadi tanda minus (-).

Metode 2 Tempel Spesial

1. Ketik jumlah hari yang ingin Anda tambahkan di sel seperti di sel C2, lalu tekan Ctrl + C untuk menyalinnya

2. Kemudian pilih tanggal yang ingin Anda tambahkan 21 hari, klik kanan untuk menampilkan menu konteks, dan pilih Tempel Spesial....

3. Dalam sisipkan Khusus dialog, periksa Add opsi (Jika Anda ingin mengurangi hari, centang Mengurangi pilihan). Klik OK.

4. Sekarang tanggal asli berubah menjadi angka 5 digit, format sebagai tanggal.

2.12 Menambah atau mengurangi bulan ke tanggal

Untuk menambah atau mengurangi bulan ke tanggal, fungsi EDATE dapat digunakan.

Klik EDATE untuk mempelajari argumen dan penggunaannya.

Misalkan untuk menambahkan 6 bulan ke tanggal di sel A2, gunakan rumus seperti ini:

=EDATE(A2,6)

Tekan Enter kunci untuk mendapatkan hasil.

Jika Anda ingin mengurangi 6 bulan ke tanggal, ubah 6 menjadi -6.

2.13 Menambah atau mengurangi tahun pada tanggal

Untuk menambah atau mengurangi n tahun pada suatu tanggal, rumus yang menggabungkan fungsi DATE, YEAR, MONTH dan DAY dapat digunakan.

Misalkan untuk menambahkan 3 tahun ke tanggal di sel A2, gunakan rumus seperti ini:

=DATE(YEAR(A2) + 3, MONTH(A2),DAY(A2))

Tekan Enter kunci untuk mendapatkan hasil.

Jika Anda ingin mengurangi 3 tahun dengan tanggal, ubah 3 menjadi -3.

2.14 Menambah atau mengurangi minggu ke tanggal

Untuk menambah atau mengurangi minggu ke tanggal, rumus umumnya adalah

Misalkan untuk menambahkan 4 minggu ke tanggal di sel A2, gunakan rumus seperti ini:

=A2+4*7

Tekan Enter kunci untuk mendapatkan hasil.

Jika Anda ingin mengurangi 4 minggu ke tanggal, ubah tanda plus (+) menjadi tanda minus (-).

2.15 Menambah atau mengurangi hari kerja termasuk atau tidak termasuk hari libur

Di bagian ini, memperkenalkan cara menggunakan fungsi WORKDAY untuk menambah atau mengurangi hari kerja ke tanggal tertentu tidak termasuk hari libur atau termasuk hari libur.

Mengunjungi HARI KERJA untuk mengetahui lebih detail tentang argumen dan penggunaannya.

Tambahkan hari kerja termasuk hari libur

Di sel A2 adalah tanggal yang Anda gunakan, di sel B2 berisi jumlah hari yang ingin Anda tambahkan, gunakan rumus seperti ini:

=WORKDAY(A2,B2)

Tekan Enter kunci untuk mendapatkan hasil.

Tambahkan hari kerja kecuali hari libur

Di sel A5 adalah tanggal yang Anda gunakan, di sel B5 berisi jumlah hari yang ingin Anda tambahkan, dalam rentang D5:D8 mencantumkan hari libur, gunakan rumus seperti ini:

=WORKDAY(A5,B5,D5:D8)

Tekan Enter kunci untuk mendapatkan hasil.

Catatan:

Fungsi WORKDAY mengambil hari Sabtu dan Minggu sebagai akhir pekan, jika akhir pekan Anda pada hari Sabtu dan Minggu, Anda dapat menerapkan fungsi WOKRDAY.INTL, yang mendukung penentuan akhir pekan.

Mengunjungi HARI KERJA.INTL lebih lanjut.

Jika Anda ingin mengurangi hari kerja menjadi tanggal, cukup ubah jumlah hari menjadi negatif dalam rumus.

2.16 Menambah atau mengurangi tahun, bulan, hari tertentu hingga tanggal

Jika Anda ingin menambahkan tahun tertentu, hari bulan ke tanggal, rumus yang menggabungkan fungsi DATE, YEAR, MONTH, dan DAYS dapat membantu Anda.

Untuk menambahkan 1 tahun 2 bulan dan 30 hari ke tanggal di A11, gunakan rumus seperti ini:

=DATE(YEAR(A11)+1,MONTH(A11)+2,DAY(A11)+30)

Tekan Enter kunci untuk mendapatkan hasil.

Jika ingin dikurangi, ubah semua tanda plus (+) menjadi tanda minus (-).

---

2.21 Menambah atau mengurangi jam/menit/detik ke waktu tanggal

Berikut menyediakan beberapa rumus untuk menambah atau mengurangi jam, menit, atau detik ke datetime.

Tambahkan atau kurangi jam ke datetime

Misalkan untuk menambahkan 3 jam ke datetime (juga bisa menjadi waktu) di sel A2, gunakan rumus seperti ini:

=A2+3/24

Tekan Enter kunci untuk mendapatkan hasil.

Tambahkan atau kurangi jam ke datetime

Misalkan untuk menambahkan 15 menit ke datetime (juga bisa menjadi waktu) di sel A5, gunakan rumus seperti ini:

=A2+15/1440

Tekan Enter kunci untuk mendapatkan hasil.

Tambahkan atau kurangi jam ke datetime

Misalkan untuk menambahkan 20 detik ke datetime (juga bisa menjadi waktu) di sel A8, gunakan rumus seperti ini:

=A2+20/86400

Tekan Enter kunci untuk mendapatkan hasil.

2.22 Jumlah kali selama 24 jam

Misalkan ada tabel Excel yang mencatat waktu kerja semua staf dalam seminggu, untuk menjumlahkan total waktu kerja untuk menghitung pembayaran, Anda dapat menggunakan SUM(rentang) untuk mendapatkan hasilnya. Namun secara umum hasil penjumlahan akan ditampilkan dalam waktu tidak lebih dari 24 jam seperti gambar di bawah ini, bagaimana Anda bisa mendapatkan hasil yang benar?

Sebenarnya, Anda hanya perlu memformat hasilnya sebagai [hh]:mm:ss.

Klik kanan pada sel hasil, pilih Format Cells di menu konteks, dan di popping Format Cells dialog, pilih Kustom dari daftar, dan ketik [hh]:mm:ss ke dalam kotak teks di bagian kanan, klik OK.
  

Hasil penjumlahan akan ditampilkan dengan benar.

2.23 Tambahkan jam kerja ke tanggal tidak termasuk akhir pekan dan hari libur

Berikut ini memberikan rumus panjang untuk mendapatkan tanggal akhir berdasarkan penambahan jumlah jam kerja tertentu ke tanggal mulai dan tidak termasuk akhir pekan (Sabtu dan Minggu) dan hari libur.

Dalam tabel Excel, A11 berisi waktu mulai dan waktu mulai, dan B11 berisi jam kerja, di sel E11 dan E13 adalah waktu mulai dan berakhir kerja, dan sel E15 berisi hari libur yang akan dikecualikan.

Silakan gunakan rumus seperti ini:

=WORKDAY(A11,INT(B11/8)+IF(TIME(HOUR(A11),MINUTE(A11),SECOND(A11))+TIME(MOD(B11,8),MOD(MOD(B11,8),1)*60,0)> $E$13,1,0),$E$15)+IF(TIME(HOUR(A11),MINUTE(A11),SECOND(A11))+TIME(MOD(B11,8),MOD(MOD(B11,8),1)*60,0)>$E$13,$E$11 +TIME(HOUR(A11),MINUTE(A11),SECOND(A11))+TIME(MOD(B11,8),MOD(MOD(B11,8),1)*60,0)-$E$13,TIME(HOUR(A11),MINUTE(A11),SECOND(A11)) +TIME(MOD(B11,8),MOD(MOD(B11,8),1)*60,0))

Tekan Enter kunci untuk mendapatkan hasil.

---

Jika Anda memiliki Kutools for Excel terpasang, hanya satu alat – Tanggal & Waktu Helper dapat menyelesaikan sebagian besar perhitungan pada penambahan dan pengurangan datetime.

1. Klik sel yang ingin Anda keluarkan hasilnya, dan terapkan alat ini dengan mengklik Kutools > Pembantu Formula > Pembantu Tanggal & Waktu.

2. Dalam Pembantu Tanggal & Waktu dialog, periksa Add opsi atau Mengurangi opsi yang Anda butuhkan, lalu pilih sel atau langsung ketik tanggal waktu yang ingin Anda gunakan Masukan argumen bagian, lalu tentukan tahun, bulan, minggu, hari, jam, menit dan detik yang ingin Anda tambahkan atau kurangi, lalu klik Ok. Lihat tangkapan layar:

Anda dapat melihat pratinjau hasil yang dihitung di Hasil bagian.

Sekarang hasilnya dikeluarkan, seret pegangan otomatis ke sel lain untuk mendapatkan hasilnya.

Klik Pembantu Tanggal & Waktu untuk mengetahui lebih banyak penggunaan fitur ini.

Klik Kutools for Excel untuk mengetahui semua fitur add-in ini.

Klik Unduh Biaya untuk mendapatkan 30-hari uji coba gratis Kutools for Excel

---

2.41 Centang atau sorot jika tanggal kedaluwarsa

Jika ada daftar tanggal kadaluwarsa produk, Anda mungkin ingin memeriksa dan menyorot tanggal kadaluwarsa berdasarkan hari ini seperti gambar di bawah ini.

Sebenarnya, itu Format Bersyarat dapat dengan cepat menangani pekerjaan ini.

1. Pilih tanggal yang ingin Anda periksa, lalu klik Beranda > Format Bersyarat > Aturan baru.

2. Dalam Aturan Pemformatan Baru dialog, pilih Gunakan rumus untuk menentukan sel mana yang akan diformat dalam Pilih Jenis Aturan bagian, dan jenis =B2 ke dalam kotak input (B2 adalah kencan pertama yang ingin Anda periksa), dan klik dibentuk muncul Format Cells dialog, lalu pilih pemformatan yang berbeda untuk mengungguli tanggal kedaluwarsa yang Anda butuhkan. Klik OK > OK.
  

2.42 Mengembalikan akhir bulan ini/hari pertama bulan depan/a>

Tanggal kadaluarsa beberapa produk ada di akhir bulan produksi atau hari pertama bulan produksi berikutnya, untuk dengan cepat mencantumkan tanggal kadaluwarsa berdasarkan tanggal produksi, ikuti bagian ini.

Dapatkan akhir bulan ini

Berikut adalah tanggal produksi di sel B13, gunakan rumus seperti ini:

=EOMONTH(B13,0)

Tekan Enter kunci untuk mendapatkan hasil.

Dapatkan hari pertama bulan depan

Berikut adalah tanggal produksi di sel B18, gunakan rumus seperti ini:

=EOMONTH(B18,0)+1

Tekan Enter kunci untuk mendapatkan hasil.

---

3. Hitung usia

Di bagian ini, daftar metode pemecahan cara menghitung usia berdasarkan tanggal tertentu atau nomor seri.

---

3.11 Hitung usia berdasarkan tanggal lahir yang diberikan

Dapatkan usia dalam angka desimal berdasarkan tanggal lahir

Klik FRAC TAHUN untuk detail tentang argumennya dan penggunaannya.

Misalnya, untuk mendapatkan umur berdasarkan daftar tanggal lahir pada kolom B2:B9, gunakan rumus sebagai berikut:

=YEARFRAC(B2,TODAY())

Tekan Enter tombol, lalu seret tuas IsiOtomatis ke bawah hingga semua usia dihitung.

olymp trade indonesiaTip:

1) Anda dapat menentukan tempat desimal yang Anda butuhkan di Format Cells dialog.

2) Jika Anda ingin menghitung usia pada tanggal tertentu berdasarkan tanggal lahir tertentu, ubah HARI INI() ke tanggal tertentu yang diapit dengan tanda kutip ganda seperti =YEARFRAC(B2,"1/1/2021")

3) Jika Anda ingin mendapatkan usia tahun depan berdasarkan tanggal lahir, cukup tambahkan 1 dalam rumus seperti =YEARFRAC(B2,TODAY())+1.

Dapatkan usia dalam bilangan bulat berdasarkan tanggal lahir

Klik TANGGAL untuk detail tentang argumennya dan penggunaannya.

Menggunakan contoh di atas, untuk mendapatkan usia berdasarkan tanggal lahir dalam daftar di B2:B9, gunakan rumus seperti ini:

=DATEDIF(B2,TODAY(),"y")

Tekan Enter tombol, lalu seret tuas isi-otomatis ke bawah hingga semua usia dihitung.

olymp trade indonesiaTip:

1) Jika Anda ingin menghitung usia pada tanggal tertentu berdasarkan tanggal lahir tertentu, ubah HARI INI() ke tanggal tertentu yang diapit dengan tanda kutip ganda seperti =DATEDIF(B2,"1/1/2021","y") .

2) Jika Anda ingin mendapatkan usia tahun depan berdasarkan tanggal lahir, cukup tambahkan 1 dalam rumus seperti =DATEDIF(B2,TODAY(),"y")+1.

3.12 Hitung usia dalam format tahun, bulan dan hari dengan tanggal lahir yang diberikan

Jika Anda ingin menghitung usia berdasarkan tanggal lahir tertentu, dan menunjukkan hasilnya sebagai xx tahun, xx bulan, xx hari seperti gambar di bawah ini, berikut adalah rumus panjang yang dapat membantu Anda.

Untuk mendapatkan umur dalam tahun, bulan, dan hari berdasarkan tanggal lahir di sel B12, gunakan rumus sebagai berikut:

=DATEDIF(B12,TODAY(),"Y")&" Years, "&DATEDIF(B12,TODAY(),"YM")&" Months, "&DATEDIF(B12,TODAY(),"MD")&" Days"

Tekan Enter untuk mendapatkan usia, lalu seret tuas IsiOtomatis ke sel lain.

olymp trade indonesiaTip:

Jika Anda ingin menghitung usia pada tanggal tertentu berdasarkan tanggal lahir tertentu, ubah HARI INI() ke tanggal tertentu yang diapit dengan tanda kutip ganda seperti = =DATEDIF(B12,"1/1/2021","Y")& " Tahun, "&DATEDIF(B12,"1/1/2021",,"YM")&" Bulan, "&DATEDIF(B12,"1/1/2021",,"MD")&" Hari".

3.13 Hitung usia berdasarkan tanggal lahir sebelum 1/1/1900

Di Excel, tanggal sebelum 1/1/1900 tidak dapat dimasukkan sebagai datetime atau dihitung dengan benar. Tetapi jika Anda ingin menghitung usia orang terkenal berdasarkan tanggal lahir yang diberikan (sebelum 1/11900) dan tanggal kematian, hanya kode VBA yang dapat membantu Anda.

1. tekan lain + F11 kunci untuk mengaktifkan Microsoft Visual Basic untuk Aplikasi jendela, dan klik Menyisipkan tab dan pilih Modul untuk membuat modul baru.

2. Kemudian salin dan tempel kode di bawah ini ke modul baru.

VBA: Hitung usia sebelum 1/1/1900

Public Function AgeFunc(SDate As Variant, EDate As Variant) As Long
'UpdatebyExtendOffice
    Dim xSMonth As Integer
    Dim xSDay As Integer
    Dim xSYear As Integer
    Dim xEMonth As Integer
    Dim xEDay As Integer
    Dim xEYear As Integer
    Dim xAge As Integer
    If Not GetDate(SDate, xSYear, xSMonth, xSDay) Then
        AgeFunc = "Invalid Date"
        Exit Function
    End If
    If Not GetDate(EDate, xEYear, xEMonth, xEDay) Then
        AgeFunc = "Invalid Date"
        Exit Function
    End If
    xAge = xEYear - xSYear
    If xSMonth > xEMonth Then
        xAge = xAge - 1
    ElseIf xSMonth = xEMonth Then
        If xSDay > xEDay Then xAge = xAge - 1
    End If
    If xAge < 0 Then
        AgeFunc = "Invalid Date"
    Else
        AgeFunc = xAge
    End If
End Function
Private Function GetDate(ByVal DateStr As String, Y As Integer, M As Integer, D As Integer) As Boolean
    Dim I As Long
    Dim K As Long
    Y = 0
    M = 0
    D = 0
    GetDate = True
    On Error Resume Next
    I = InStr(1, DateStr, "/")
    M = CLng(Left(DateStr, I - 1))
    D = CLng(Mid(DateStr, I + 1, InStr(I + 1, DateStr, "/") - I - 1))
    Y = CLng(Right(DateStr, Len(DateStr) - InStrRev(DateStr, "/")))
    If M < 1 Or M > 12 Or D < 1 Or D > 31 Or Y < 1 Then
        GetDate = False
    End If
End Function

3. Simpan kode, dan kembali ke lembar dan pilih sel untuk menempatkan usia yang dihitung, ketik =AgeFunc(tanggal lahir,tanggal mati), dalam hal ini, =UsiaFunc(B22,C22), tekan tombol Enter untuk mendapatkan usia. Dan gunakan pegangan pengisian otomatis untuk menerapkan rumus ini ke sel lain jika diperlukan.

Jika Anda memiliki Kutools for Excel diinstal di Excel, Anda dapat menerapkan Pembantu Tanggal & Waktu alat untuk menghitung umur.

1. Pilih sel yang ingin Anda tempatkan usia yang dihitung, dan klik Kutools > Pembantu Formula > Pembantu Tanggal & Waktu.

2. Dalam Pembantu Tanggal & Waktu dialog,

• 1) Periksa Usia pilihan;
• 2) Pilih sel tanggal lahir atau langsung masukkan tanggal lahir atau klik ikon kalender untuk memilih tanggal lahir;
• 3) Pilih Hari ini opsi jika Anda ingin menghitung usia saat ini, pilih Tanggal yang ditentukan opsi dan masukkan tanggal jika Anda ingin menghitung usia di masa lalu atau masa depan;
• 4) Tentukan jenis output dari daftar drop-down;
• 5) Pratinjau hasil keluaran. Klik Ok.

Klik Pembantu Tanggal & Waktu untuk mengetahui lebih banyak penggunaan fitur ini.

Klik Kutools for Excel untuk mengetahui semua fitur add-in ini.

Klik Free download untuk mendapatkan 30-hari uji coba gratis Kutools for Excel

---

3.31 Dapatkan ulang tahun dari nomor ID

Jika ada daftar nomor ID yang menggunakan 6 digit pertama untuk mencatat tanggal lahir seperti 920315330 berarti tanggal lahir adalah 03/15/1992, bagaimana Anda bisa dengan cepat memasukkan tanggal lahir ke kolom lain?

Sekarang mari kita ambil daftar nomor ID yang dimulai di sel C2 sebagai contoh, dan gunakan rumus seperti ini:

=MID(C2,5,2)&"/"&MID(C2,3,2)&"/"&MID(C2,1,2)

Tekan Enter kunci. Kemudian seret tuas IsiOtomatis ke bawah untuk mendapatkan hasil lainnya.

Catatan:

Dalam rumus, Anda dapat mengubah referensi sesuai kebutuhan Anda. Misalnya, jika nomor ID ditampilkan sebagai 13219920420392, tanggal lahirnya adalah 04/20/1992, Anda dapat mengubah rumus menjadi =MID(C2,8,2)&"/"&MID(C2,10,2)&"/ "&MID(C2,4,4) untuk mendapatkan hasil yang benar.

3.32 Hitung usia dari nomor ID

Jika ada daftar nomor ID yang menggunakan 6 digit pertama untuk mencatat tanggal lahir seperti 920315330 berarti tanggal lahir adalah 03/15/1992, bagaimana Anda dapat dengan cepat menghitung usia berdasarkan setiap nomor ID di Excel?

Sekarang mari kita ambil daftar nomor ID yang dimulai di sel C2 sebagai contoh, dan gunakan rumus seperti ini:

=DATEDIF(DATE(IF(LEFT(C2,2)>TEXT(TODAY(),"YY"),"19"&LEFT(C2,2),"20"&LEFT(C2,2)),MID(C2,3,2),MID(C2,5,2)),TODAY(),"y")

Tekan Enter kunci. Kemudian seret tuas IsiOtomatis ke bawah untuk mendapatkan hasil lainnya.

Catatan:

Dalam rumus ini, jika tahun lebih kecil dari tahun berjalan, maka tahun dianggap dimulai dengan 20, misalnya 200203943 akan dianggap sebagai tahun 2020; jika tahun lebih besar dari tahun sekarang, tahun akan dianggap dimulai dengan 19, seperti 920420392 akan dianggap sebagai tahun 1992.

---

Lebih Banyak Tutorial Excel: