Bagaimana cara agar jendela excel selalu di atas?

Pernahkah Anda berharap agar jendela Excel Anda selalu di atas dan tidak tertutup oleh jendela lain? Sayangnya, Excel tidak menyediakan fitur untuk menyelesaikan tugas ini. Tapi, di sini, saya bisa memberi Anda kode VBA untuk menangani pekerjaan ini.

Jaga agar jendela Excel selalu di atas dengan kode VBA

Jaga agar jendela Excel selalu di atas dengan kode VBA

Kode VBA berikut dapat membantu Anda menjaga jendela Excel selalu di atas, kode tersebut diterapkan ke office 32-bit dan office 64-bit.

1. Tahan ALT + F11 kunci untuk membuka Jendela Microsoft Visual Basic for Applications.

2. Klik Menyisipkan > Modul, dan tempel kode berikut di Jendela Modul.

Kode VBA: Jaga agar jendela Excel selalu di atas

'Update 20140909
#If Win64 Then
    Public Declare PtrSafe Function SetWindowPos _
        Lib "user32" ( _
            ByVal hwnd As LongPtr, _
            ByVal hwndInsertAfter As LongPtr, _
            ByVal x As Long, ByVal y As Long, _
            ByVal cx As Long, ByVal cy As Long, _
            ByVal wFlags As Long) _
    As Long
#Else
    Public Declare Function SetWindowPos _
        Lib "user32" ( _
            ByVal hwnd As Long, _
            ByVal hwndInsertAfter As Long, _
            ByVal x As Long, ByVal y As Long, _
            ByVal cx As Long, ByVal cy As Long, _
            ByVal wFlags As Long) _
    As Long
#End If
Public Const SWP_NOSIZE = &H1
Public Const SWP_NOMOVE = &H2
Public Const HWND_TOPMOST = -1
Public Const HWND_NOTOPMOST = -2
Sub ShowXLOnTop(ByVal OnTop As Boolean)
    Dim xStype As Long
    #If Win64 Then
        Dim xHwnd As LongPtr
    #Else
        Dim xHwnd As Long
    #End If
    If OnTop Then
        xStype = HWND_TOPMOST
    Else
        xStype = HWND_NOTOPMOST
    End If
    Call SetWindowPos(Application.hwnd, xStype, 0, 0, 0, 0, SWP_NOSIZE Or SWP_NOMOVE)
End Sub
Sub SetXLOnTop()
    ShowXLOnTop True
End Sub
Sub SetXLNormal()
    ShowXLOnTop False
End Sub

3. Lalu tekan F5 kunci untuk menjalankan kode ini, dan a Macro kotak dialog akan muncul, pilih SetXLOnTop opsi, dan klik Run .

4. Dan kemudian jendela Excel Anda akan selalu berada di atas aplikasi lain.

Note: Jika Anda ingin mengembalikan jendela Excel ke normal, cukup tekan F5 kunci untuk membuka Macro dialog, pilih SetelXNormal dan klik Run.